MQL5 Wizard - MFIによる条件付きの3 Black Crows/3 White Soldiers - MetaTrader 5のためのエキスパート

MQL5 Wizardを使えば、クライアントターミナルにあるStandard libraryのエキスパートアドバイザーを自動生成することができます。(詳細は、Creating Ready-Made Expert Advisors in MQL5 Wizardを参照)トレードシグナルのクラスを生成しさせすれば、トレードアイディアをすぐに確認することができますクラスの例と構造については MQL5 Wizard: How to Create a Module of Trading Signalsを参照してください。

一般的な考え方は下記の通りです。:CExpertSignalがシグナルのクラスです。そして、LongCondition() と ShortCondition() を上書きする必要があります。

"Strategies of best traders" (ロシア)という著書があります。 そこには数多くの手法と方法が記述されており、転換足パターンを Stochastic、 CCI、 MFI、 RSIの条件のもと、焦点を当てていきます。

最も良い方法は、ロウソク足のパターンの確認に、CExpertSignalから導かれるクラスを切り分けて生成することです。ロウソク足のパターンによるトレードシグナルの確認には、CCandlePatternのクラスを書いて、必要な条件例えば、オシレーターの確認など)を追加すれば十分です。

Market Facilitation Index (MFI)条件付きの"3 Black Crows/3 White Soldiers"トレードシグナルのモジュールは、CCandlePattern classに基づいています。ロウソク足のパターンによるシグナルの生成のシンプルな一例です。

1. "3 Black Crows" and 3 "White Soldiers" 転換足パターン

1.1. 3 Black Crows

現在の上昇トレンドの転換としてのベア型のロウソク足このパターンは、それぞれの足の始値がひとつ前の足の実体の範囲内にある状態で、終値がひとつ前の終値よりも低い3つの連続した実体の長いロウソク足で形成される。

図1. "3 Black Crows"のロウソク足パターン

"3 Black Crows"は、CCandlePattern classの CheckPatternThreeBlackCrows method に実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "3 Black Crows" candlestick pattern          |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeBlackCrows()
  {
//--- 3 Black Crows 
   if((Open(3)-Close(3)>AvgBody(1)) && // (long black)
      (Open(2)-Close(2)>AvgBody(1)) &&
      (Open(1)-Close(1)>AvgBody(1)) && 
      (MidPoint(2)<MidPoint(3))     && // (lower midpoints)
      (MidPoint(1)<MidPoint(2)))       
      return(true);
//---
   return(false);
  }

1.2. 3 White Soldiers

現在の下降トレンドの転換を予想するのに使うブル型のロウソク足のパターンこのパターンは、それぞれの足の始値がひとつ前の足の実体の範囲内にある状態で、終値がひとつ前の終値よりも高い3つの連続した実体の長いロウソク足で形成される。

このパターンは、2日目の日足の始値が日中の半分よりも上にある限り、有効です。日の終わりごろに、極めて小さい上ヒゲを残して、高値付近で終値を迎えるはずです。同じパターンが3日目でも繰り返されます。

図2. "3 White Soldiers"

"3 White Soldiers"のメソッドです。:

//+------------------------------------------------------------------+
//| Checks formation of "3 White Soldiers" candlestick pattern       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeWhiteSoldiers()
  {
   //--- 3 White Soldiers
   if((Close(3)-Open(3)>AvgBody(1)) && // long white
      (Close(2)-Open(2)>AvgBody(1)) &&
      (Close(1)-Open(1)>AvgBody(1)) &&
      (MidPoint(2)>MidPoint(3))     && // higher midpoints
      (MidPoint(1)>MidPoint(2)))
      return(true);
//---
   return(false);
  }

2. MFI条件付きのシグナル

買いポジション・売りポジションのシグナルは、MFIで確認する必要があります。MFIの値は、40 (買いポジションの場合)よりも低く、60 (売りポジションの場合)よりも高くなければなりません。

ポジションの決済はMFIの値で行います。2通りのケースがあります。:

1. MFIが反対の基準値に到達した場合 (買いポジションは70。売りポジションは30)
2. 逆のシグナルが発生しない (MFIが次の値に到達: 買いポジションは30、売りポジションは70)

図3. MFIの条件付きの"3 Black Crows"

• int CBC_WS_MFI::LongCondition() - 買いポジションのエントリー条件(80) と 売りポジションの決済条件 (40);
  
• int CBC_WS_MFI::ShortCondition() - 売りポジションのエントリー条件(80) と 買いポジションの決済条件 (40)

2.1. 買いポジション/売りポジションの決済

1. "3 White Soldiers" の状態はMFIで確認する必要があります。: MFI(1)<40 (直近の確定した足のMFIの値が40よりも小さい).

2. MFIが基準値(70 か 30)を上抜けした場合、売りポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBC_WS_MFI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of 3 White Soldiers pattern and MFI<40
  if(CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) && (MFI(1)<40))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (upward 30, upward 70)
  if(((MFI(1)>30) && (MFI(2)<30)) || ((MFI(1)>70) && (MFI(2)<70)))
     result=40;
//--- return result
   return(result);
  }

2.2. 売りポジション/買いポジションの決済

1. "3 Black Crows"の状態はMFIで確認する必要があります。: MFI(1)>60 (直近の確定した足のMFIの値が60よりも大きい)

2. MFIが基準値 (70 か 30)を上抜けした場合、買いポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBC_WS_MFI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of 3 Black Crows pattern and MFI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) && (MFI(1)>60))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (upward 70, downward 30)
   if(((MFI(1)>70) && (MFI(2)<70)) || ((MFI(1)<30) && (MFI(2)>30)))
     result=40;
//--- return result
   return(result);
  }

2.3. MQL5 WizardでEAを生成する

エキスパートアドバイザーを生成するには、MQL5 Wizardを立ち上げてください。:

図4. MQL5 WizardでEAを生成する

エキスパートアドバイザーの名前を決めましょう。:

図5. エキスパートアドバイザーの一般設定

トレードシグナルのモジュールを選択します。

図6. エキスパートアドバイザーのシグナルプロパティ

今回の場合、モジュールは１つだけ使います。

"Signals based on 3 Black Crows/3 White Soldiers confirmed by MFI" モジュールの追加:

図7. エキスパートアドバイザーのシグナルプロパティ

シグナルの追加モジュール:

図8. エキスパートアドバイザーのシグナルプロパティ

トレーリングプロパティにも様々なものがありますが、今回は"Trailing Stop not used"にします。:

図9. エキスパートアドバイザーのトレーリングプロパティTrailing properties of the Expert Advisor

資金管理プロパティとして、"Trading with fixed trade volume"(単利)を使います。:

図10エキスパートアドバイザーの資金管理プロパティMoney management properties of the Expert Advisor

"Finish"ボタンを押すと、エキスパートアドバイザーがExpert_ABC_WS_MFI.mq5に生成されます。保存場所は、terminal_data_folder\MQL5\Experts\.です。

生成後のエキスパートアドバイザーのデフォルトのパラメーター:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in points)

上記は下記にしなければなりません。:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Signal_ThresholdOpen/Signal_ThresholdClose パラメーターは、ポジションのオープン、決済の最初のレベルを決めます。

LongCondition() と ShortCondition() のメソッドのコードの中に、デフォルトの固定値が入っています。:

• エントリー: 80;
• 決済: 40.
  

Signal_StopLevel と Signal_TakeLevel パラメーターの値は、0にします。これは、ポジションの決済は、決済条件がtrueのときにのみ行われるということを表します。

2.4. バックテスト結果

過去データでエキスパートアドバイザーをテストしてみましょう。(EURUSD H1, テスト期間: 2010.01.01-2011.03.16, PeriodMFI=37, MA_period=13).

エキスパートアドバイザーの生成において、今回は固定ロット(Trading Fixed Lot, 0.1), トレーリングストップ(Trailing not used)はなしを選択しました。

図11. 3 Black Crows/3 White Soldiers + MFI のテスト結果

パラメーターの最適な設定値は、MetaTrader 5 client terminalのStrategy Testerで探すことができます。

MQL5 Wizard で生成したコードは expert_abc_ws_mfi.mq5 です。