Référence MQL5Bibliothèque StandardMathematiquesLogique floueFonctions d'appartenanceCZ_ShapedMembershipFunction

CZ_ShapedMembershipFunction

Classe d'implémentation d'une fonction d'appartenance en forme de Z avec les paramètres А et B.

Description

La fonction définit une fonction d'appartenance en forme de Z et ayant deux paramètres. C'est une fonction non croissante prenant des valeurs de 1 à 0. Les paramètres de la fonction définissent l'intervalle, dans lequel la fonction baisse dans une trajectoire non linéaire et de 1 à 0.

La fonction représente des ensembles flous de type "très bas". En d'autres termes, elle définit des fonctions d'appartenance non croissante avec saturation.

fuzzy_z_function

Un extrait de code dessinant un graphique est affiché plus bas.

Déclaration

class CZ_ShapedMembershipFuncion : public IMembershipFunction

Titre

#include <Math\Fuzzy\membershipfunction.mqh>

Hiérarchie d'héritage

CObject

IMembershipFunction

CZ_ShapedMembershipFunction

Méthodes de classe

Méthode de classe	Description
A	Retourne et définit le paramètre du début de l'intervalle décroissant.
B	Retourne et définit le paramètre de fin de l'intervalle décroissant.
GetValue	Calcule la valeur de la fonction d'appartenance d'un argument donné.

Méthodes héritées de la classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemple

//+------------------------------------------------------------------+
//|                                   Z_ShapedMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crée les fonctions membres
CZ_ShapedMembershipFunction func1(2,1);
CZ_ShapedMembershipFunction func2(2,5);
CZ_ShapedMembershipFunction func3(2,9);
//--- Crée les wrappers des fonctions membres
double Z_ShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double Z_ShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double Z_ShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Fonction de lancement du script                                  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crée le graphique
   CGraphic graphic;
   if(!graphic.Create(0,"Z_ShapedMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"Z_ShapedMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("Z_ShapedMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- crée une courbe
   graphic.CurveAdd(Z_ShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[2, 1]");
   graphic.CurveAdd(Z_ShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[2, 5]");
   graphic.CurveAdd(Z_ShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[2, 9]");
//--- définit les propriétés de l'axe X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- définit les propriétés de l'axe Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- dessin
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue