MQL5 RiferimentoLibreria StandardMatematicheLogica fuzzyMembership functionsCZ_ShapedMembershipFunction

CZ_ShapedMembershipFunction

Classe per implementare una funzione di appartenenza stile-z ccon i parametri A e B.

Descrizione

La funzione imposta due parametri stile-z ad una funzione di appartenenza. Questa è una funzione di appartenenza non crescente che assume valori da 1 a 0. I parametri della funzione definiscono un intervallo entro il quale la funzione diminuisce di traiettoria non lineare da 1 a 0.

La funzione rappresenta insiemi fuzzy di tipo "molto basso". In altre parole, essa imposta funzioni di appartenenza non crescente con saturazione.

fuzzy_z_function

Un codice di esempio per tracciare un grafico viene visualizzato qui di seguito.

Dichiarazione

class CZ_ShapedMembershipFuncion : public IMembershipFunction

Titolo

#include <Math\Fuzzy\membershipfunction.mqh>

Gerarchia di ereditarietà

CObject

IMembershipFunction

CZ_ShapedMembershipFunction

I metodi della classe

I metodi della classe	Descrizione
A	Ottiene ed imposta il parametro della diminuzione inizio dell'intervallo.
B	Ottiene ed imposta il parametro della diminuzione fine dell'intervallo.
GetValue	Calcola il valore della funzione di appartenenza da un argomento specificato.

Metodi ereditati dalla classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Esempio

//+------------------------------------------------------------------+
//|                                   Z_ShapedMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crea funzioni di appartenenza
CZ_ShapedMembershipFunction func1(2,1);
CZ_ShapedMembershipFunction func2(2,5);
CZ_ShapedMembershipFunction func3(2,9);
//--- Crea wrapper per funzioni di appartenenza
double Z_ShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double Z_ShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double Z_ShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Funzione di start del programma Script                           |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crea grafica
   CGraphic graphic;
   if(!graphic.Create(0,"Z_ShapedMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"Z_ShapedMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("Z_ShapedMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- crea curva
   graphic.CurveAdd(Z_ShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[2, 1]");
   graphic.CurveAdd(Z_ShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[2, 5]");
   graphic.CurveAdd(Z_ShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[2, 9]");
//--- imposta le proprietà dell'asse X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- imposta le proprietà asse Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plotta
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue