MQL5 リファレンス標準ライブラリ数学ファジー論理メンバーシップ関数CZ_ShapedMembershipFunction

CZ_ShapedMembershipFunction

АとBのパラメータを持つz字メンバーシップ関数を実装するためのクラス。

説明

この関数は、2パラメータz字メンバーシップ関数を設定します。これは1から0までの値をとる非増加メンバーシップ関数です。関数のパラメータは、関数が非線形軌道において1から0まで減少する間隔を定義します。

関数は、「非常に低い」タイプのファジー集合を表します。すなわち、飽和を伴う非増加メンバーシップ関数が設定されます。

fuzzy_z_function

下記はチャートをプロットするためのサンプルコードです。

宣言

class CZ_ShapedMembershipFuncion : public IMembershipFunction

タイトル

#include <Math\Fuzzy\membershipfunction.mqh>

継承階層

CObject

IMembershipFunction

CZ_ShapedMembershipFunction

クラスメソッド

クラスメソッド	説明
A	減少区間開始のパラメータを取得および設定します。
B	減少区間終了のパラメータを取得および設定します。
GetValue	メンバーシップ関数の値を指定された引数で計算します。

クラスから継承されたメソッド CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

例

//+------------------------------------------------------------------+
//| Z_ShapedMembershipFunction.mq5 |
//| Copyright 2016, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- メンバーシップ関数を作成します
CZ_ShapedMembershipFunction func1(2,1);
CZ_ShapedMembershipFunction func2(2,5);
CZ_ShapedMembershipFunction func3(2,9);
//--- メンバーシップ関数用のラッパーを作成する
double Z_ShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double Z_ShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double Z_ShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- グラフィックを作成する
CGraphic graphic;
if(!graphic.Create(0,"Z_ShapedMembershipFunction",0,30,30,780,380))
{
graphic.Attach(0,"Z_ShapedMembershipFunction");
}
graphic.HistoryNameWidth(70);
graphic.BackgroundMain("Z_ShapedMembershipFunction");
graphic.BackgroundMainSize(16);
//--- 曲線を作成する
graphic.CurveAdd(Z_ShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[2, 1]");
graphic.CurveAdd(Z_ShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[2, 5]");
graphic.CurveAdd(Z_ShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[2, 9]");
//--- X軸のプロパティを設定する
graphic.XAxis().AutoScale(false);
graphic.XAxis().Min(0.0);
graphic.XAxis().Max(10.0);
graphic.XAxis().DefaultStep(1.0);
//--- Y軸のプロパティを設定する
graphic.YAxis().AutoScale(false);
graphic.YAxis().Min(0.0);
graphic.YAxis().Max(1.1);
graphic.YAxis().DefaultStep(0.2);
//--- プロット
graphic.CurvePlotAll();
graphic.Update();
}

GetValue