Référence MQL5Bibliothèque StandardMathematiquesLogique floueFonctions d'appartenanceCGeneralizedBellShapedMembershipFunction

CGeneralizedBellShapedMembershipFunction

Classe d'implémentation d'une fonction d'appartenance généralisée en forme de cloche avec les paramètres A, B et C.

Description

La forme d'une fonction d'appartenance en forme de cloche est similaire aux fonctions gaussiennes. La fonction est lisse et prend des valeurs différentes de zéro le long de toute la zone de définition.

fuzzy_gbell_function

Un extrait de code dessinant un graphique est affiché plus bas.

Déclaration

class CGeneralizedBellShapedMembershipFuncion : public IMembershipFunction

Titre

#include <Math\Fuzzy\membershipfunction.mqh>

Hiérarchie d'héritage

CObject

IMembershipFunction

CGeneralizedBellShapedMembershipFunction

Méthodes de classe

Méthode de classe	Description
A	Retourne et définit le rapport de concentration de la fonction d'appartenance.
B	Retourne et définit le ratio de pente de la fonction d'appartenance.
С	Retourne et définit la coordonnée du maximum de la fonction d'appartenance.
GetValue	Calcule la valeur de la fonction d'appartenance d'un argument donné.

Méthodes héritées de la classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemple

//+------------------------------------------------------------------+
//|                      GeneralizedBellShapedMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crée les fonctions membres
CGeneralizedBellShapedMembershipFunction func1(5, 1, 3);
CGeneralizedBellShapedMembershipFunction func2(5, 2, 3);
CGeneralizedBellShapedMembershipFunction func3(5, 3, 3);
//--- Crée les wrappers des fonctions membres
double GeneralizedBellShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double GeneralizedBellShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double GeneralizedBellShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Fonction de lancement du script                                  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crée le graphique
   CGraphic graphic;
   if(!graphic.Create(0,"GeneralizedBellShapedMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"GeneralizedBellShapedMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("GeneralizedBellShapedMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- crée une courbe
   graphic.CurveAdd(GeneralizedBellShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[5, 1, 3]");
   graphic.CurveAdd(GeneralizedBellShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[5, 2, 3]");
   graphic.CurveAdd(GeneralizedBellShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[5, 3, 3]");
//--- définit les propriétés de l'axe X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- définit les propriétés de l'axe Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- dessin
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue