Descargar MetaTrader 5

AccountInfoInteger

Devuelve el valor de la propiedad correspondiente de la cuenta.

long  AccountInfoInteger(
   int  property_id      // identificador de la propiedad
   );

Parámetros

property_id

[in] Identificador de la propiedad. El valor puede ser uno de los valores ENUM_ACCOUNT_INFO_INTEGER.

Valor devuelto

Valor del tipo long.

Nota

La propiedad debe ser uno de los tipos bool, int o long.

Ejemplo:

void OnStart()
  {
//--- sacamos toda la información que se pueda de la función AccountInfoInteger()
   printf("ACCOUNT_LOGIN =  %d",AccountInfoInteger(ACCOUNT_LOGIN));
   printf("ACCOUNT_LEVERAGE =  %d",AccountInfoInteger(ACCOUNT_LEVERAGE));
   bool thisAccountTradeAllowed=AccountInfoInteger(ACCOUNT_TRADE_ALLOWED);
   bool EATradeAllowed=AccountInfoInteger(ACCOUNT_TRADE_EXPERT);
   ENUM_ACCOUNT_TRADE_MODE tradeMode=(ENUM_ACCOUNT_TRADE_MODE)AccountInfoInteger(ACCOUNT_TRADE_MODE);
   ENUM_ACCOUNT_STOPOUT_MODE stopOutMode=(ENUM_ACCOUNT_STOPOUT_MODE)AccountInfoInteger(ACCOUNT_MARGIN_SO_MODE);
 
//--- avisamos sobre la posibilidad de realizar las operaciones comerciales
   if(thisAccountTradeAllowed)
      Print("La actividad comercial para esta cuenta está permitida");
   else
      Print("La actividad comercial para esta cuenta está prohibida!");
 
//--- comprobamos si los expertos pueden comerciar en esta cuenta
   if(EATradeAllowed)
      Print("La actividad comercial usando los Asesores Expertos está permitida para esta cuenta");
   else
      Print("La actividad comercial usando los Asesores Expertos está prohibida para esta cuenta!");
 
//--- averiguamos el tipo de cuenta
   switch(tradeMode)
     {
      case(ACCOUNT_TRADE_MODE_DEMO):
         Print("Es una cuenta de demostración");
         break;
      case(ACCOUNT_TRADE_MODE_CONTEST):
         Print("Es una cuenta de concurso");
         break;
      default:Print("Es una cuenta real!");
     }
 
//--- averiguamos el régimen de establecimiento del nivel StopOut
   switch(stopOutMode)
     {
      case(ACCOUNT_STOPOUT_MODE_PERCENT):
         Print("El nivel StopOut se especifica en porcentaje");
         break;
      default:Print("El nivel StopOut se especifica en moneda");
     }
  }

Véase también

Información de cuenta


Actualizado: 2015.12.03