Asistente MQL5 - Basado en Señales de Trade de Hammer/Hanging Man + CCI - Asesor Experto para MetaTrader 5

El Asistente MQL5 permite crear EAs listos para usar basados en clases de la Librería Estándar entregadas junto con el terminal de cliente (para los detalles véase Creación de EAS listos para usar del asistente MQL5). Permite comprobar rápidamente tus ideas de trade, y todo lo que necesitas es crear tu propia clase de señales de trading. La estructura de esta clase y ejemplos pueden encontrarse en el artículo Asistente MQL5: Cómo Crear un Módulo de Trading.

La idea genérica es la siguiente: la clase de las señales de trading se deriva del CExpertSignal, y seguidamente, es necesario reemplazar los métodos virtuales LongCondition() y ShortCondition() por sus propios métodos.

Hay un libro "Estrategias de los mejores traders" (en ruso), donde se consideran muchas estrategias de trading, y nos centraremos en los patrones de velas de reversión, confirmados por los osciladores estocástico, RSI , CCI y MFI.

La mejor manera es crear la clase separada, derivada de CExpertSignal para el control de la formación de patrones de vela. Para la confirmación de las señales de trade, generados por los patrones de vela, es suficiente escribir la clase, derivada del CCandlePattern y añadir las características necesarias (por ejemplo, confirmación de osciladores).

Aquí tendremos en cuenta las señales, basadas en patrones de velas de reversión "martillo/colgante hombre" , confirmados por el indicador CCI . El módulo de señales de trade se basa en la clase CCandlePattern , es un simple ejemplo de su uso para creación de señales de trade con los patrones de velas.

1. Patrones de velas de reversión "Hammer" y "Hombre colgado"

1.1. Hammer

El "Hamer" es una vela con un cuerpo pequeño y mecha inferior larga, formada tras movimiento de los precios a la baja. El patrón "Hamer" indica el final de una tendencia bajista.

No importa el color del cuerpo de la vela, pero un hammer alcista indica mayor potencial alcista. El cuerpo del patrón "Hammer" muchas veces se forma cerca del mínimo de la vela anterior. La mecha inferior más larga y mecha superior mas corta conduce a un mayor potencial del patrón de reversión.

Fig. 1. Patrón de velas "Martillo"

El reconocimiento del patrón "Hamer" se implementa en el método CheckPatternHammer() de la clase CCandlePattern :

//+------------------------------------------------------------------+
//| comprobaciones en la formación de patrones de velas "Hammer"     |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHammer()
  {
//--- Hammer
   if((MidPoint(1)<CloseAvg(2))                                 && // down trend
      (MathMin(Open(1),Close(1))>(High(1)-(High(1)-Low(1))/3.0)) && // body in upper 1/3
      (Close(1)<Close(2)) && (Open(1)<Open(2)))                    // body gap
      return(true);
//---
   return(false);
  }

1.2. Hanging Man

El "Hanging Man" es una vela con un cuerpo pequeño y mecha inferior larga, formado después de movimiento alcista de precios. El patrón de "Hanging Man" indica el final de una tendencia alcista.

No importa el color del cuerpo de vela, pero una vela bajista indica mayor potencial bajista. El cuerpo del patrón del "Hanging Man" a menudo se forma cerca del máximo de la vela anterior. La mecha inferior más larga y mecha superior mas corta conduce a un mayor potencial del patrón de reversión.

Figura 2. Patrón de vela "Hanging Man"

El reconocimiento del patrón de "Hanging Man" se implementa en método CheckPatternHangingMan() la clase CCandlePattern :

//+------------------------------------------------------------------+
//| Comprobaciones en la formación de patrones de vela "Hanging Man" |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHangingMan()
  {
//--- Hanging man
   if((MidPoint(1)>CloseAvg(2))                                && // tendencia alcista
      (MathMin(Open(1),Close(1)>(High(1)-(High(1)-Low(1))/3.0)) && // body in upper 1/3
      (Close(1)>Close(2)) && (Open(1)>Open(2))))                  // gap del cuerpo
      return(true);
//---
   return(false);
  }

2. Señales de trade, confirmadas por el indicador CCI

Las señales de trading para abrir posiciones largas o cortas debe ser confirmadas por el indicador CCI. El valor del CCI debe ser mayor/menor que los niveles críticos (-50 para la posición larga y 50 para posición corta).

El cierre de posiciones abiertas depende de los valores del CCI. Se puede hacer en 2 casos:

1. Si la línea CCI ha alcanzado el nivel crítico opuesto (80 para la posición larga y -80 para posición corta
2. Si no está confirmada la señal de reversión (cuando el CCI alcanza los siguientes niveles: -80 para la posición larga y 80 para la posición corta)

Figura 3. El patrón de "Hammer", confirmado por EL indicador CCI

• int CH_HM_CCI::LongCondition() - comprueba las condiciones para abrir posición larga (regresa de 80) y el cierre de la posición corta (regresa de 40);
  
• int CH_HM_CCI::ShortCondition() - comprueba las condiciones para abrir posición corta (regresa de 80) y el cierre de la posición larga (regresa de 40).

2.1. Apertura de posición larga/cierre de posición corta

1. La formación del patrón "Hammer" debe ser confirmada por indicador CCI: CCI(1) < -50 (el valor del CCI de la última barra completa debe ser inferior a -50).

2. La posición corta debe estar cerrada si el indicador CCI ha cruzado hacia arriba del nivel crítico -80 o cruzado hacia abajo al nivel 80.

//+------------------------------------------------------------------------+
//| Comprueba las condiciones para la entrar y salir del mercado           |
//| 1) Entrada en el mercado (apertura de posición larga, resultado = 80)  |
//| 2) Salida del mercado (cierre de posición corta, resultado = 40)       |
//+------------------------------------------------------------------+
int CH_HM_CCI::LongCondition()
  {
   int result=0;
//--- idx se puede utilizar para determinar el modo de trabajo del EA
//--- idx=0 - en este caso el EA comprueba las condiciones de trade en cada tick
//--- idx=1 - en este caso el EA comprueba las condiciones de trade sólo en las barras nuevas
   int idx   =StartIndex();
//--- comprobación de condiciones para la apertura de posiciones largas
//--- formación del patron Hammer y CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) && (CCI(1)<-50))
     result=80;
//--- comprobación de condiciones para el cierre de posiciones cortas
//--- Cruce de linea de señal de niveles de sobrecompra / sobreventa (bajo -80, bajo -80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- devuelve resultado
   return(result);
  }

2.2. Apertura de corta/cierre de posición larga

1. La formación del patrón "Hanging Man" debe ser confirmada por el indicador CCI: CCI(1) > 50 (el valor del indicador CCI de la última barra completa debe ser mayor de 50).

2. La posición larga debe estar cerrada si el indicador CCI ha cruzado hacia abajo el -80 u 80 niveles.

//+----------------------------------------------------------------------+
//| Comprobando condiciones para la entrada o salida del mercado         |
//| 1) Entrada en el Mercado (apertura de posición corta, resultado=80)  |
//| 2) Salida del Mercado (cierre de posición corta, result=40)          |
//+----------------------------------------------------------------------+
int CH_HM_CCI::ShortCondition()
  {
   int result=0;
//--- idx se puede utilizar para determinar el modo de trabajo del EA
//--- idx=0 - en este caso el EA comprueba las condiciones de trade en cada tick
//--- idx=1 - en este caso el EA comprueba las condiciones de trade sólo en las barras nuevas
   int idx   =StartIndex();
//--- comprobación de condiciones para apertura de posiciones cortas
//--- formacion de patrones Hanging Man y CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) && (CCI(1)>50))
     result=80;
//--- comprobación de condiciones para el cierre de posiciones largas
//--- Cruce de linea de señal de niveles de sobrecompra / sobreventa (bajo -80, bajo -80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- devuelve resultado
   return(result);
  }

2.3. Creación del EA utilizando el Asistente MQL5

Para crear un EA lanzar el Asistente MQL5:

Fig. 4. Creación del EA utilizando el Asistente MQL5

Vamos a especificar el nombre del EA:

Fig. 5. Propiedades generales del EA

Después de esto tenemos que seleccionar los módulos de señales de trade utilizadas.

Fig. 6. Propiedades de la señal del EA

En nuestro caso utilizamos sólo un módulo de señales de trade.

Añadiendo el módulo de señales de trading "señales basadas en Hamer/Hanging Man confirmadas por CCI" :

Fig. 7. Propiedades de la señal del EA

Módulo de señales de trade añadido:

Fig. 8. Propiedades de la señal del EA

Puedes seleccionar cualquiera de las propiedades de trailing, pero usaremos "Trailing Stop no utilizado":

Fig. 9. Propiedades de trailing del EA

En cuanto a las propiedades del money management, vamos a usar "Trading con volumen de trade fijo":

Fig. 10. Propiedades de money management del EA

Pulsando el botón "Finish", obtendremos el código del EA generado, situado en Expert_AH_HM_CCI.mq5, se guardará en terminal_data_folder\MQL5\Experts\.

Los parámetros de entrada por defecto del EA generado:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Valor umbral de señal para abrir [0...100]
input int            Signal_ThresholdClose  =10;     // Valor umbral de señal para cerrar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nivel de precios para ejecutar una operación
input double         Signal_StopLevel       =50.0;   // Nivel de Stop Loss (en puntos)
input double         Signal_TakeLevel       =50.0;   //  Nivel de Take Profit (en puntos)

debe ser reemplazado por:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Valor umbral de señal para abrir [0...100]
input int            Signal_ThresholdClose  =20;     // Valor umbral de señal para cerrar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nivel de precios para ejecutar una operación
input double         Signal_StopLevel       =0.0;    // Nivel de Stop Loss (en puntos)
input double         Signal_TakeLevel       =0.0;    // Nivel de Take Profit (en puntos)

Los parámetros de entrada Signal_ThresholdOpen/Signal_ThresholdClose permiten especificar los niveles de umbral para abrir y cerrar posiciones.

En el código de los métodos LongCondition() y ShortCondition() de las clases de señales de trade hemos especificado los valores fijos del umbral:

• Abrir posición: 80;
• Cerrar posición: 40.
  

Los valores de los parámetros de entrada Signal_StopLevel y Signal_TakeLevel se establecen a 0, esto significa que el cierre de las posiciones se hará sólo cuando las condiciones de cierre sean ciertas.

2.4. Resultados de backtesting del histórico

Consideremos backtesting del EA en los datos históricos (EURUSD H1, periodo de pruebas: 2010.01.01-2011.03.16, PeriodCCI = 25, MA_period = 5).

En la creación de EA utilizamos el volumen fijo (Trading fija muchos, 0.1), el algoritmo Trailing Stop no se utiliza (Trailing no utilizado).

Fig. 11. Probando los resultados del EA, basado en Hammer/Hanging Man + CCI

Puede encontrar el mejor conjunto de parámetros de entrada utilizando el Probador de estrategias del terminal de cliente MetaTrader 5.

El código del EA, creado por el Asistente MQL5 se adjunta en expert_ah_hm_cci.mq5.