Скачать MetaTrader 5

Смотри, как бесплатно скачать роботов

Интересный скрипт?
Поставь на него ссылку - пусть другие тоже оценят

Понравился скрипт?
Оцени его работу в терминале MetaTrader 5

2011.03.18 15:45
Советники

Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + CCI - эксперт для MetaTrader 5

| Russian English 中文 Español Deutsch 日本語 Português

Просмотров:
1201
Рейтинг:
голосов: 14
\MQL5\Include\Expert\Signal\MySignals\

С появлением Мастера MQL5 появилась возможность автоматической генерации кода советника на базе классов торговых сигналов, сопровождения позиций и управления капиталом. Помимо классов торговых сигналов из Стандартной библиотеки, вы можете создавать и тестировать свои собственные торговые системы, для этого достаточно написать модуль торговых сигналов.

В книге "Стратегии лучших трейдеров мира" описаны индикаторы и торговые стратегии для технического анализа с использованием программного пакета MetaStock. Наряду с традиционными, в ней рассмотрены торговые сигналы, основанные на совместном использовании разворотных свечных моделей с подтверждением от осцилляторов Stochastic, CCI, MFI и RSI.

Использование "разворотных" свечных моделей совместно с сигналами осцилляторов позволяет сократить количество ложных сигналов и повысить эффективность торговой системы.

В данной работе мы рассмотрим результаты использования моделей Hammer ("Молот") и Hanging Man ("Повешенный") в комбинации с сигналами индикатора CCI.


1. Паттерны "Hammer" и "Hanging Man" и их распознавание

1.1. Паттерн "Молот" (Hammer)

Модель "Hammer" ("Молот") - свеча с маленьким телом и длинной нижней тенью, появившейся после нисходящей тенденции. Появление "Молота" - сильный сигнал того, что господство медвежьего рынка подходит к концу.

Цвет тела значения не имеет, однако бычий цвет молота имеет больший потенциал. Обычно "Молот" формируется вблизи минимума предыдущей свечи. Чем длиннее нижняя тень, чем короче верхняя тень и чем меньше тело, тем выше потенциал модели.

Рисунок 1. Свечной паттерн "Hammer"

Рисунок 1. Свечной паттерн "Hammer"

Распознавание паттерна "Hammer" ("Молот") реализовано в методе CheckPatternHammer класса CCandlePattern:

//+------------------------------------------------------------------+
//| Метод проверки формирования свечной модели "Hammer"              |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHammer()
  {
//--- Hammer - распознавание модели "Молот"
   if((MidPoint(1)<CloseAvg(2))                                && // нисходящий тренд (down trend)
      (MathMin(Open(1),Close(1))>High(1)-((High(1)-Low(1))/3.0)) && // тело в верхней трети свечи (body in upper 1/3)
      (Close(1)<Close(2)) && (Open(1)<Open(2)))                    // разрыв в ценах открытия/закрытия (body gap)
      return(true);
//---
   return(false);
  }

Для проверки факта формирования модели "Hammer" используется метод CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) класса CCandlePattern.


1.2. Паттерн "Повешенный" (Hanging Man)

Модель "Hanging Man" ("Повешенный") - свеча с маленьким телом и длинной нижней тенью, появившейся после восходящей тенденции. Появление "Повешенного" сигнализирует об окончании повышательной тенденции.

Цвет тела также значения не имеет, но медвежий цвет свечи имеет больший потенциал. Модель "Повешенный" обычно формируется вблизи максимума предыдущей свечи. Чем длиннее нижняя тень, чем короче верхняя тень и чем меньше тело, тем выше потенциал модели.

Рисунок 2. Свечной паттерн "Hanging Man"

Рисунок 2. Свечной паттерн "Hanging Man"

Метод распознавания модели "Hanging Man":

//+------------------------------------------------------------------+
//| Метод проверки формирования свечной модели "Hanging Man"         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHangingMan()
  {
//--- Hanging man - распознавание модели "Повешенный"
   if((MidPoint(1)>CloseAvg(2))                                && // восходящий тренд (up trend)
      (MathMin(Open(1),Close(1))>High(1)-((High(1)-Low(1))/3.0)) &&// тело в верхней трети свечи (body in upper 1/3)
      (Close(1)>Close(2)) && (Open(1)>Open(2)))                   // разрыв в ценах открытия/закрытия (body gap)
      return(true);
//---
   return(false);
  }

Для проверки факта формирования модели "Hanging Man" используется метод CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) класса CCandlePattern.


2. Торговые сигналы в комбинации с индикатором CCI

Сигналы для входа в рынок подаются при появлении соответствующей разворотной фигуры и достижением CCI уровня -50 для длинной и выше 50 для короткой позиции.

Сигналы выхода из позиций подаются только индикатором CCI. Это происходит в случае достижения им противоположного уровня (80 для длинной и -80 для короткой позиций) или же не подтверждает разворота и достигает нового минимума.

Рисунок 3. Торговые сигналы паттерна "Hammer" с подтверждением от индикатора CCI

Рисунок 3. Торговые сигналы паттерна "Hammer" с подтверждением от индикатора CCI

Реализация проверки условий входа и выхода в рынок осуществляется в методах:

  • int CH_HM_CCI::LongCondition() - проверка условий для открытия длинной позиции (ф-я возвращает 80) и закрытия короткой позиции (ф-я возвращает 40);
  • int CH_HM_CCI::ShortCondition() - проверка условий для открытия короткой позиции (ф-я возвращает 80) и закрытия длинной позиции (ф-я возвращает 40).

2.1. Открытие длинной позиции и закрытие короткой позиции

  1. Сигналом к открытию длинной позиции является формирование свечной комбинации "Hammer" ("Молот") и выполнение условия CCI (1)<-50 (значение индикатора CCI на последнем завершенном баре меньше -50).

  2. Сигналом к закрытию короткой позиции является пересечение индикатора CCI уровня -80 (сверху вниз) или уровня 80 (сверху вниз).

    //+------------------------------------------------------------------+
    //| Метод проверки условий для входа и выхода с рынка                |
    //| Проверка условий для                                             |
    //| 1) входа в рынок (открытие длинной позиции, result=80)           |
    //| 2) выхода из рынка (закрытие короткой позиции, result=40)        |
    //+------------------------------------------------------------------+
    int CH_HM_CCI::LongCondition()
      {
       int result=0;
    //--- idx можно использовать для того чтобы узнать режим работы эксперта
    //--- idx=0 - эксперт будет вызывать проверки выполнения торговых условий на каждом тике
    //--- idx=1 - эксперт будет вызывать проверки выполнения торговых условий только на новых барах
       int idx   =StartIndex();
    //--- проверка условий для открытия длинной позиции
    //--- формирование бычьей свечной комбинации Hammer и выполнения условия CCI<-50
       if(CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) && (CCI(1)<-50))
          result=80;
    //--- проверка условий для закрытия короткой позиции
       if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
          result=40;
    //--- возвращаем result
       return(result);
      }

2.2. Открытие короткой позиции и закрытие длинной позиции

  1. Сигналом к открытию короткой позиции является формирование паттерна "Hanging Man" ("Повешенный") и выполнение условия CCI(1)>50 (значение индикатора CCI на последнем завершенном баре больше 50).

  2. Сигналом к закрытию длинной позиции является пересечение индикатором CCI уровня 80 (сверху вниз) или уровня -80 (сверху вниз).

    //+------------------------------------------------------------------+
    //| Метод проверки условий для входа и выхода с рынка                |
    //| Проверка условий для                                             |
    //| 1) входа в рынок (открытие короткой позиции, result=80)          |
    //| 2) выхода из рынка (закрытие длинной позиции, result=40)         |
    //+------------------------------------------------------------------+
    int CH_HM_CCI::ShortCondition()
      {
       int result=0;
    //--- idx можно использовать для того чтобы узнать режим работы эксперта
    //--- idx=0 - эксперт будет вызывать проверки выполнения торговых условий на каждом тике
    //--- idx=1 - эксперт будет вызывать проверки выполнения торговых условий только на новых барах
       int idx   =StartIndex();
    //--- проверка условий для открытия короткой позиции
    //--- формирование медвежьей свечной комбинации Hanging Man и выполнения условия CCI>50
       if(CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) && (CCI(1)>50))
         result=80;
    //--- проверка условий для закрытия длинной позиции
       if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
         result=40;
    //--- возвращаем result
       return(result);
      }

2.3. Создание эксперта на основе торговых сигналов разворотной модели "Hammer/Hanging Man + CCI" при помощи Мастера MQL5

Класс CH_HM_CCI не входит в Стандартную библиотеку классов торговых сигналов, поэтому для его использования нужно скачать файл ach_hm_cci.mqh (прилагается) и сохранить его в каталог_данных_терминала\Include\Expert\Signal\MySignals. Файл acandlepatterns.mqh следует скопировать в тот же каталог, что и файл ach_hm_cci.mqh. После этого, перезапустив MetaEditor, вы получите возможность его использования в Мастере MQL5.

Чтобы создать торгового робота по данной стратегии запустите Мастер MQL5:

Рис. 4. Создание советника в Мастере MQL5

Рис. 4. Создание советника в Мастере MQL5

Нажав на кнопку "Далее", укажем имя советника:

Рис. 5. Общие параметры советника

Рис. 5. Общие параметры советника

После этого нужно указать параметры сигналов.

Рис. 6. Параметры сигналов советника

Рис. 6. Параметры сигналов советника

В нашем случае мы будем использовать лишь один модуль торговых сигналов.

Добавляем модуль "Signals based on Hammer/Hanging Man confirmed by CCI":

Рис. 7. Параметры сигналов советника

Рис. 7. Параметры сигналов советника

Модуль сигналов добавлен:

Рис. 8. Параметры сигналов советника

Рис. 8. Параметры сигналов советника

После этого можно выбрать модуль трейлинга, мы его использовать не будем. Выбираем "Trailing Stop not used":

Рис. 9. Выбор модуля трейлинга

Рис. 9. Выбор модуля трейлинга

Затем нужно выбрать модуль управления капиталом, мы будем использовать торговлю с фиксированным объемом (Trading with fixed trade volume):

Рис. 10. Выбор модуля управления капиталом

Рис. 10. Выбор модуля управления капиталом

Нажав на кнопку "Готово", мы получим код сгенерированного советника - файл Expert_AH_HM_CCI.mq5, который будет сохранен в папке: каталог_данных_терминала\MQL5\Experts\.

Входные параметры (по умолчанию) советника:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

заменяем на:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Параметры Signal_ThresholdOpen и Signal_ThresholdClose позволяют задать пороги для открытия и закрытия позиций.

В коде функций LongCondition() и ShortCondition() модуля торговых сигналов мы указали фиксированные значения порогов:

  • Для открытия позиций: 80;
  • Для закрытия позиций: 40.

Советник, сгенерированный при помощи Мастера MQL5, принимает решение об открытии или закрытии позиции на основании результатов "голосования" модулей торговых сигналов, добавленных в процессе создания советника. При этом основной модуль (содержащий все добавленные модули) торговых сигналов также принимает участие в "голосовании", однако его методы LongCondition() и ShortCondition() всегда возвращают 0.

Поскольку при расчете "голосов" производится усреднение по количеству присутствующих модулей (основной + один добавленный модуль), то значения порогов следует указывать с учетом данного обстоятельства. По этой причине значения величин Signal_ThresholdOpen и Signal_ThresholdClose должны быть установлены в 40=(0+80)/2 и 20=(0+40)/2 соответственно.

Значения входных параметров Signal_StopLevel и Signal_TakeLevel устанавливаем в 0, это означает, что закрытие позиций будет осуществляться только при поступлении торговых сигналов на закрытие позиций.


2.4 Результаты тестирования на истории

Результаты тестирования советника на исторических данных (EURUSD H1, период тестирования: 2010.01.01-2011.03.16, PeriodCCI=25, MA_period=5).

В данном советнике использовался модуль торговли фиксированным объемом 0.1 лота (Trading Fixed Lot), трейлинг не использовался (Trailing not used).

Рис. 11. Результаты тестирования советника, построенного на базе генератора торговых сигналов "Hammer/Hanging Man + CCI"

Рис. 11. Результаты тестирования советника, построенного на базе генератора торговых сигналов "Hammer/Hanging Man + CCI"

Наилучший набор параметров торговой системы можно найти при помощи Тестера Стратегий терминала MetaTrader 5.

Код советника, созданного Мастером MQL5, прилагается в файле expert_ah_hm_cci.mq5.


Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + Stochastic Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + Stochastic

Торговые сигналы свечных моделей "Hammer/Hanging Man" ("Молот"/"Повешенный") с подтверждением от индикатора Stochastic.

Мастер MQL5 - Торговые сигналы свечных паттернов Bullish Harami/Bearish Harami + RSI Мастер MQL5 - Торговые сигналы свечных паттернов Bullish Harami/Bearish Harami + RSI

Торговые сигналы свечных моделей "Bullish Harami/Bearish Harami" (Бычья и медвежья модели Харами) с подтверждением от индикатора RSI.

Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + MFI Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + MFI

Торговые сигналы свечных моделей "Hammer/Hanging Man" ("Молот"/"Повешенный") с подтверждением от индикатора MFI.

Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + RSI Мастер MQL5 - Торговые сигналы свечных паттернов Hammer/Hanging Man + RSI

Торговые сигналы свечных моделей "Hammer/Hanging Man" ("Молот"/"Повешенный") с подтверждением от индикатора RSI.