Assistente MQL5 - Sinais de negociação baseado em Engolfo de Alta/Engolfo de baixa + RSI - expert para MetaTrader 5

O Assistente MQL5 permite a criação de Expert Advisors pronto para uso com base nas classes da Biblioteca padrão fornecidas no terminal do cliente (ver Criando Expert Advisors prontos no Assistente MQL5 para maiores detalhes). Ele permite verificar suas ideias de negociação de forma rápida, tudo o que você precisa é criar sua classe personalizada de sinais de negociação. A estrutura desta classe e os exemplos podem ser encontrados no artigo Assistente MQL5: Como criar um Módulo de Sinais de Negociação.

Em geral, a ideia é a seguinte: a classe de sinais de negociação é derivada de CExpertSignal, então, é necessário sobrescrever os métodos virtuais LongCondition() e ShortCondition() com seus próprios métodos.

No livro "Estratégias dos melhores Traders" (em Russo), podemos encontrar várias estratégias de negociação, por hora focaremos nos padrões de velas de reversão , e confirmado pelos osciladores Estocástico, CCI, MFI e RSI.

A melhor maneira de proceder é criando uma classe separada, derivada de CExpertSignal para verificar a formação dos padrões de velas. Para confirmar os sinais de negociação, gerado pelos padrões de velas, é suficiente escrever uma classe, derivada de CCandlePattern e adicionar as características necessárias nela (por exemplo, confirmação por osciladores).

Neste artigo, consideraremos os sinais com base no padrão de velas de reversão "Engolfo de alta/Engolfo de baixa", confirmado pelo indicador RSI. O módulo de sinais de negociação, baseado na classe CCandlePattern, é um simples exemplo de seu uso na geração de sinais de negociação por meio dos padrões de velas.

1. Padrões de velas de reversão "Engolfo de alta" e "Engolfo de baixa"

1.1. Engolfo de alta

O padrão de reversão "Engolfo de alta" se forma em tendências baixistas quando uma pequena vela negra é seguida por uma grande vela branca, que envolve completamente ("engolfa") a vela anterior. As sombras (caudas) da pequena vela são curtas, o que permite que o corpo da grande vela cubra completamente a vela anterior.

Fig. 1. Padrão de vela "Engolfo de alta"

O reconhecimento do padrão "Engolfo de alta" está implementado no método CheckPatternBullishEngulfing() da classe CCandlePattern:

//+------------------------------------------------------------------+
//| Verifica a formação do padrão de vela "Engolfo de alta"          |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishEngulfing()
  {
//--- Engolfo de alta
   if((Open(2)>Close(2))             &&  // vela anterior é baixista
      (Close(1)-Open(1)>AvgBody(1))  &&  // o corpo da vela altista é maior que o valor médio de seu corpo
      (Close(1)>Open(2))             &&  // o preço de fechamento da vela altista é maior que o preço de abertura da vela baixista
      (MidOpenClose(2)<CloseAvg(2))  &&  // tendência de baixa
      (Open(1)<Close(2)))                // preço de abertura da vela altista é menor que o preço de fechamento da vela baixista
      return(true);
//---
   return(false);
  }

1.2. Engolfo de baixa

O padrão de reversão "Engolfo de baixa" se forma em tendências altistas quando uma pequena vela branca é seguida de um grande vela preta, que envolve completamente ("engolfa") a vela anterior. As sombras (caudas) da pequena vela são curtas, o que permite que o corpo da grande vela cubra completamente a vela anterior.

Figura 2. Padrão de vela "Engolfo de baixa"

O reconhecimento do padrão "Engolfo de baixa" está implementado no método CheckPatternBearishEngulfing() da classe CCandlePattern:

//+------------------------------------------------------------------+
//| Verifica a formação do padrão de vela "Engolfo de baixa"         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishEngulfing()
  {
//--- Engolfo de baixa
   if((Open(2)<Close(2))            &&  // vela anterior é baixista
      (Open(1)-Close(1)>AvgBody(1)) &&  // o corpo da vela é maior que valor médio de seu corpo
      (Close(1)<Open(2))            &&  // o preço de fechamento da vela baixista é menor que o preço de abertura da vela altista
      (MidOpenClose(2)>CloseAvg(2)) &&  // tendência de alta
      (Open(1)>Close(2)))               // preço de abertura da vela baixista é maior que o preço de fechamento da vela altista
      return(true);
//---
   return(false);
  }

2. Sinais de negociação, confirmado pelo indicador RSI

O sinais de negociação para abrir posições de compra ou venda deve ser confirmado pelo indicador RSI. O valor de RSI deve ser menor/maior que os níveis críticos (40 para posição comprada e 60 para posição vendida).

O fechamento da posição em aberto depende dos valores do indicador RSI. Ele pode ser feito em 2 casos:

1. Se o RSI atingiu o nível crítico oposto (70 para posição comprada e 30 para posição vendida)
2. Se o sinal reverso não foi confirmado (quando o indicador RSI atinge os seguintes níveis: 30 para posição comprada e 70 para posição vendida)

Fig. 3. Padrão "Engolfo de alta", confirmado pelo indicador RSI

• int CBE_BE_RSI::LongCondition() - verifica as condições de abertura de posição comprada (retorna 80) e o fechamento da posição vendida (retorna 40);
  
• int CBE_BE_RSI::ShortCondition() - verifica as condições de abertura de posição vendida (retorna 80) e o fechamento da posição comprada (retorna 40).

2.1. Abertura de posição comprada/fechamento de posição vendida

1. A formação do padrão "Engolfo de alta" deve ser confirmado pelo indicador RSI: RSI(1)<40 (o valor do indicador RSI da última barra completa deve ser inferior a 40).

2. A posição vendida deve ser fechada se o indicador RSI cruzou acima dos níveis críticos (70 ou 30).

//+---------------------------------------------------------------------------+
//| Verifica as condições de entrada e saída do mercado                       |
//| 1) Entrada no mercado (abertura de posição comprada, resultado=80)        |
//| 2) Saída do mercado (fechamento de posição vendida, resultado=40)         |
//+---------------------------------------------------------------------------+
int CBE_BE_RSI::LongCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de funcionamento do Expert Advisor
//--- idx=0 - neste caso o EA verifica as condições de negociação a cada tick
//--- idx=1 - neste caso o EA verifica as condições de negociação somente quando há novas barras
   int idx   =StartIndex();
//--- verificando as condições de abertura de posição comprada
//--- formação do padrão Engolfo de alta e RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_ENGULFING) && (RSI(1)<40))
     result=80;
//--- verificando as condições de fechamento da posição vendida
//--- cruzamento da linha de sinal nos níveis de sobrecompra/sobrevenda (acima de 30, acima de 70)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- retorna o resultado
   return(result);
  }

2.2. Abertura de posição vendida/fechamento de posição comprada

1. A formação do padrão "Engolfo de baixa" deve ser confirmado pelo indicador RSI: RSI(1)>60 (o valor do indicador RSI da última barra completa deve ser superior a 60).

2. A posição comprada deve ser fechada se o indicador RSI cruzou abaixo dos níveis críticos (70 ou 30).

//+------------------------------------------------------------------------+
//| Verifica as condições de entrada e saída do mercado                    |
//| 1) Entrada no mercado (abertura de posição vendida, resultado=80)      |
//| 2) Saída do mercado (fechamento de posição comprada, resultado=40)     |
//+------------------------------------------------------------------------+
int CBE_BE_RSI::ShortCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de funcionamento do Expert Advisor
//--- idx=0 - neste caso o EA verifica as condições de negociação a cada tick
//--- idx=1 - neste caso o EA verifica as condições de negociação somente quando há novas barras
   int idx   =StartIndex();
//--- verificando as condições de abertura de posição vendida
//--- formação do padrão Engolfo de baixa e RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_ENGULFING) && (RSI(1)>60))
     result=80;
//--- verificando as condições de fechamento de posição comprada
//--- cruzamento da linha de sinal nos níveis de sobrecompra/sobrevenda (abaixo de 70, abaixo de 30)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- retorna o resultado
   return(result);
  }

2.3. Criando o Expert Advisor usando o Assistente MQL5

Para criar um Expert Advisor inicie o Assistente MQL5:

Fig. 4. Criando o Expert Advisor usando o Assistente MQL5

Vamos especificar o nome do Expert Advisor:

Fig. 5. Propriedades gerais do Expert Advisor

Após isso, precisamos selecionar os módulos dos sinais de negociação usados.

Fig. 6. Propriedades de sinais do Expert Advisor

Em nosso caso usaremos apenas um módulo de sinais de negociação.

Adicionando o módulo de sinais de negociação "Sinais baseado no Engolfo de alta/Engolfo de baixa e confirmado pelo RSI":

Fig. 7. Propriedades de sinais do Expert Advisor

Módulo de sinais de negociação adicionado:

Fig. 8. Propriedades de sinais do Expert Advisor

Você pode selecionar qualquer propriedade de trailing, mas nós usaremos "Trailing Stop não utilizado":

Fig. 9. Propriedades de Trailing do Expert Advisor

Em relação às propriedades de gerenciamento de capital, usaremos "Negociação com volume fixo":

Fig. 10. Propriedades do gerenciamento de capital do Expert Advisor

Ao pressionar o botão "Finalizar", obteremos o código gerado do Expert Advisor, de nome Expert_ABE_BE_RSI.mq5, localizado na pasta terminal_data_folder\MQL5\Experts\.

Parâmetros de entrada padrâo do Expert Advisor gerado:

//--- entradas do sinal principal
input int            Signal_ThresholdOpen   =10;     // Valor do sinal de abertura [0...100]
input int            Signal_ThresholdClose  =10;     // Valor do sinal de fechamento [0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para a execução do negócio
input double         Signal_StopLevel       =50.0;   // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =50.0;   // Nível de Take Profit (em pontos)

deve ser substituído por:

//--- entradas do sinal principal
input int            Signal_ThresholdOpen   =40;     // Valor do sinal de abertura [0...100]
input int            Signal_ThresholdClose  =20;     // Valor do sinal de fechamento [0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para a execução do negócio
input double         Signal_StopLevel       =0.0;    // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =0.0;    // Nível de Take Profit (em pontos)

Os parâmetros de entrada Signal_ThresholdOpen/Signal_ThresholdClose permitem especificar os valores dos níveis de abertura e fechamento de posições.

No código dos métodos LongCondition() e ShortCondition() da classe de sinais de negociação, nós especificamos os valores fixos das limiares:

• Abertura de posição: 80;
• Fechamento da posição: 40.
  

Os valores dos parâmetros de entrada de Signal_StopLevel e Signal_TakeLevel está definido com o valor 0, isto significa que o fechamento das posições será executado apenas quando as condições de fechamento forem verdadeiras.

2.4. Resultados do backtesting com dados históricos

Vamos considerar o backtesting com dados históricos do Expert Advisor como sendo (EURUSD H1, período de teste: 2010.01.01-2011.03.04, PeriodRSI=11, MA_period=5).

Na criação do Expert Advisor usaremos o volume fixo (Negociação com lote fixo, 0.1), o algoritmo de Trailing Stop não é usado (Trailing não utilizado).

Fig. 11. Resultados do teste com o Expert Advisor, baseado em Engolfo de alta/Engolfo de baixa + RSI

O melhor conjunto dos parâmetros de entrada podem ser encontrado utilizando o Strategy Tester do terminal cliente MetaTrader 5.

O código do Expert Advisor, criado pelo Assistente MQL5 se encontra em anexo em expert_abe_be_rsi.mq5.