MQL5 リファレンス日付と時刻TimeLocal

TimeLocal

클라이언트 터미널이 실행 중인 시스템의 로컬 시간을 반환. 함수의 2가지 변수가 있습니다.

매개변수 없이 호출

datetime TimeLocal();

MqlDateTime 유형 매개변수를 사용하여 호출

datetime  TimeLocal(
   MqlDateTime&  dt_struct      // 구조 유형의 변수
   );

매개변수

dt_struct

[out] 구조 유형의 변수 MqlDateTime.

값 반환

datetime 유형의 값

주의

MqlDateTime 구조 유형 변수가 매개변수로 전달된 경우 그에 따라 채워집니다.

고해상도 카운터 및 타이머를 정렬하려면 밀리초 단위의 값을 생성하는 GetTickCount() 함수를 사용합니다.

전략 테스터에서 테스트하는 동안 TimeLocal()은 항상 TimeCurrent() 시뮬레이션된 서버 시간과 같습니다.

예:

void OnStart()
  {
//--- PC 로컬 시간 데이터로 채워질 MqlDateTime 변수를 선언합니다.
   MqlDateTime tm={};
   datetime    time1=TimeLocal();   // 첫 번째 호출 형식: PC 로컬 시간
   datetime    time2=TimeLocal(tm); // 두 번째 호출 형식: MqlDateTime 구조를 채우는 PC 로컬 시간

//--- PC 로컬 시간을 수신하고 로그의 해당 데이터로 구조를 채운 결과를 표시합니다.
   PrintFormat("Local time: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)",
               (string)time1, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week, EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week));
  /*
  결과:
   Local time: 2024.04.18 19:44:09
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 19
   - Min: 44
   - Sec: 09
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
  */
  }

TimeTradeServer

TimeGMT