MQL5 リファレンス日付と時刻TimeToStruct

TimeToStruct

날짜 시간 유형의 값(1970년 1월 1일 이후의 초 단위 시간)을 구조 변수 MqlDateTime으로 반환.

bool  TimeToStruct(
   datetime      dt,            // 날짜 및 시간
   MqlDateTime&  dt_struct      // 가치의 채택을 위한 구조
   );

매개변수

[in] 변환할 날짜 값.

dt_struct

[out] 구조 유형 MqlDateTime의 변수.

값 반환

성공하면 true, 실패하면 false. 오류에 대한 정보를 얻으려면 GetLastError() 함수를 호출.

예:

void OnStart()
  {
//--- 서버의 마지막으로 알려진 시간을 가져오고 날짜/시간 구조를 선언하고 구조 필드를 채웁니다.
   datetime    time=TimeCurrent();
   MqlDateTime tm  ={};
   if(!TimeToStruct(time,tm))
      Print("TimeToStruct() failed. Error ", GetLastError());

//--- 획득한 서버 시간과 TimeToStruct()를 사용하여 MqlDateTime 구조를 채운 결과를 로그에 표시합니다.
   PrintFormat("Server time: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)",
               (string)time, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week, EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week));
  /*
  결과:
   Server time: 2024.04.18 15:47:27
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 15
   - Min: 47
   - Sec: 27
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
  */
  }

TimeGMTOffset

StructToTime