Download all ticks of a symbol's history - Asesor Experto para MetaTrader 5

También necesitaremos leer y escribir en el disco duro y como estamos trabajando con símbolos creamos 2 funciones rápidas para escribir y leer cadenas desde ficheros binarios.

Escribe una longitud entera de cuántos caracteres hay en la cadena y luego almacena cada carácter en la cadena.

La función cargar cadena desde archivo:

string readStringFromFile(int f)
  {
   string result="";
//cargar cadena de símbolos
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

Procede a leer cada carácter en una matriz de caracteres y luego crea una cadena a partir de esa matriz de caracteres que se devuelve como resultado de la carga como cadena.

Volvamos a la estructura CDownloadManager . Necesitamos una forma de inicializar el gestor y llenarlo desde el market watch:

   //+------------------------------------------------------------------+
   //| coger símbolos de la vigilancia del mercado|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //! solo desde el mw !
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

Esta es la parte del código que realiza la descarga en el temporizador:

//+------------------------------------------------------------------+
//|Temporizador|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- si está sincronizado
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- carga el sistema aquí
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- sistema cargado por lo que estamos escaneando un símbolo aquí
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- carga de ticks

         //--- encuentra primero el tick más antiguo disponible en el broker
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- en este punto tenemos el tick más antiguo
         //--- empezar a pedir ticks del más antiguo al más reciente
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- recibe la hora del último tick para este símbolo almacenado en symbol_time
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- solicitar un nuevo lote comenzando desde la hora más antigua con el límite de ticks especificado
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- si sacamos un nuevo lote actualizamos nuestros tiempos descargados
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- timeout server requests , alteralo si quieres
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- actualizar el gestor y seguir adelante
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- tome los símbolos de vigilancia del mercado para iniciar la descarga
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }