Download all ticks of a symbol's history - MetaTrader 5용 expert

또한 하드 드라이브에 읽고 쓸 필요가 있으며 심볼로 작업하기 때문에 바이너리 파일에서 문자열을 쓰고 읽는 두 가지 빠른 함수를 만듭니다.

문자열에 몇 개의 문자가 있는지 정수 길이로 기록한 다음 각 문자를 문자열에 저장합니다.

파일에서 문자열 로드 함수:

string readStringFromFile(int f)
  {
   string result="";
//로드 심볼 문자열
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

이 함수는 파일의 해당 지점에서 예상되는 문자 수를 정수 길이로 읽고, 각 문자를 문자 배열로 읽은 다음 해당 문자 배열에서 문자열을 생성하여 로드 결과로 문자열로 반환합니다.

CDownloadManager 구조체로 돌아갑니다. 매니저를 초기화하고 마켓 워치에서 채우는 방법이 필요합니다:

   //+------------------------------------------------------------------+
   //| 마켓 워치에서 심볼 잡기|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //! 오직 MW에서만!
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

이것이 타이머에 대한 다운로드를 수행하는 코드의 일부입니다:

//+------------------------------------------------------------------+
//|타이머|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- 동기화된 경우
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- 여기에 시스템을 로드합니다.
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- 시스템이 로드되었으므로 여기서 심볼을 스캔합니다.
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- 틱 로드

         //--- 먼저 브로커에서 사용 가능한 가장 오래된 틱을 찾습니다.
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- 이 시점에서 가장 오래된 틱이 있습니다.
         //--- 가장 오래된 것부터 최신 것까지 틱을 요청하기 시작합니다.
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- 심볼_시간에 저장된 이 심볼의 마지막 틱 시간을 수신합니다.
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- 지정된 틱 제한을 사용하여 가장 오래된 시간부터 새 배치를 요청합니다.
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- 새 배치 업데이트를 가져오는 경우 다운로드 시간
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- 서버 요청 시간 초과 , 원하는 경우 변경하십시오.
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- 관리자를 업데이트하고 계속 진행합니다.
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- 마켓워치 심볼을 잡고 다운로드를 시작하세요.
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }