Download all ticks of a symbol's history - MetaTrader 5EA

我们还需要读取和写入硬盘，由于我们使用的是符号，因此我们创建了 2 个快速函数，用于从二进制文件中写入和读取字符串。

写入字符串中字符个数的整数长度，然后将每个字符存储到字符串中。

从文件加载字符串函数：

string readStringFromFile(int f)
  {
   string result="";
//load symbol string
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

它读取一个整数长度，该长度表示在文件中的这一点有多少个字符。它继续将每个字符读入一个字符数组，然后从该字符数组中创建一个字符串，并将字符串作为字符串加载的结果返回。

回到 CDownloadManager 结构。我们需要一种方法来初始化管理器，并从市场观察中填充它：

   //+------------------------------------------------------------------+
   //| 从市场观察中抓取符号|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //仅从 MW ！
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

这部分代码在定时器上进行下载：

//+------------------------------------------------------------------+
//| 定时器|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- 如果同步
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- 在此加载系统
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- 系统已加载，因此我们在这里扫描一个符号
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- 标记加载

         //--- 先找到经纪商中可用的最老的刻度线
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //---------------------此时我们有了最老的刻度
         //-----------------开始从最旧到最新请求刻度
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- 接收存储在 symbol_time 中的该符号最后一次跳动的时间
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- 申请新的批次，从最旧的时间开始，并指定刻度限制
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- 如果我们提取新的批次，更新我们的下载时间
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- 服务器请求超时，如果需要可以修改
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- 更新管理器并继续
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- 抓取市场观察符号开始下载
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }