Download all ticks of a symbol's history - expert pour MetaTrader 5

Nous aurons également besoin de lire et d'écrire sur le disque dur et, puisque nous travaillons avec des symboles, nous créons deux fonctions rapides pour écrire et lire des chaînes de caractères à partir de fichiers binaires.

Elle écrit une longueur entière correspondant au nombre de caractères contenus dans la chaîne, puis stocke chaque caractère dans la chaîne.

La fonction load string from file (charger la chaîne de caractères du fichier) :

string readStringFromFile(int f)
  {
   string result="";
//chargement de la chaîne de symboles
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

Elle lit une longueur entière indiquant le nombre de caractères attendus à cet endroit du fichier. Elle lit chaque caractère dans un tableau de caractères, puis crée une chaîne de caractères à partir de ce tableau de caractères, qui est renvoyée en tant que résultat de la fonction load as a string (charger une chaîne de caractères).

Revenons à la structure CDownloadManager . Nous avons besoin d'un moyen d'initialiser le gestionnaire et de le remplir à partir de la veille du marché :

   //+------------------------------------------------------------------+
   //| saisir les symboles de la surveillance du marché|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      // ! uniquement à partir du mw !
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

Voici la partie du code qui exécute le téléchargement sur la minuterie :

//+------------------------------------------------------------------+
//|Timer|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- si synchronisé
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- charger le système ici
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- le système est chargé, nous analysons donc un symbole ici
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- tick load

         //--- recherche d'abord le plus ancien tick disponible dans le broker
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000 ;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- à ce stade, nous avons la plus ancienne tique
         //--- commencer à demander des ticks du plus ancien au plus récent
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- reçoit l'heure du dernier tick pour ce symbole stocké dans symbol_time
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- demande un nouveau lot à partir de l'heure la plus ancienne avec la limite de ticks spécifiée
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- si nous tirons un nouveau lot, nous mettons à jour les temps téléchargés
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- délai d'attente pour les requêtes du serveur, modifiez-le si vous le souhaitez
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- mettre à jour le gestionnaire et continuer
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- saisir les symboles de surveillance du marché pour commencer le téléchargement
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }