Download all ticks of a symbol's history - sistema esperto per MetaTrader 5

Avremo anche bisogno di leggere e scrivere sul disco rigido e, dato che stiamo lavorando con i simboli, creiamo 2 funzioni rapide per scrivere e leggere stringhe da file binari.

Scrive un numero intero di caratteri presenti nella stringa e poi memorizza ogni carattere nella stringa.

La funzione di caricamento della stringa dal file:

string readStringFromFile(int f)
  {
   string result="";
//caricare la stringa di simboli
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

Legge un numero intero di lunghezza che indica quanti caratteri ci si deve aspettare in quel punto del file. Procede alla lettura di ogni carattere in un array di caratteri e quindi crea una stringa da quell'array di caratteri che viene restituita come risultato del caricamento come stringa.

Torniamo alla struttura CDownloadManager. Abbiamo bisogno di un modo per inizializzare il gestore e riempirlo dall'orologio di mercato:

   //+------------------------------------------------------------------+
   //| prendere i simboli dall'orologio di mercato|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //! solo dalla mw !
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

Questa è la parte di codice che esegue il download sul timer:

//+------------------------------------------------------------------+
//Timer|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- se sincronizzato
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- caricare il sistema qui
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- sistema caricato, quindi stiamo analizzando un simbolo qui
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- carico dei tick

         //--- trova prima il tick più vecchio disponibile nel broker
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- a questo punto abbiamo il tick più vecchio
         //--- iniziare a richiedere i tick dal più vecchio al più recente
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- ricevere l'ora dell'ultimo tick per questo simbolo memorizzato in symbol_time
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- richiedere un nuovo batch partendo dal tempo più vecchio con il limite di ticks specificato
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- se si estrae un nuovo lotto si aggiornano i tempi scaricati
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- timeout delle richieste del server, modificarlo se si vuole
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //-- aggiornare il gestore e andare avanti
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- prendere i simboli di market watch per avviare il download
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }