Download all ticks of a symbol's history - эксперт для MetaTrader 5

Нам также понадобится читать и записывать данные на жесткий диск, и поскольку мы работаем с символами, мы создадим 2 быстрые функции для записи и чтения строк из бинарных файлов.

Она записывает целое число длины, показывающее, сколько символов в строке, а затем сохраняет каждый символ в строке.

Функция загрузки строки из файла:

string readStringFromFile(int f)
  {
   string result="";
// загрузите строку символов
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

Считывается целое число длины, указывающее, сколько символов ожидается в данной точке файла. Далее происходит считывание каждого символа в массив char и создание строки из этого массива char, которая возвращается как результат загрузки в виде строки.

Вернемся к структуре CDownloadManager. Нам нужен способ инициализации менеджера и его наполнения из маркет-чата:

   //+------------------------------------------------------------------+
   //| Захватывайте символы с рынка.|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //! только с mw!
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

Это часть кода, выполняющая загрузку по таймеру:

//+------------------------------------------------------------------+
//|Таймер|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- если синхронизированы
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- загрузите систему здесь
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- система загружена, поэтому мы сканируем символ здесь
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- загрузка тика

         //--- сначала найдите самый старый тик, доступный в брокере
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- в этот момент у нас есть самый старый тик
         //--- начните запрашивать тики от самого старого к самому новому
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- получаем время последнего тика для этого символа, хранящееся в symbol_time
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- запросите новую партию, начиная с самого старого времени с указанным лимитом тиков
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- если мы получим новую партию, обновите время загрузки.
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- таймаут запросов к серверу, измените его, если хотите
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- обновите менеджера и двигайтесь дальше
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- захватите символы наблюдения за рынком, чтобы начать загрузку
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }