Download all ticks of a symbol's history - Experte für den MetaTrader 5

Da wir mit Symbolen arbeiten, erstellen wir 2 schnelle Funktionen, um Strings aus Binärdateien zu lesen und zu schreiben.

Sie schreibt eine ganzzahlige Länge, die angibt, wie viele Zeichen die Zeichenkette hat, und speichert dann jedes Zeichen in der Zeichenkette.

Die Funktion load string from file:

string readStringFromFile(int f)
  {
   string result="";
//Zeichenfolge laden
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

Sie liest eine ganzzahlige Länge, die angibt, wie viele Zeichen an dieser Stelle in der Datei zu erwarten sind, liest jedes Zeichen in ein char-Array und erstellt dann aus diesem char-Array einen String, der als Ergebnis des Ladevorgangs als String zurückgegeben wird.

Zurück zur CDownloadManager-Struktur. Wir brauchen eine Möglichkeit, den Manager zu initialisieren und ihn mit Daten aus der Marktüberwachung zu füllen:

   //+------------------------------------------------------------------+
   //| Symbole aus der Marktbeobachtung übernehmen|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //! nur von der mw !
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

Dies ist der Teil des Codes, der das Herunterladen mit dem Timer durchführt:

//+------------------------------------------------------------------+
//|Timer|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- wenn synchronisiert
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- das System hier laden
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- System geladen, daher wird hier ein Symbol gescannt
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- tick load

         //--- zuerst den ältesten im Broker verfügbaren Tick suchen
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- zu diesem Zeitpunkt haben wir den ältesten Tick
         //--- Beginn der Abfrage von Ticks vom ältesten zum neuesten
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- empfange die Zeit des letzten Ticks für dieses Symbol, gespeichert in symbol_time
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- Anforderung einer neuen Charge ab der ältesten Zeit mit der angegebenen Tickgrenze
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- wenn wir einen neuen Stapel ziehen, aktualisieren wir die heruntergeladenen Zeiten
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- Zeitüberschreitung bei Serveranfragen, ändern Sie diese, wenn Sie wollen
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- den Manager aktualisieren und weitermachen
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- Wählen Sie die Marktbeobachtungssymbole, um den Download zu starten
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }