Download all ticks of a symbol's history - expert para MetaTrader 5

Também precisaremos ler e gravar no disco rígido e, como estamos trabalhando com símbolos, criamos duas funções rápidas para gravar e ler strings de arquivos binários.

Ela escreve um comprimento inteiro de quantos caracteres há na cadeia e, em seguida, armazena cada caractere na cadeia.

A função carregar cadeia de caracteres do arquivo:

string readStringFromFile(int f)
  {
   string result="";
//carregar string de símbolo
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

Ele lê um comprimento inteiro de quantos caracteres devem ser esperados naquele ponto do arquivo, lê cada caractere em uma matriz de caracteres e, em seguida, cria uma cadeia de caracteres a partir dessa matriz de caracteres, que é retornada como resultado do carregamento como uma cadeia de caracteres.

De volta à estrutura do CDownloadManager. Precisamos de uma maneira de inicializar o gerenciador e preenchê-lo a partir da observação do mercado:

   //+------------------------------------------------------------------+
   //| pegar símbolos da observação do mercado|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //! somente do mw !
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

Essa é a parte do código que realiza o download no cronômetro:

//+------------------------------------------------------------------+
//|Timer|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- se sincronizado
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- carregar o sistema aqui
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- sistema carregado, portanto, estamos verificando um símbolo aqui
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- tick load

         //--- encontre primeiro o tique mais antigo disponível no corretor
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- nesse ponto, temos o tique mais antigo
         //--- comece a solicitar ticks do mais antigo para o mais recente
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- recebe a hora do último tique para esse símbolo armazenado em symbol_time
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- solicitar um novo lote a partir do tempo mais antigo com o limite de ticks especificado
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- se puxarmos um novo lote, atualize nossos tempos baixados
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- timeout server requests , altere-o se desejar
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- atualize o gerente e siga em frente
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- pegue os símbolos do market watch para iniciar o download
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }