Download all ticks of a symbol's history - MetaTrader 5のためのエキスパート

シンボルを扱うので、バイナリファイルから文字列を書き込んだり読み込んだりするための簡単な関数を2つ作ります。

文字列の長さを整数で書き込み、各文字を文字列に格納する。

ファイルから文字列をロードする関数：

string readStringFromFile(int f)
  {
   string result="";
//シンボル文字列のロード
   char syload[];
   int charstotal=(int)FileReadInteger(f,INT_VALUE);
   if(charstotal>0)
     {
      ArrayResize(syload,charstotal,0);
      for(int i=0;i<charstotal;i++)
        {
         syload[i]=(char)FileReadInteger(f,CHAR_VALUE);
        }
      result=CharArrayToString(syload,0,charstotal,CP_ACP);
     }
   return(result);
  }

各文字をchar配列に読み込み、そのchar配列から文字列を作成し、文字列としてロードした結果として返されます。

CDownloadManager構造体に戻る。マネージャーを初期化し、マーケット・ウォッチからそれを埋める方法が必要だ：

   //+------------------------------------------------------------------+
   //| マーケット・ウォッチからシンボルをつかむ|
   //+------------------------------------------------------------------+
   void              grab_symbols()
     {
      //MWからのみ！
      int s=SymbolsTotal(true);
      ArrayResize(m_symbols,s,0);
      for(int i=0;i<ArraySize(m_symbols);i++)
        {
         m_symbols[i]=SymbolName(i,true);
        }
     }

これがタイマーでダウンロードを行うコードの部分である：

//+------------------------------------------------------------------+
//|タイマー|
//+------------------------------------------------------------------+
void OnTimer()
  {
//--- 同期している場合
   if(SymbolIsSynchronized(_Symbol)&&TerminalInfoInteger(TERMINAL_CONNECTED)==1)
     {
      EventKillTimer();
      //--- ここにシステムをロードする
      if(MANAGER.load(MANAGER_FOLDER,MANAGER_STATUS_FILE))
        {
         //--- システムがロードされたので、ここでシンボルをスキャンしている
         Comment("System loaded and we are processing "+MANAGER.m_current);
         //--- ティックロード

         //--- ブローカーで利用可能な最も古いティックを最初に見つける
         int attempts=0;
         int ping=-1;
         datetime cursor=flatten(TimeTradeServer());
         long cursorMSC=((long)cursor)*1000;
         long jump=2592000000;//60*60*24*30*1000;

         MqlTick receiver[];
         long oldest=LONG_MAX;
         Comment("PleaseWait");
         while(attempts<5)
           {
            ping=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,cursorMSC,1);
            if(ping==1)
              {
               if(receiver[0].time_msc==oldest)
                 {
                  attempts++;
                 }
               else
                 {
                  attempts=0;
                 }
               if(receiver[0].time_msc<oldest)
                 {
                  oldest=receiver[0].time_msc;
                 }
               cursorMSC-=jump;
               if(limitDate&&receiver[0].time<=oldestLimit)
                 {
                  break;
                 }
              }
            else
              {
               attempts++;
              }

            Sleep(44);
            Comment("Oldest Tick : "+TimeToString((datetime)(oldest/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+"\nCursor("+TimeToString((datetime)(cursorMSC/1000),TIME_DATE|TIME_MINUTES|TIME_SECONDS)+")\nAttempts("+IntegerToString(attempts)+")\nPlease wait for response...");
           }
         //--- この時点で、最も古いティックがある。
         //--- 古いものから新しいものへと刻みのリクエストを開始する。
         if(oldest!=LONG_MAX)
           {
            ArrayFree(receiver);
            datetime newest_tick=0;
            //--- symbol_timeに格納されている、このシンボルの最後のティックの時刻を受け取る。
            datetime most_recent_candle=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
            while(newest_tick<most_recent_candle)
              {
               //--- 指定された目盛りの制限で、最も古い時間から始まる新しいバッチを要求する。
               int pulled=CopyTicks(_Symbol,receiver,COPY_TICKS_ALL,oldest,tick_packets);
               if(pulled>0)
                 {
                  //--- 新しいバッチを取り出したら、ダウンロードした時間を更新する。
                  newest_tick=receiver[pulled-1].time;
                  oldest=receiver[pulled-1].time_msc;
                  ArrayFree(receiver);
                 }
               //--- タイムアウトサーバーリクエスト。
               Sleep(44);
               Comment("Pulled up to "+TimeToString(newest_tick,TIME_DATE|TIME_MINUTES|TIME_SECONDS)+" so far");
              }
           }
         else
           {
            Alert("Please close the terminal \n head over to the ticks folder \n and delete the empty folders");
            ExpertRemove();
           }
         //--- マネージャーを更新し、次に進む
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
      else
        {
         //--- ダウンロードを開始するには、マーケット・ウォッチ・シンボルを入手する。
         Comment("Grabbing MW and starting");
         MANAGER.grab_symbols();
         MANAGER.manage(MANAGER_FOLDER,MANAGER_STATUS_FILE);
        }
     }
  }