Справочник MQL5Методы матриц и векторовПроизведенияCorrCoef

CorrCoef

Вычисляет коэффициент корреляции Пирсона (линейный коэффициент корреляции).

matrix matrix::CorrCoef(
const bool rowvar=true // вектора наблюдений расположены в строках, если false - то в столбцах
);

scalar vector::CorrCoef(
const vector& b // второй вектор
);

Параметры

rowvar

[in] Флаг, определяющий расположение векторов в матрице для вычисления попарной корреляции — горизонтально или вертикально. По умолчанию rowvar равно true, это означает, что векторы находятся в строках матрицы. Если rowvar равно false, то корреляций считается между столюцами матрицы.

[in] Второй вектор.

Возвращаемое значение

Значение коэффициенты корреляции для вектора.

Квадратная матрица значений коэффициентов корреляцит между векторами матрицы для матрицы. Размер матрицы соответствует количеству векторов в матрице, который могут располагаться по строкам (rowvar=true) или по столбцам ((rowvar=false).

Примечание

Коэффициент корреляции находится в диапазоне [-1, 1].

Из-за округления числа с плавающей запятой результирующий массив может не быть эрмитовым, диагональные элементы могут не равняться 1, а элементы могут не удовлетворять неравенству abs(a) <= 1. Действительная и мнимая части обрезаются до интервала [-1, 1], чтобы это исправить, но это не всегда помогает в сложных случаях.

Простой алгоритм вычисления коэффициента корреляции двух векторов на MQL5:

double VectorCorrelation(const vector& vector_x,const vector& vector_y)
  {
   ulong n=vector_x.Size()<vector_y.Size() ? vector_x.Size() : vector_y.Size();
   if(n<=1)
      return(0);

   ulong  i;
   double xmean=0;
   double ymean=0;
   for(i=0; i<n; i++)
     {
      if(!MathIsValidNumber(vector_x[i]))
         return(0);
      if(!MathIsValidNumber(vector_y[i]))
         return(0);
      xmean+=vector_x[i];
      ymean+=vector_y[i];
     }
   xmean/=(double)n;
   ymean/=(double)n;

   double s=0;
   double xv=0;
   double yv=0;
   double t1=0;
   double t2=0;
//--- вычисление
   s=0;
   for(i=0; i<n; i++)
     {
      t1=vector_x[i]-xmean;
      t2=vector_y[i]-ymean;
      xv+=t1*t1;
      yv+=t2*t2;
      s+=t1*t2;
     }
//--- проверка
   if(xv==0 || yv==0)
      return(0);
//--- вернем результат
   return(s/(MathSqrt(xv)*MathSqrt(yv)));
  }

Пример на MQL5:

   vectorf vector_a={1,2,3,4,5};
   vectorf vector_b={0,1,0.5,2,2.5};
   Print("vectors correlation ",vector_a.CorrCoef(vector_b));
//---
   matrixf matrix_a={{1,2,3,4,5},
                    {0,1,0.5,2,2.5}};
   Print("matrix rows correlation\n",matrix_a.CorrCoef());
   matrixf matrix_a2=matrix_a.Transpose();
   Print("transposed matrix cols correlation\n",matrix_a2.CorrCoef(false));
   matrixf matrix_a3={{1.0f, 2.0f, 3.0f, 4.0f, 5.0f},
                      {0.0f, 1.0f, 0.5f, 2.0f, 2.5f},
                      {0.1f, 1.0f, 2.0f, 1.0f, 0.3f}};
   Print("rows correlation\n",matrix_a3.CorrCoef());
   Print("cols correlation\n",matrix_a3.CorrCoef(false));

  /*
   vectors correlation 0.9149913787841797
   matrix rows correlation
   [[1,0.91499138]
    [0.91499138,1]]
   transposed matrix cols correlation
   [[1,0.91499138]
    [0.91499138,1]]
   rows correlation
   [[1,0.91499138,0.08474271]
    [0.91499138,1,-0.17123166]
    [0.08474271,-0.17123166,1]]
   cols correlation
   [[1,0.99587059,0.85375023,0.91129309,0.83773589]
    [0.99587059,1,0.80295509,0.94491106,0.88385159]
    [0.85375023,0.80295509,1,0.56362146,0.43088508]
    [0.91129309,0.94491106,0.56362146,1,0.98827404]
    [0.83773589,0.88385159,0.43088508,0.98827404,1]]
   */

Пример на Python:

import numpy as np
va=[1,2,3,4,5]
vb=[0,1,0.5,2,2.5]
print("vectors correlation")
print(np.corrcoef(va,vb))

ma=np.zeros((2,5))
ma[0,:]=va
ma[1,:]=vb
print("matrix rows correlation")
print(np.corrcoef(ma))
print("transposed matrix cols correlation")
print(np.corrcoef(np.transpose(ma),rowvar=False))
print("")

ma1=[[1,2,3,4,5],[0,1,0.5,2,2.5],[0.1,1,0.2,1,0.3]]
print("rows correlation\n",np.corrcoef(ma1))
print("cols correlation\n",np.corrcoef(ma1,rowvar=False))

transposed matrix cols correlation
[[1.         0.91499142]
[0.91499142 1.        ]]

rows correlation
[[1.         0.91499142 0.1424941 ]
[0.91499142 1.         0.39657517]
[0.1424941  0.39657517 1.        ]]
cols correlation
[[1.         0.99587059 0.98226063 0.91129318 0.83773586]
[0.99587059 1.         0.99522839 0.94491118 0.88385151]
[0.98226063 0.99522839 1.         0.97234063 0.92527551]
[0.91129318 0.94491118 0.97234063 1.         0.98827406]
[0.83773586 0.88385151 0.92527551 0.98827406 1.        ]]

Outer

Cov