Assistente MQL5 - Sinais de negociação baseado em Martelo/Enforcado + Estocástico - expert para MetaTrader 5

O Assistente MQL5 permite a criação de Expert Advisors pronto para uso com base nas classes da Biblioteca padrão fornecidas no terminal do cliente (ver Criando Expert Advisors prontos no Assistente MQL5 para maiores detalhes). Ele permite verificar suas ideias de negociação de forma rápida, tudo o que você precisa é criar sua classe personalizada de sinais de negociação. A estrutura desta classe e os exemplos podem ser encontrados no artigo Assistente MQL5: Como criar um Módulo de Sinais de Negociação.

Em geral, a ideia é a seguinte: a classe de sinais de negociação é derivada de CExpertSignal, então, é necessário sobrescrever os métodos virtuais LongCondition() e ShortCondition() com seus próprios métodos.

No livro "Estratégias dos melhores Traders" (em Russo), podemos encontrar várias estratégias de negociação, por hora focaremos nos padrões de velas de reversão , e confirmado pelos osciladores Estocástico, CCI, MFI e RSI.

A melhor maneira de proceder é criando uma classe separada, derivada de CExpertSignal para verificar a formação dos padrões de velas. Para confirmar os sinais de negociação, gerado pelos padrões de velas, é suficiente escrever uma classe, derivada de CCandlePattern e adicionar as características necessárias nela (por exemplo, confirmação por osciladores).

Neste artigo, consideraremos os sinais com base no padrão de velas de reversão "Martelo/Enforcado", confirmado pelo indicador Estocástico. O módulo de sinais de negociação, baseado na classe CCandlePattern, é um simples exemplo de seu uso na geração de sinais de negociação por meio dos padrões de velas.

1. Padrões de velas de reversão "Martelo" e "Enforcado"

1.1. Martelo

O "Martelo" é uma vela com um corpo pequeno e com um longo pavio inferior, formado após um movimento de baixa nos preços. O padrão "Martelo" indica o fim de uma tendência de baixa.

A cor do corpo da vela não é importante, mas o Martelo altista indica um potencial altista maior. O corpo do padrão "Martelo" se forma com frequência próximo da mínima da vela anterior. Um pavio inferior mais longo e um pavio superior mais curto, leva a um maior potencial no padrão de reversão.

Fig. 1. Padrão de vela "Martelo"

O reconhecimento do padrão "Martelo" está implementado no método CheckPatternHammer() da classe CCandlePattern:

//+------------------------------------------------------------------+
//| Verifica a formação do padrão de vela "Martelo"                  |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHammer()
  {
//--- Martelo
   if((MidPoint(1)<CloseAvg(2))                                 && // tendência de baixa
      (MathMin(Open(1),Close(1))>(High(1)-(High(1)-Low(1))/3.0)) && // corpo superior a 1/3
      (Close(1)<Close(2)) && (Open(1)<Open(2)))                    // gap do corpo
      return(true);
//---
   return(false);
  }

1.2. Enforcado

O "Enforcado" é uma vela com um corpo pequeno e um longo pavio inferior, formado após um movimento de alta nos preços. O padrão "Enforcado" indica o fim de uma tendência de alta.

A cor do corpo da vela não é importante, mas uma vela baixista indica um potencial baixista maior. O corpo do padrão "Enforcado" se forma com frequência próximo da máxima da vela anterior. Um pavio inferior mais longo e um pavio superior mais curto, leva a um maior potencial no padrão de reversão.

Figure 2. Padrão de vela "Enforcado"

O reconhecimento do padrão "Enforcado" está implementado no método CheckPatternHangingMan() da classe CCandlePattern:

//+---------------------------------------------------------+
//| Verifica a formação do padrão de vela "Enforcado"       |
//+---------------------------------------------------------+
bool CCandlePattern::CheckPatternHangingMan()
  {
//--- Enforcado
   if((MidPoint(1)>CloseAvg(2))                                && // tendência de alta
      (MathMin(Open(1),Close(1)>(High(1)-(High(1)-Low(1))/3.0)) && // corpo superior a 1/3
      (Close(1)>Close(2)) && (Open(1)>Open(2))))                  // gap do corpo
      return(true);
//---
   return(false);
  }

2. Sinais de negociação, confirmado pelo indicador Estocástico

O sinais de negociação para abrir posições de compra ou venda deve ser confirmado pelo oscilador Estocástico. A linha do sinal %D deve ser maior/menor que os níveis críticos correspondentes (30 ou 70).

O fechamento da posição em aberto depende dos valores da linha de sinal %D do indicador. Ele pode ser feito em 2 casos:

1. Se a linha %D atingiu o nível crítico oposto (80 para posição comprada e 20 para posição vendida)
2. Se o sinal reverso não foi confirmado (quando a linha %D atinge os seguintes níveis: 20 para posição comprada e 80 para posição vendida)

Figure 3. Padrão de vela "Martelo", confirmado pelo indicador Estocástico

• int CH_HM_Stoch::LongCondition() - verifica as condições de abertura de posição comprada (retorna 80) e o fechamento da posição vendida (retorna 40);
  
• int CH_HM_Stoch::ShortCondition() - verifica as condições de abertura de posição vendida (retorna 80) e o fechamento da posição comprada (retorna 40).

2.1. Abertura de posição comprada/fechamento de posição vendida

1. A formação do padrão "Martelo" deve ser confirmado pelo indicador Estocástico: StochSignal(1)<30 (o valor da linha de sinal do indicador Estocástico da última barra completa deve ser inferior a 30).

2. A posição vendida deve ser fechada se a linha de sinal do indicador Estocástico cruzou acima dos níveis críticos (20 ou 80).

//+---------------------------------------------------------------------------+
//| Verifica as condições de entrada e saída do mercado                       |
//| 1) Entrada no mercado (abertura de posição comprada, resultado=80)        |
//| 2) Saída do mercado (fechamento de posição vendida, resultado=40)         |
//+---------------------------------------------------------------------------+
int CH_HM_Stoch::LongCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de funcionamento do Expert Advisor
//--- idx=0 - neste caso o EA verifica as condições de negociação a cada tick
//--- idx=1 - neste caso o EA verifica as condições de negociação somente quando há novas barras
   int idx   =StartIndex();
//--- verificando as condições de abertura de posição comprada
//--- formação do padrão Martelo e linha de sinal <30
  if (CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) && (StochSignal(1)<30))
     result=80;
//--- verificando as condições de fechamento da posição vendida
//--- cruzamento da linha de sinal nos níveis de sobrecompra/sobrevenda (abaixo de 20, acima de 80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- retorna o resultado
   return(result);
  }

2.2. Abertura de posição vendida/fechamento de posição comprada

1. A formação do padrão "Enforcado" deve ser confirmado pelo indicador Estocástico: StochSignal(1)>70 (o valor da linha de sinal do indicador Estocástico da última barra completa deve ser superior a 70).

2. A posição comprada deve ser fechada se a linha de sinal do indicador Estocástico cruzou abaixo dos níveis críticos (80 ou 20).

//+------------------------------------------------------------------------+
//| Verifica as condições de entrada e saída do mercado                    |
//| 1) Entrada no mercado (abertura de posição vendida, resultado=80)      |
//| 2) Saída do mercado (fechamento de posição comprada, resultado=40)     |
//+------------------------------------------------------------------------+
int CH_HM_Stoch::ShortCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de funcionamento do Expert Advisor
//--- idx=0 - neste caso o EA verifica as condições de negociação a cada tick
//--- idx=1 - neste caso o EA verifica as condições de negociação somente quando há novas barras
   int idx   =StartIndex();
//--- verificando as condições de abertura de posição vendida
//--- formação do padrão Enforcado e linha de sinal >70
  if (CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) && (StochSignal(1)>70))
     result=80;
//--- verificando as condições de fechamento de posição comprada
//--- cruzamento da linha de sinal nos níveis de sobrecompra/sobrevenda (abaixo de 80, acima de 20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- retorna o resultado
   return(result);
  }

2.3. Criando o Expert Advisor usando o Assistente MQL5

Para criar um Expert Advisor inicie o Assistente MQL5:

Fig. 4. Criando o Expert Advisor usando o Assistente MQL5

Vamos especificar o nome do Expert Advisor:

Fig. 5. Propriedades gerais do Expert Advisor

Após isso, precisamos selecionar os módulos dos sinais de negociação usados.

Fig. 6. Propriedades de sinais do Expert Advisor

Em nosso caso usaremos apenas um módulo de sinais de negociação.

Adicionando o módulo de sinais de negociação "Sinais baseado no Martelo/Enforcado e confirmado pelo Estocástico":

Fig. 7. Propriedades de sinais do Expert Advisor

Módulo de sinais de negociação adicionado:

Fig. 8. Propriedades de sinais do Expert Advisor

Você pode selecionar qualquer propriedade de trailing, mas nós usaremos "Trailing Stop não utilizado":

Fig. 9. Propriedades de Trailing do Expert Advisor

Em relação às propriedades de gerenciamento de capital, usaremos "Negociação com volume fixo":

Fig. 10. Propriedades do gerenciamento de capital do Expert Advisor

Ao pressionar o botão "Finalizar", obteremos o código gerado do Expert Advisor, de nome Expert_AH_HM_Stoch.mq5, localizado na pasta terminal_data_folder\MQL5\Experts\.

Parâmetros de entrada padrâo do Expert Advisor gerado:

//--- entradas do sinal principal
input int            Signal_ThresholdOpen   =10;     // Valor do sinal de abertura [0...100]
input int            Signal_ThresholdClose  =10;     // Valor do sinal de fechamento [0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para a execução do negócio
input double         Signal_StopLevel       =50.0;   // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =50.0;   // Nível de Take Profit (em pontos)

deve ser substituído por:

//--- entradas do sinal principal
input int            Signal_ThresholdOpen   =40;     // Valor do sinal de abertura [0...100]
input int            Signal_ThresholdClose  =20;     // Valor do sinal de fechamento [0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para a execução do negócio
input double         Signal_StopLevel       =0.0;    // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =0.0;    // Nível de Take Profit (em pontos)

Os parâmetros de entrada Signal_ThresholdOpen/Signal_ThresholdClose permitem especificar os valores dos níveis de abertura e fechamento de posições.

No código dos métodos LongCondition() e ShortCondition() da classe de sinais de negociação, nós especificamos os valores fixos das limiares:

• Abertura de posição: 80;
• Fechamento da posição: 40.
  

Os valores dos parâmetros de entrada de Signal_StopLevel e Signal_TakeLevel está definido com o valor 0, isto significa que o fechamento das posições será executado apenas quando as condições de fechamento forem verdadeiras.

2.4. Resultados do backtesting com dados históricos

Vamos considerar o backtesting com dados históricos do Expert Advisor como sendo (EURUSD H1, período de teste: 2010.01.01-2011.03.04, PeriodK=47, PeriodD=9, PeriodSlow=13, MA_period=5).

Na criação do Expert Advisor usaremos o volume fixo (Negociação com lote fixo, 0.1), o algoritmo de Trailing Stop não é usado (Trailing não utilizado).

Fig. 11. Resultados do teste com o Expert Advisor, baseado em Martelo/Enforcado + Estocástico

O melhor conjunto dos parâmetros de entrada podem ser encontrado utilizando o Strategy Tester do terminal cliente MetaTrader 5.

O código do Expert Advisor, criado pelo Assistente MQL5 se encontra em anexo em expert_ah_hm_stoch.mq5.