SymbolInfoString

指定されたシンボルの指定されたプロパティを返します。この関数には 2 つのバージョンがあります。

1. すぐにプロパティ値を返します。

string SymbolInfoString(
string name, // シンボル
ENUM_SYMBOL_INFO_STRING prop_id // プロパティ識別子
);

2. 関数の成功に応じて、true または false を返します。成功した場合、プロパティの値は、参照によって渡された最後のパラメータに配置されます。

bool SymbolInfoString(
string name, // シンボル
ENUM_SYMBOL_INFO_STRING prop_id, // プロパティ識別子
string& string_var // プロパティ値を受け取る
);

パラメータ

name

[in] 銘柄名

prop_id

[in] シンボルプロパティの識別子（値は ENUM_SYMBOL_INFO_STRING 列挙のいずれか）

string_var

[out] リクエストされたプロパティ値を受け取るstring 型の変数

戻り値

string 型の値実行が失敗した場合、エラー情報は GetLastError() 関数で取得出来ます。

5040 – 銘柄名指定での不正な文字列パラメータの使用
4301 – 未知のシンボル（銘柄）
4302 – シンボルが「気配値表示」で未選択（利用可能なシンボルのリストに不在）
4303 – 不正なシンボルプロパティ識別子

注意事項

最後のティック情報取得には SymbolInfoTick() の使用が推奨されます。端末が取引口座に接続されてから、相場が一つも出ていない可能性があります。このような場合には、リクエストされた値は不定となります。

ほとんどの場合は SymbolInfoTick() 関数の1 回の呼び出しで、ユーザの買値、売値、最終値、ボリューム、また最後のティックの到着時間の受信を可能にするので充分です。

例：

#define SYMBOL_NAME "USDJPY"

//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- SYMBOL_NAMEシンボルの文字列データを取得する
string currency_base = SymbolInfoString(SYMBOL_NAME, SYMBOL_CURRENCY_BASE); // Base currency of the symbol
string currency_profit = SymbolInfoString(SYMBOL_NAME, SYMBOL_CURRENCY_PROFIT); // Profit currency
string currency_margin = SymbolInfoString(SYMBOL_NAME, SYMBOL_CURRENCY_MARGIN); // Margin currency
string symbol_descript = SymbolInfoString(SYMBOL_NAME, SYMBOL_DESCRIPTION); // String description of the symbol

//--- 取得したデータを使用してメッセージテキストを作成する
string text=StringFormat("Symbol %s:\n"+
"- Currency Base: %s\n"+
"- Currensy Profit: %s\n"+
"- Currency Margin: %s\n"+
"- Symbol Description: %s",
SYMBOL_NAME, currency_base,
currency_profit, currency_margin,
symbol_descript);

//--- 取得したデータを操作ログに送信する
Print(text);
/*
Symbol USDJPY:
- Currency Base: USD
- Currensy Profit: JPY
- Currency Margin: USD
- Symbol Description: US Dollar vs Yen
*/
}

SymbolInfoInteger

SymbolInfoMarginRate