無料でロボットをダウンロードする方法を見る
Facebook上で私たちを見つけてください。
私たちのファンページに参加してください
興味深いスクリプト?
それではリンクにそれを投稿してください。-
他の人にそれを評価してもらいます
記事を気に入りましたか?MetaTrader 5ターミナルの中でそれを試してみてください。
エキスパート

MQL5 Wizard - RSIによる条件付きの Bullish/Bearish Meeting Lines - MetaTrader 5のためのエキスパート

ビュー:
1131
評価:
(24)
パブリッシュ済み:
2015.11.26 10:31
アップデート済み:
2016.11.22 07:34
\MQL5\Include\Expert\Signal\MySignals\
このコードに基づいたロボットまたはインジケーターが必要なら、フリーランスでご注文ください フリーランスに移動

MQL5 Wizardを使えば、クライアントターミナルにあるStandard libraryのエキスパートアドバイザーを自動生成することができます。(詳細は、Creating Ready-Made Expert Advisors in MQL5 Wizardを参照)トレードシグナルのクラスを生成しさせすれば、トレードアイディアをすぐに確認することができますクラスの例と構造については MQL5 Wizard: How to Create a Module of Trading Signalsを参照してください。

一般的な考え方は下記の通りです。:CExpertSignalがシグナルのクラスです。そして、LongCondition()ShortCondition() を上書きする必要があります。

"Strategies of best traders" (ロシア)という著書があります。 そこには数多くの手法と方法が記述されており、転換足パターンを StochasticCCIMFIRSIの条件のもと、焦点を当てていきます。

最も良い方法は、ロウソク足のパターンの確認に、CExpertSignalから導かれるクラスを切り分けて生成することです。ロウソク足のパターンによるトレードシグナルの確認には、CCandlePatternのクラスを書いて、必要な条件例えば、オシレーターの確認など)を追加すれば十分です。

RSI による条件付きの"Bullish/Bearish Meeting Lines"の転換足パターンのシグナルを考えてみましょう。トレードシグナルのモジュールは、CCandlePattern クラスに基づいています。ロウソク足のパターンによるシグナルの生成のシンプルな一例です。


1. "Meeting Lines"

1.1. Bullish Meeting Lines

このパターンは、終値が極めて近いブル型とベア型の2つのロウソク足からなります。2つのロウソク足の実体は、実体の長さの平均よりも大きくなければなりません。

"Bullish Meeting Lines"は、下降トレンドの転換を表します。

図1. "Bullish Meeting Lines"

図1. "Bullish Meeting Lines"

"Bullish Meeting Lines"は、 CCandlePatternのCheckPatternCheckPatternBullishMeetingLines() メソッド に実装されています:

//+--------------------------------------------------------------------+
//| Checks formation of "Bullish Meeting Lines" candlestick pattern    |            
//+--------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishMeetingLines()
  {
//--- Bullish Meeting Lines
   if((Open(2)-Close(2)>AvgBody(1))              && // long black
     ((Close(1)-Open(1))>AvgBody(1))             && // long white
      (MathAbs(Close(1)-Close(2))<0.1*AvgBody(1)))   // doji close
      return(true);
//---
   return(false);
  }

CCandlePattern の CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_MEETING_LINES) メソッド を "Bullish Meeting Lines"で使います。


1.1. Bearish Meeting Lines

このパターンは、終値が極めて近いブル型とベア型の2つのロウソク足からなります。2つのロウソク足の実体は、実体の長さの平均よりも大きくなければなりません。

"Bearish Meeting Lines"は、下降トレンドの転換を表します。

図2. "Bearish Meeting Lines"

図2. Bearish Meeting Lines

"Bearish Meeting Lines"は、 CCandlePatternのCheckPatternBearishMeetingLines() メソッド に実装されています:

//+--------------------------------------------------------------------+
//| Checks formation of "Bearish Meeting Lines" candlestick pattern    |
//+--------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishMeetingLines()
  {
//--- Bearish Meeting Lines
   if((Close(2)-Open(2)>AvgBody(1))             && // long white
     ((Open(1)-Close(1))>AvgBody(1))            && // long black
      (MathAbs(Close(1)-Close(2))<0.1*AvgBody(1)))  // doji close
      return(true);
//---
   return(false);
  }

CCandlePattern の CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_MEETING_LINES) メソッド を "Bearish Meeting Lines"で使います。



2. RSI の条件付きのシグナル

買いポジション・売りポジションのシグナルは、RSI で確認する必要があります。RSI の値は、基準値よりも低いか/大きい必要があります。 (買いポジションは40、売りポジションは60).

ポジションの決済は RSIの値で行います。2通りのケースがあります:

  1. RSI が反対の基準点に到達した場合(買いポジションは70。売りポジションは30)
  2. 逆のシグナルが発生しない(RSIが次の点に達したとき: 買いポジションは30。売りポジションは70)

図3. RSIによる条件付きの"Bearish Meeting Lines"

図3. RSIによる条件付きの"Bearish Meeting Lines


  • int CML_RSI::LongCondition() - 買いポジションのエントリー条件(80) と 売りポジションの決済条件 (40);
  • int CML_RSI::ShortCondition() - 売りポジションのエントリー条件(80) と 買いポジションの決済条件 (40)。

2.1. 買いポジション/売りポジションの決済

  1. "Bullish Meeting Lines"の条件は、RSI で確認しなければなりません: RSI(1)<40 (直近の確定した足のRSIの値が40よりも小さい)。

  2. RSIが基準値 70 か 30 を上抜けした場合、売りポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CML_RSI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Bullish Metting Lines pattern and RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_MEETING_LINES) && (RSI(1)<40))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (upward 30, upward 70)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- return result
   return(result);
  }

2.2. 売りポジション/買いポジションの決済

  1. "Bearish Meeting Lines"の条件は、RSI で確認しなければなりません: RSI(1)>60 (直近の確定した足のRSI が60よりも大きい)。

  2. RSIが基準値 70 か 30を下向きにクロスした場合、買いポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CML_RSI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Bearish Meeting Lines pattern and RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_MEETING_LINES) && (RSI(1)>60))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward 70, downward 30)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- return result
   return(result);
  }


2.3. MQL5 WizardでEAを生成する

CML_RSI クラスはStandard Libraryには含まれていません。利用するには、acml_rsi.mqh をダウンロードして、client_terminal_data_folder\MQL5\Include\Expert\Signal\MySignalsに保存する必要があります。(添付詳細)同様の操作が acandlepatterns.mqh にも必要です。MQL5 Wizardを使うには、MetaEditorを再起動する必要があります。

エキスパートアドバイザーを生成するには、MQL5 Wizardを立ち上げてください:

図4. MQL5 WizardでEAを生成する

図4. MQL5 WizardでEAを生成する

エキスパートアドバイザーの名前を決めましょう:

図5. エキスパートアドバイザーの一般設定

図5. エキスパートアドバイザーの一般設定

トレードシグナルのモジュールを選択します。

図6. エキスパートアドバイザーのシグナルプロパティ

図6. エキスパートアドバイザーのシグナルプロパティ

今回の場合、モジュールは1つだけ使います。

"Signals based on Bullish/Bearish Meeting Lines confirmed by RSI" のモジュールを追加:

図7. エキスパートアドバイザーのシグナルプロパティ

図7. エキスパートアドバイザーのシグナルプロパティ

シグナルの追加モジュール:

図8. エキスパートアドバイザーのシグナルプロパティ

図8. エキスパートアドバイザーのシグナルプロパティ

トレーリングプロパティにも様々なものがありますが、今回は"Trailing Stop not used"にします:

図9. エキスパートアドバイザーのトレーリングプロパティ

図9. エキスパートアドバイザーのトレーリングプロパティ

資金管理プロパティとして、"Trading with fixed trade volume"(単利)を使います:

図10エキスパートアドバイザーの資金管理プロパティ

図10エキスパートアドバイザーの資金管理プロパティ

"Finish"ボタンを押すと、エキスパートアドバイザーがExpert_AML_RSI.mq5に生成されます。保存場所は、terminal_data_folder\MQL5\Experts\です。

生成後のエキスパートアドバイザーのデフォルトのパラメーター:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

上記は下記にしなければなりません:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Signal_ThresholdOpen/Signal_ThresholdClose パラメーターは、ポジションのオープン、決済の最初のレベルを決めます。

LongCondition() と ShortCondition() のメソッドのコードの中に、デフォルトの固定値が入っています:

  • エントリー: 80;
  • 決済: 40。

MQL5 Wizard で生成したエキスパートアドバイザーは、トレードシグナルのモジュールの"ボート"を使ってエントリー、決済を行います。メインモジュール(コンテナとして、すべての追加モジュールを含む)のボートもまた、使われますが、 LongCondition() と ShortCondition() メソッドは常に0を返します。

メインモジュールの評価結果は、"ボート"平均が使われます。今回の場合、メインモジュールとシグナルのモジュールがあるので、初期値を与えるときには、このことを考慮に入れなければいけません。そのことにより、ThresholdOpen と ThresholdClose は、 40=(0+80)/2 and 20=(0+40)/2に設定しなければなりません。

Signal_StopLevel と Signal_TakeLevel パラメーターの値は、0にします。これは、ポジションの決済は、決済条件がtrueのときにのみ行われるということを表します。


2.4. バックテスト結果

過去データでエキスパートアドバイザーをテストしてみましょう。 (EURUSD H1, テスト期間: 2000.01.01-2011.03.01, PeriodRSI=11, MA_period=3)。

エキスパートアドバイザーの生成において、今回は固定ロット(Trading Fixed Lot, 0.1), トレーリングストップ(Trailing not used)はなしを選択しました。

図11. Bullish/Bearish Meeting Lines + RSIのテスト結果

図11. Bullish/Bearish Meeting Lines + RSIのテスト結果


パラメーターの最適な設定値は、MetaTrader 5 client terminalのStrategy Testerで探すことができます。

MQL5 Wizard で生成したコードはexpert_aml_rsi.mq5です。

MetaQuotes Ltdによってロシア語から翻訳されました。
元のコード: https://www.mql5.com/ru/code/321

MQL5 Wizard - MFIによる条件付きの'Bullish/Bearish Meeting Lines'ロウソク足パターン MQL5 Wizard - MFIによる条件付きの'Bullish/Bearish Meeting Lines'ロウソク足パターン

MFIによる条件付きの"Bullish/Bearish Meeting Lines"のシグナルを試すことができます。この戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。

EA_OBJPROP_CHART_ID EA_OBJPROP_CHART_ID

このEAは、典型的なチャート機能としてのOBJ_CHARTオブジェクトのデモです。カスタムカラーやインジケーターなどを設定することができます。

MQL5 Wizard - CCIの条件付きの Morning/Evening Stars MQL5 Wizard - CCIの条件付きの Morning/Evening Stars

商品チャネル指数(CCI)による条件付きの"Morning Star/Evening Star"のシグナルを試すことができます。この戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。

MQL5 Wizard - MFIの条件付きの Morning/Evening Stars MQL5 Wizard - MFIの条件付きの Morning/Evening Stars

MFIによる条件付きの"Morning Star/Evening Star"のシグナルを試すことができます。この戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。