Référence MQL5Bibliothèque StandardMathematiquesLogique floueFonctions d'appartenanceCDifferencTwoSigmoidalMembershipFunction

CDifferencTwoSigmoidalMembershipFunction

Classe d'implémentation d'une fonction d'appartenance sous la forme d'une différence entre deux fonctions sigmoïdes avec les paramètres А1, А2, С1 et С2.

Description

La fonction est basée sur une courbe sigmoïde. Elle permet de créer des fonctions d'appartenance avec des valeurs égales à 1 commençant avec la valeur de l'argument. De telles fonctions conviennent si vous avez besoin de définir des termes linguistiques tels que "short" ou "long".

fuzzy_diffsigmoidal_function

Un extrait de code dessinant un graphique est affiché plus bas.

Déclaration

class CDifferencTwoSigmoidalMembershipFuncion : public IMembershipFunction

Titre

#include <Math\Fuzzy\membershipfunction.mqh>

Hiérarchie d'héritage

CObject

IMembershipFunction

CDifferencTwoSigmoidalMembershipFunction

Méthodes de classe

Méthode de classe	Description
A1	Retourne et définit le rapport de la pente de la première fonction d'appartenance.
A2	Retourne et définit le rapport de la pente de la deuxième fonction d'appartenance.
С1	Retourne et définit le paramètre des coordonnées de l'inflexion de la première fonction d'appartenance.
С2	Retourne et définit le paramètre des coordonnées de l'inflexion de la deuxième fonction d'appartenance.
GetValue	Calcule la valeur de la fonction d'appartenance d'un argument donné.

Méthodes héritées de la classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemple

//+------------------------------------------------------------------+
//|                      DifferencTwoSigmoidalMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crée les fonctions membres
CDifferencTwoSigmoidalMembershipFunction func1(5,1,8,7);
CDifferencTwoSigmoidalMembershipFunction func2(5,4,5,7);
CDifferencTwoSigmoidalMembershipFunction func3(5,6,2,7);
//--- Crée les wrappers des fonctions membres
double DifferencTwoSigmoidalMembershipFunction1(double x) { return(func1.GetValue(x)); }
double DifferencTwoSigmoidalMembershipFunction2(double x) { return(func2.GetValue(x)); }
double DifferencTwoSigmoidalMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Fonction de lancement du script                                  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crée le graphique
   CGraphic graphic;
   if(!graphic.Create(0,"DifferencTwoSigmoidalMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"DifferencTwoSigmoidalMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("DifferencTwoSigmoidalMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- crée une courbe
   graphic.CurveAdd(DifferencTwoSigmoidalMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[5, 1, 8, 7]");
   graphic.CurveAdd(DifferencTwoSigmoidalMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[5, 4, 5, 7]");
   graphic.CurveAdd(DifferencTwoSigmoidalMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[5, 6, 2, 7]");
//--- définit les propriétés de l'axe X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- définit les propriétés de l'axe Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- dessin
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue