MQL5 リファレンス標準ライブラリ数学ファジー論理メンバーシップ関数CDifferencTwoSigmoidalMembershipFunction

CDifferencTwoSigmoidalMembershipFunction

А1、А2、С1、С2パラメータを持つ2つのシグモイド関数の差の形でメンバーシップ関数を実装するためのクラス。

説明

この関数はシグモイド曲線に基づいています。引数値で始まる値が1のメンバーシップ関数の作成が可能になります。このような関数は、「ショート」や「ロング」などの言語用語を設定する必要がある場合に適しています。

fuzzy_diffsigmoidal_function

下記はチャートをプロットするためのサンプルコードです。

宣言

class CDifferencTwoSigmoidalMembershipFuncion : public IMembershipFunction

タイトル

#include <Math\Fuzzy\membershipfunction.mqh>

継承階層

CObject

IMembershipFunction

CDifferencTwoSigmoidalMembershipFunction

クラスメソッド

クラスメソッド	説明
A1	1番目のメンバーシップ関数の勾配比を取得及び設定します。
A2	2番目のメンバーシップ関数の勾配比を取得及び設定します。
С1	1番目のメンバーシップ関数の屈曲座標パラメータを取得及び設定します。
С2	2番目のメンバーシップ関数の屈曲座標パラメータを取得及び設定します。
GetValue	メンバーシップ関数の値を指定された引数で計算します。

クラスから継承されたメソッド CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

例

//+------------------------------------------------------------------+
//| DifferencTwoSigmoidalMembershipFunction.mq5 |
//| Copyright 2016, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- メンバーシップ関数を作成します
CDifferencTwoSigmoidalMembershipFunction func1(5,1,8,7);
CDifferencTwoSigmoidalMembershipFunction func2(5,4,5,7);
CDifferencTwoSigmoidalMembershipFunction func3(5,6,2,7);
//--- メンバーシップ関数用のラッパーを作成する
double DifferencTwoSigmoidalMembershipFunction1(double x) { return(func1.GetValue(x)); }
double DifferencTwoSigmoidalMembershipFunction2(double x) { return(func2.GetValue(x)); }
double DifferencTwoSigmoidalMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- グラフィックを作成する
CGraphic graphic;
if(!graphic.Create(0,"DifferencTwoSigmoidalMembershipFunction",0,30,30,780,380))
{
graphic.Attach(0,"DifferencTwoSigmoidalMembershipFunction");
}
graphic.HistoryNameWidth(70);
graphic.BackgroundMain("DifferencTwoSigmoidalMembershipFunction");
graphic.BackgroundMainSize(16);
//--- 曲線を作成する
graphic.CurveAdd(DifferencTwoSigmoidalMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[5, 1, 8, 7]");
graphic.CurveAdd(DifferencTwoSigmoidalMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[5, 4, 5, 7]");
graphic.CurveAdd(DifferencTwoSigmoidalMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[5, 6, 2, 7]");
//--- X軸のプロパティを設定する
graphic.XAxis().AutoScale(false);
graphic.XAxis().Min(0.0);
graphic.XAxis().Max(10.0);
graphic.XAxis().DefaultStep(1.0);
//--- Y軸のプロパティを設定する
graphic.YAxis().AutoScale(false);
graphic.YAxis().Min(0.0);
graphic.YAxis().Max(1.1);
graphic.YAxis().DefaultStep(0.2);
//--- プロット
graphic.CurvePlotAll();
graphic.Update();
}

GetValue