Descargar MetaTrader 5

iRVI

Devuelve el manejador del indicador Relative Vigor Index.

int  iRVI(
   string           symbol,        // nombre del símbolo
   ENUM_TIMEFRAMES  period,        // período
   int              ma_period      // período promedio
   );

Parámetros

symbol

[in]  Símbolo del instrumento financiero cuyos datos serán usados para calcular el indicador. NULL significa el símbolo actual.

period

[in]  Valor del período puede ser uno de los valores de la enumeración ENUM_TIMEFRAMES, 0 significa el timeframe actual.

ma_period

[in]  Período promedio para calcular el índice.

Valor devuelto

Devuelve el manejador del indicador técnico especificado, en caso del fallo devuelve INVALID_HANDLE. Para liberar la memoria del ordenador del indicador que ya no se utiliza la función IndicatorRelease() a la que se le pasa el manejador (handle) de este indicador.

Nota

Números de búfers: 0 - MAIN_LINE, 1 - SIGNAL_LINE.

Ejemplo:

//+------------------------------------------------------------------+
//|                                                    Demo_iRVI.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "El indicador demuestra cómo hay que obtener los datos"
#property description "de los búfers indicadores para el indicador técnico iRVI."
#property description "El símbolo y el período de tiempo en el que se calcula el indicador"
#property description "se establecen mediante los parámetros symbol y period."
#property description "El modo de crear el manejador (handle) se establece mediante el parámetro 'type' (tipo de función)."
#property description "Todos los demás parámetros son iguales a los del Relative Vigor Index estándar."
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   2
//--- construcción de RVI
#property indicator_label1  "RVI"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrGreen
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- construcción de Signal
#property indicator_label2  "Signal"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrRed
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//+------------------------------------------------------------------+
//|  Enumeración de modos de crear el manejador                      |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iRVI,              // usar iRVI
   Call_IndicatorCreate    // usar IndicatorCreate
  };
//--- parámetros de entrada
input Creation             type=Call_iRVI;               // tipo de función 
input int                  ma_period=10;                 // período para el cálculo
input string               symbol=" ";                   // símbolo 
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;        // timeframe
//--- búfers indicadores
double         RVIBuffer[];
double         SignalBuffer[];
//--- variable para guardar el manejador del indicador iRVI
int    handle;
//--- variable para guardar
string name=symbol;
//--- nombre del indicador en el gráfico
string short_name;
//--- vamos a guardar el número de los valores en el indicador Relative Vigor Index
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- vinculación de los arrays a los búfers indicadores
   SetIndexBuffer(0,RVIBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,SignalBuffer,INDICATOR_DATA);
//--- determinamos el símbolo para el que se construye el indicador
   name=symbol;
//--- eliminaremos los espacios del lado izquierdo y derecho
   StringTrimRight(name);
   StringTrimLeft(name);
//--- si después de eso la longitud de la cadena name obtiene el valor cero,
   if(StringLen(name)==0)
     {
      //--- cogeremos el símbolo del gráfico en el que está iniciado el indicador
      name=_Symbol;
     }
//--- crearemos el manejador del indicador
   if(type==Call_iRVI)
      handle=iRVI(name,period,ma_period);
   else
     {
      //--- llenaremos la estructura con los valores de los parámetros del indicador     
      MqlParam pars[1];
      //--- período para el cálculo
      pars[0].type=TYPE_INT;
      pars[0].integer_value=ma_period;
      handle=IndicatorCreate(name,period,IND_RVI,1,pars);
     }
//--- si no se puede crear el manejador
   if(handle==INVALID_HANDLE)
     {
      //--- avisaremos sobre el fallo y mostraremos el número del error
      PrintFormat("Fallo al crear el manejador del indicador iRVI para el par %s/%s, código del error %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- el trabajo del indicador se finaliza anticipadamente
      return(INIT_FAILED);
     }
//--- mostraremos sobre qué par símbolo/período ha sido calculado el indicador Relative Vigor Index
   short_name=StringFormat("iRSI(%s/%s, %d, %d)",name,EnumToString(period),ma_period);
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialización correcta del indicador
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- número de valores copiados desde el indicador iRVI
   int values_to_copy;
//--- vamos a averiguar el número de valores calculados en el indicador
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() ha devuelto %d, el código del error %d",calculated,GetLastError());
      return(0);
     }
//--- si se trata del primer arranque del proceso de calculación de nuestro indicador o se ha cambiado el número de valores en el indicador iRVI
//--- o si es necesario calcular el indicador para dos o más barras (entonces algo se ha cambiado en el historial)
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- si el array RVIBuffer supera el número de valores en el indicador iRVI sobre el par symbol/period, entonces no copiamos todo 
      //--- en caso contrario, copiaremos menos que el tamaño de los búfers indicadores
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
     }
   else
     {
      //--- significa que no es la primera vez que se calcula nuestro indicador y desde el momento de la primera llamada de OnCalculate())
      //--- se ha añadido no más de una barra para la calculación
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- llenamos los arrays con los valores desde el indicador iRVI
//--- si FillArrayFromBuffer ha devuelto false, significa que los datos no están listos - entonces finalizamos el trabajo
   if(!FillArrayFromBuffer(RVIBuffer,SignalBuffer,handle,values_to_copy)) return(0);
//--- creamos el mensaje
   string comm=StringFormat("%s ==>  Actualizados los valores en el indicador %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- mostraremos en el gráfico un mensaje de servicio
   Comment(comm);
//--- recordaremos el número de valores en el indicador Relative Vigor Index
   bars_calculated=calculated;
//--- devolveremos el valor prev_calculated para la siguiente llamada
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Llenamos los búfers indicadores desde el indicador iRVI          |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &rvi_buffer[],     // búfer indicador de valores Relative Vigor Index
                         double &signal_buffer[],  // búfer indicador de la línea de señales
                         int ind_handle,           // manejador del indicador iRVI
                         int amount                // número de valores a copiar
                         )
  {
//--- actualizaremos el código del error
   ResetLastError();
//--- llenamos una parte del array iRVIBuffer con los valores desde el búfer indicador con el índice 0
   if(CopyBuffer(ind_handle,0,0,amount,rvi_buffer)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iRVI, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
//--- llenamos una parte del array SignalBuffer con los valores desde el búfer indicador con el índice 1
   if(CopyBuffer(ind_handle,1,0,amount,signal_buffer)<0)
     {
      //--- si el proceso de copiado ha fallado, comunicaremos el código del error
      PrintFormat("Fallo al copiar los datos desde el indicador iRVI, código del error %d",GetLastError());
      //--- finalizaremos con el resultado nulo - eso quiere decir que el indicador será considerado como no calculado
      return(false);
     }
//--- todo ha salido bien
   return(true);
  }
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- limpiaremos el gráfico tras eliminar el indicador
   Comment("");
  }


Actualizado: 2015.12.03