MQL5 Sihirbazı - Stochastic Oscillator Göstergesiyle Onaylı Olarak Boğa Tipi / Ayı Tipi Buluşan Hat Mum Modellerine Dayalı Ticaret Sinyalleri - MetaTrader 5 için Uzman Danışman

MQL5 Sihirbazı, müşteri terminali ile birlikte sağlanan Standart Kütüphane sınıflarına dayanan hazır Uzman Danışmanlar oluşturmaya olanak sağlar (ayrıntılar için bkz. MQL5 Sihirbazında Hazır Uzman Danışmanlar Oluşturma). Ticaret fikirlerinizi hızlı bir şekilde test etmenize olanak tanır, tek ihtiyacınız olan kendi ticaret sinyalleri sınıfınızı oluşturmaktır. Bu sınıfın yapısı ve örneği, MQL5 Sihirbazı: Ticaret Sinyali Modülü Nasıl Oluşturulur? makalesinde bulunur.

Ana fikir şudur: ticaret sinyalleri sınıfı CExpertSignal'dan türer, sizin LongCondition() ve ShortCondition() sanal metotlarına kendi yöntemlerinizi uygulamanız gerekir.

"Стратегии Лучших Трейдеров Мира" (Dünyanın En İyi Yatırımcılarının Stratejileri) adlı kitapta (Rusça), incelenen birçok ticaret stratejisi vardır ve çoğunluklu olarak Stochastic, CCI, MFI ve RSI osilatörleriyle onaylı terse dönüş mum modellerine odaklanır.

En iyi yol, mum modellerinin oluşumunu kontrol etmek için CExpertSignal'dan türeyen ayrı bir sınıf oluşturmaktır. Mum modelleri tarafından oluşturulan ticaret sinyallerinin onayı için CCandlePattern'dan türeyen sınıf yazmak ve gerekli özellikleri (örneğin, osilatörler tarafından onay) oraya eklemek yeterlidir.

Bu bölümde Stochastic Oscillator göstergesiyle onaylı olarak boğa tipi / ayı tipi buluşan hat terse dönüş mum modellerini temel alan strateji ele alınacak. Ticaret sinyali modülü CCandlePattern sınıfına dayanır, mum modelleriyle ticaret sinyalleri oluşturmak için kullanımının basit bir örneğidir.

1. Buluşan hat mum modelleri

1.1. Boğa tipi buluşan hat

Bu model, aynı (veya çok yakın) kapanış fiyatlarına sahip iki mumdan (boğa tipinde ve ayı tipinde) oluşur. İki mumun gövdesi, ortalama gövde uzunluğundan daha büyük olmalıdır.

Boğa tipi buluşan hat modeli, düşüş trendinin terse dönüşüne işaret eder.

Şekil 1. Boğa tipi buluşan hat modeli

Boğa tipi buluşan hat modelinin tanınması, CCandlePattern sınıfının CheckPatternCheckPatternBullishMeetingLines() metodunda yer alır:

//+--------------------------------------------------------------------+
//| boğa tipi buluşan hat mum modelinin oluşumunu kontrol et           |            
//+--------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishMeetingLines()
  {
//--- boğa tipi buluşan hat
   if((Open(2)-Close(2)>AvgBody(1))              && // ayı tipinde uzun gövdeli mum
     ((Close(1)-Open(1))>AvgBody(1))             && // boğa tipinde uzun gövdeli mum
      (MathAbs(Close(1)-Close(2))<0.1*AvgBody(1)))   // doji kapanışı
      return(true);
//---
   return(false);
  }

1.1. Ayı tipi buluşan hat

Bu model, aynı (veya çok yakın) kapanış fiyatlarına sahip iki mumdan (boğa tipinde ve ayı tipinde) oluşur. İki mumun gövdesi, ortalama gövde uzunluğundan daha büyük olmalıdır.

Ayı tipi buluşan hat modeli, yükseliş trendinin terse dönüşüne işaret eder.

Şekil 2. Ayı tipi buluşan hat modeli

Ayı tipi buluşan hat modelinin tanınması, CCandlePattern sınıfının CheckPatternBearishMeetingLines() metodunda yer alır:

//+--------------------------------------------------------------------+
//| ayı tipi buluşan hat mum modelinin oluşumunu kontrol et            |
//+--------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishMeetingLines()
  {
//--- ayı tipi buluşan hat
   if((Close(2)-Open(2)>AvgBody(1))             && // boğa tipinde uzun gövdeli mum
     ((Open(1)-Close(1))>AvgBody(1))            && // ayı tipinde uzun gövdeli mum
      (MathAbs(Close(1)-Close(2))<0.1*AvgBody(1)))  // doji kapanışı
      return(true);
//---
   return(false);
  }

2. Stochastic Oscillator göstergesi tarafından onaylanan ticaret sinyalleri

Alış veya satış pozisyonu açma için ticaret sinyalleri Stochastic Oscillator tarafından onaylanmalıdır. %D sinyal çizgisi, karşılık gelen kritik seviyenin (30 veya 70) yukarısında veya aşağısında olmalıdır.

Açık pozisyonun kapanması %D'nin davranışlarına bağlıdır. 2 durumda gerçekleşir:

1. %D çizgisi karşı kritik seviyeye (alış pozisyonu için 80 ve satış pozisyonu için 20) ulaştığında
2. terse dönüş sinyali onaylanmazsa (%D çizgisi şu seviyelere ulaştığında: alış pozisyonu için 20 ve satış pozisyonu için 80)

Şekil 3. Stochastic Oscillator göstergesiyle onaylanan ayı tipi buluşan hat mum modeli

• int CML_Stoch::LongCondition() - alış pozisyonu açma (80 geri döndürür) ve satış pozisyonunu kapatma (40 geri döndürür) için koşulları kontrol eder;
  
• int CML_Stoch::ShortCondition() - satış pozisyonu açma (80 geri döndürür) ve alış pozisyonunu kapatma (40 geri döndürür) için koşulları kontrol eder.

2.1. Alış pozisyonu açma/Satış pozisyonunu kapatma

1. Alış pozisyonu açma sinyali, boğa tipi buluşan hat modelinin oluşması ve oluşan modelin Stochastic Oscillator göstergesiyle onaylanmasıyla (StochSignal(1)<30 (son tamamlanmış çubuğun Stochastic Oscillator göstergesinin sinyal çizgisinin değeri 30'dan daha düşük olmalıdır)) oluşur.

2. Satış pozisyonunu kapatma sinyali, Stochastic Oscillator göstergesinin sinyal çizgisinin 80 veya 20 seviyesini yukarı doğru çaprazlamasıyla oluşur.

//+------------------------------------------------------------------+
//| piyasaya giriş ve çıkış koşullarını kontrol et                   |
//| 1) piyasaya giriş (alış pozisyonu açma, result==80)              |
//| 2) piyasadan çıkış (satış pozisyonunu kapatma, result=40)        |
//+------------------------------------------------------------------+
int CML_Stoch::LongCondition()
  {
   int result=0;
//--- idx, Uzman Danışmanın çalışma modunu belirlemek için kullanılabilir
//--- idx=0 - bu durumda Uzman Danışman, ticaret koşullarını her tikte kontrol eder
//--- idx=1 - bu durumda Uzman Danışman, ticaret koşullarını yalnızca yeni mumlarda kontrol eder
   int idx   =StartIndex();
//--- alış pozisyonu açma için koşulların kontrolü
//--- boğa tipi buluşan hat modeli ve sinyal hattı<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_MEETING_LINES) && (StochSignal(1)<30))
     result=80;
//--- satış pozisyonunu kapatma için koşulların kontrolü
//--- sinyal çizgisinin aşırı alış / aşırı satış seviyelerini çaprazlaması (80 veya 20'yi yukarı doğru)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- sonucu geri döndür
   return(result);
  }

2.2. Satış pozisyonu açma/Alış pozisyonunu kapatma

1. Satış pozisyonu açma sinyali, ayı tipi buluşan hat mum modelinin oluşması ve oluşan modelin Stochastic Oscillator göstergesiyle onaylanmasıyla (StochSignal(1)>70 (son tamamlanmış çubuğun Stochastic Oscillator göstergesinin sinyal çizgisinin değeri 70'dan daha yüksek olmalıdır)) oluşur.

2. Alış pozisyonunu kapatma sinyali, Stochastic Oscillator göstergesinin sinyal çizgisinin 80 veya 20 seviyesini aşağı doğru çaprazlamasıyla oluşur.

//+------------------------------------------------------------------+
//| piyasaya giriş ve çıkış koşullarını kontrol et                   |
//| 1) piyasaya giriş (satış pozisyonu açma, result=80)              |
//| 2) piyasadan çıkış (alış pozisyonunu kapatma, result=40)         |
//+------------------------------------------------------------------+
int CML_Stoch::ShortCondition()
  {
   int result=0;
//--- idx, Uzman Danışmanın çalışma modunu belirlemek için kullanılabilir
//--- idx=0 - bu durumda Uzman Danışman, ticaret koşullarını her tikte kontrol eder
//--- idx=1 - bu durumda Uzman Danışman, ticaret koşullarını yalnızca yeni mumlarda kontrol eder
   int idx   =StartIndex();
//--- satış pozisyonu açma için koşulların kontrolü
//--- ayı tipi buluşan hat modeli ve sinyal hattı>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_MEETING_LINES) && (StochSignal(1)>70))
     result=80;
//--- alış pozisyonunu kapatma için koşulların kontrolü
//--- sinyal çizgisinin aşırı alış / aşırı satış seviyelerini çaprazlaması (80 veya 20'yi aşağı doğru)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- sonucu geri döndür
   return(result);
  }

2.3. MQL5 Sihirbazını kullanarak Uzman Danışman oluşturma

Uzman Danışman oluşturmak için MQL5 Sihirbazını başlatın:

Şekil 4. MQL5 Sihirbazını kullanarak Uzman Danışman oluşturma

Uzman Danışmanın adını belirtin:

Şekil 5. Uzman Danışmanın genel özellikleri

Ardından, kullanılan ticaret sinyali modüllerini seçmeniz gerekir.

Şekil 6. Uzman Danışmanın sinyal özellikleri

Bizim durumumuzda yalnızca bir ticaret sinyali modülü kullanılacağız.

"Signals based on Bullish/Bearish Meeting Lines confirmed by Stochastic" ticaret sinyali modülünün eklenmesi:

Şekil 7. Uzman Danışmanın sinyal özellikleri

Ticaret sinyali modülü eklendi:

Şekil 8. Uzman Danışmanın sinyal özellikleri

Ardından, takip eden durdurucu modülünü seçebilirsiniz, biz onu kullanmayacağız, bu yüzden "Trailing Stop not used" seçeneğini seçtik:

Şekil 9. Uzman Danışmanın takip eden durdurucu özelliği

Şimdi ise bir para yönetimi modülü seçilmesi gerekiyor, biz burada "Trading with fixed trade volume" (Sabit işlem hacmi ile ticaret) kullanacağız:

Şekil 10. Uzman Danışmanın para yönetimi özelliği

"Tamam" düğmesine basarak, oluşturulan Uzman Danışman kodunu elde edeceğiz - kod, expert_AML_Stoch.mq5 dosyasına kaydedilir ve bu dosya da terminal_veri_klasörü\MQL5\Experts\ klasörüne yerleştirilir.

Oluşturulan Uzman Danışmanın varsayılan girdi parametreleri:

//--- ana sinyal için girdiler
input int            Signal_ThresholdOpen   =10;     // pozisyon açma için sinyal eşik değeri [0...100]
input int            Signal_ThresholdClose  =10;     // pozisyonu kapatma için sinyal eşik değeri [0...100]
input double         Signal_PriceLevel      =0.0;    // işlemi gerçekleştirmek için fiyat seviyesi
input double         Signal_StopLevel       =50.0;   // Zararı Durdur seviyesi (puan cinsinden)
input double         Signal_TakeLevel       =50.0;   // Kârı Al seviyesi (puan cinsinden)

şu şekilde değiştirilmelidir:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // pozisyon açma için sinyal eşik değeri [0...100]
input int            Signal_ThresholdClose  =20;     // pozisyonu kapatma için sinyal eşik değeri [0...100]
input double         Signal_PriceLevel      =0.0;    // işlemi gerçekleştirmek için fiyat seviyesi
input double         Signal_StopLevel       =0.0;    // Zararı Durdur seviyesi (puan cinsinden)
input double         Signal_TakeLevel       =0.0;    // Kârı Al seviyesi (puan cinsinden)

Signal_ThresholdOpen/Signal_ThresholdClose girdi parametreleri, pozisyonların açılması ve kapanması için eşik seviyelerin belirlenmesine olanak tanır.

Ticaret sinyali modülünün LongCondition() ve ShortCondition() metotlarının kodunda, sabit eşik değerleri şu şekildedir:

• Alış pozisyonu: 80;
• Satış pozisyonu: 40.
  

Signal_StopLevel ve Signal_TakeLevel girdi parametrelerinin değerleri 0 olarak ayarlanmıştır, bu, pozisyonların yalnızca kapanış koşulları mevcut olduğunda kapatılacağı anlamına gelir.

2.4. Geçmiş verileri üzerinde test sonuçları

Uzman Danışmanın geçmiş verileri üzerinde geriye dönük testini ele alalım (EURUSD H1, test aralığı: 2005.01.01-2010.03.16, PeriodK=6, PeriodD=3, PeriodSlow=36, MA_period=3).

Uzman Danışman oluşturulurken 0.1 lotluk sabit işlem hacmi kullanıldı (Trading Fixed Lot), Takip Eden Durdurucu algoritması kullanılmadı (Trailing not used).

Şekil 11. Stochastic Oscillator göstergesiyle onaylı olarak boğa tipi / ayı tipi buluşan hat mum modellerine dayalı Uzman Danışmanın geçmişe dönük test sonuçları

En iyi girdi parametreleri kümesi, MetaTrader 5 müşteri terminalinin Strateji Sınayıcısı kullanılarak bulunabilir.

MQL5 Sihirbazı tarafından oluşturulan Uzman Danışman kodu, expert_aml_stoch.mq5 dosyasına eklenir.