Assistant MQL5 - Signaux de Trading Basés sur les Lignes de Rencontres Haussières/Baissières + Stochastique - expert pour MetaTrader 5

L'Assistant MQL5 permet de créer des Expert Advisors prêts à l'emploi basés sur les classes de la bibliothèque standard livrées avec le terminal client (voir Création d'Expert Advisors prêts à l'emploi dans l'Assistant MQL5 pour les détails). Il permet de vérifier rapidement vos idées de trading, tout ce dont vous avez besoin est de créer votre propre classe de signaux de trading. La structure de cette classe et cet exemple se trouvent dans l'article Assistant MQL5 : Comment créer un module de signaux de trading.

L'idée générique est la suivante : la classe des signaux de trading est dérivée de CExpertSignal, il faut ensuite surcharger les méthodes virtuelles LongCondition() et ShortCondition() avec vos propres méthodes.

Il existe un livre "Stratégies des meilleurs traders" (en russe), de nombreuses stratégies de trading y sont envisagées, nous nous concentrerons sur les modèles de chandeliers d'inversion, confirmés par Stochastique, Oscillateurs CCI, MFI et RSI.

Le meilleur moyen est de créer la classe séparée, dérivée de CExpertSignal pour vérifier la formation des modèles de chandeliers. Pour la confirmation des signaux de trading, générés par les modèles de chandeliers, il suffit d'écrire la classe, dérivée de CCandlePattern et d'y ajouter les fonctionnalités nécessaires (par exemple, la confirmation par des oscillateurs).

Ici, nous examinerons les signaux, basés sur les modèles de chandeliers d'inversion "Bullish/Bearish Meeting Lines", confirmés par l'indicateur Stochastique. Le module de signaux de trading est basé sur la classe CCandlePattern, c'est un exemple simple de son utilisation pour la création de signaux de trading avec des modèles de chandeliers.

1. Modèles de chandeliers de renversement "Lignes de Rencontres"

1.1. Lignes de Rencontre Haussières

Le modèle se compose de deux chandeliers (baissier et haussier) avec des prix de clôture égaux (ou très proches). Le corps de deux chandeliers doit être supérieur à la longueur moyenne du corps.

Le modèle "Bullish Meeting Lines" indique le renversement d'une tendance à la baisse.

Figure 1. Modèle "Lignes de Rencontre Haussières"

La reconnaissance du modèle "Bullish Meeting Lines" est implémentée dans la méthode CheckPatternCheckPatternBullishMeetingLines() de la classe CCandlePattern :

//+--------------------------------------------------------------------+
//| Vérifie la formation du modèle "Bullish Meeting Lines"            |            
//+--------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishMeetingLines()
  {
//--- Lignes de Rencontre Haussières
   if((Open(2)-Close(2)>AvgBody(1))              && // noir long
     ((Close(1)-Open(1))>AvgBody(1))             && // blanc long
      (MathAbs(Close(1)-Close(2))<0.1*AvgBody(1)))   // doji close
      return(true);
//---
   return(false);
  }

1.1. Lignes de Rencontre Baissières

Le modèle se compose de deux chandeliers (haussier et baissier) avec des prix de clôture égaux (ou très proches). Le corps de deux chandeliers doit être supérieur à la longueur moyenne du corps.

Le modèle "Bearish Meeting Lines" indique le renversement d'une tendance à la baisse.

Figure 2. Modèle "Lignes de Rencontre Baissières"

La reconnaissance du modèle "Bearish Meeting Lines" est implémentée dans la méthode CheckPatternBearishMeetingLines() de la classe CCandlePattern :

//+--------------------------------------------------------------------+
//| Vérifie la formation du modèle "Bearish Meeting Lines"            |
//+--------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishMeetingLines()
  {
//--- Lignes de Rencontre Baissières=
   if((Close(2)-Open(2)>AvgBody(1))             && // long blanc
     ((Open(1)-Close(1))>AvgBody(1))            && // long noir
      (MathAbs(Close(1)-Close(2))<0.1*AvgBody(1)))  // doji close
      return(true);
//---
   return(false);
  }

2. Signaux de trading, confirmés par l'indicateur stochastique

Les signaux de trading pour ouvrir une position longue ou courte doivent être confirmés par l'oscillateur Stochastique. La ligne %D du signal doit être supérieure/inférieure au niveau critique correspondant (30 ou 70).

La fermeture de la position ouverte dépend des valeurs de l'indicateur %D. Cela peut se faire dans 2 cas :

1. si la ligne %D a atteint le niveau critique opposé (80 pour la position longue et 20 pour la position courte)
2. si le signal inverse n'est pas confirmé (lorsque la ligne %D atteint les niveaux suivants : 20 pour la position longue et 80 pour la position courte)

Fig. 3. Modèle de "Lignes de Rencontre Baissières", confirmé par l'indicateur stochastique

• int CML_Stoch::LongCondition() - vérifie les conditions d'ouverture d'une position longue (retourne 80) et de clôture de la position courte (retourne 40) ;
  
• int CML_Stoch::ShortCondition() - vérifie les conditions d'ouverture d'une position courte (retourne 80) et de clôture de la position longue (retourne 40).

2.1. Ouverture d'une position longue/Cloôture d'une position courte

1. La formation du motif "Bullish Meeting Lines" doit être confirmée par l'indicateur Stochastique : StochSignal(1)<30 (la valeur de la ligne de signal de l'indicateur stochastique de la dernière barre complétée doit être inférieure à 30) .

2. La position courte doit être fermée si la ligne de signal de l'indicateur Stochastique a franchi à la hausse les niveaux 20 ou 80.

//+------------------------------------------------------------------+
//| Vérifie les conditions d'entrée et de sortie du marché                 |
//| 1) Entrée sur le marché (ouvrir position longue, résultat=80)    |
//| 2) Sortie du marché (fermer position courte, résultat=40)        |
//+------------------------------------------------------------------+
int CML_Stoch::LongCondition()
  {
   int result=0;
//--- idx peut être utilisé pour déterminer le mode de travail de l'Expert Advisor
//--- idx=0 - dans ce cas, l'EA vérifie les conditions de trading à chaque tick
//--- idx=1 - dans ce cas, l'EA vérifie la situation de trading uniquement sur les nouvelles barres
   int idx   =StartIndex();
//--- vérification des conditions pour ouvrir une position longue
//--- formation du motif Lignes de Rencontres Haussières et ligne de signal <30
  if (CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_MEETING_LINES) && (StochSignal(1)<30))
     result=80;
//--- vérification des conditions pour fermer la position courte
//--- croisement de la ligne de signal des niveaux de surachat/survente (à la baisse 20, à la hausse 80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- retourne le résultat
   return(result);
  }

2.2. Ouverture d'une position courte/Clôture d'une position longue

1. La formation du motif "Bearish Meeting Lines" doit être confirmée par l'indicateur stochastique : StochSignal(1)>70 (la valeur de la ligne de signal de l'indicateur stochastique de la dernière barre complétée doit être supérieure à 70) .

2. La position longue doit être fermée si la ligne de signal de l'indicateur Stochastique a franchi à la baisse les niveaux 80 ou 20.

//+------------------------------------------------------------------+
//| Vérifie les conditions d'entrée et de sortie du marché           |
//| 1) Entrée sur le marché (position courte ouverte, résultat=80)   |
//| 2) Sortie du marché (fermer position longue, résultat=40)        |
//+------------------------------------------------------------------+
int CML_Stoch::ShortCondition()
  {
   int result=0;
//--- idx peut être utilisé pour déterminer le mode de travail de l'Expert Advisor
//--- idx=0 - dans ce cas, l'EA vérifie les conditions de trading à chaque tick
//--- idx=1 - dans ce cas, l'EA vérifie la situation de trading uniquement pour les nouvelles barres
   int idx   =StartIndex();
//--- vérification des conditions pour ouvrir une position courte
//--- formation du motif Lignes de Rencontre Baissières et ligne de signal >70
  if (CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_MEETING_LINES) && (StochSignal(1)>70))
     result=80;
//--- vérification des conditions pour fermer la position longue
//--- croisement de la ligne de signal des niveaux de surachat/survente (à la baisse de 80, à la hausse de 20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- retourne le résultat
   return(result);
  }

2.3. Création d'un Expert Advisor à l'aide de l'Assistant MQL5

Pour créer un Expert Advisor, lancez l'Assistant MQL5 :

Fig. 4. Création d'un Expert Advisor à l'aide de l'Assistant MQL5

Précisons le nom de l'Expert Advisor :

Fig. 5. Propriétés générales de l'Expert Advisor

Après cela, nous devons sélectionner les modules de signaux de trading utilisés.

Fig. 6. Propriétés du signal de l'Expert Advisor

Dans notre cas, nous n'utilisons qu'un seul module de signaux de trading.

Ajout du module "Signaux basés sur des lignes de rencontre haussières/baissières confirmées par stochastique" :

Fig. 7. Propriétés du signal de l'Expert Advisor

Module de signaux de trading ajouté :

Fig. 8. Propriétés du signal de l'Expert Advisor

Vous pouvez sélectionner n'importe quelle propriété de fin, mais nous utiliserons "Trailing Stop not used":

Fig. 9. Propriétés de suivi de l'Expert Advisor

Concernant les propriétés de money management, nous utiliserons "Trading with fixed trade volume":

Fig. 10. Propriétés de gestion de l'argent de l'Expert Advisor

En appuyant sur le bouton "Terminer", nous obtiendrons le code de l'Expert Advisor généré, situé dans Expert_AML_Stoch.mq5, il sera enregistré dans terminal_data_folder\MQL5\Experts\.

Les paramètres d'entrée par défaut de l'Expert Advisor généré :

//--- entrées pour le signal principal
input int            Signal_ThresholdOpen   =10 ; // Valeur seuil du signal à ouvrir [0...100]
input int            Signal_ThresholdClose  =10 ; // Valeur seuil du signal de fermeture [0...100]
input double         Signal_PriceLevel      =0.0 ; // Niveau de prix pour exécuter une transaction
input double         Signal_StopLevel       =50,0 ; // Niveau de Stop Loss (en points)
input double         Signal_TakeLevel       =50,0 ; // Niveau de Take Profit (en points)

doit être remplacé par :

//--- entrées pour le signal principal
input int            Signal_ThresholdOpen   =40 ; // Valeur seuil du signal à ouvrir [0...100]
input int            Signal_ThresholdClose  =20 ; // Valeur seuil du signal de fermeture [0...100]
input double         Signal_PriceLevel      =0.0 ; // Niveau de prix pour exécuter une transaction
input double         Signal_StopLevel       =0.0 ; // Niveau de Stop Loss (en points)
input double         Signal_TakeLevel       =0.0 ; // Niveau de Take Profit (en points)

Les paramètres d'entrée Signal_ThresholdOpen/Signal_ThresholdClose permettent de spécifier des niveaux de seuil pour l'ouverture et la fermeture des positions.

Dans le code des méthodes LongCondition() et ShortCondition() de la classe des signaux de trading, nous avons spécifié les valeurs fixes du seuil :

• Ouvreture de position: 80 ;
• Clôture de position : 40.
  

Les valeurs des paramètres d'entrée Signal_StopLevel et Signal_TakeLevel sont définies sur 0, cela signifie que la fermeture des positions ne sera effectuée que lorsque les conditions de fermeture seront vraies.

2.4. Résultats du backtesting de l'historique

Considérons le backtesting de l'Expert Advisor sur les données historiques (EURUSD H1, période de test : 2005.01.01-2010.03.16, PeriodK=6, PeriodD=3, PeriodSlow=36, MA_period=3).

Lors de la création de l'Expert Advisor, nous avons utilisé le volume fixe (Trading Fixed Lot, 0.1), l'algorithme Trailing Stop n'est pas utilisé (Trailing not used).

Fig. 11. Résultats des tests de l'Expert Advisor, basés sur les lignes de rencontre haussière/baissière + stochastique"

Le meilleur ensemble de paramètres d'entrée peut être trouvé en utilisant le Strategy Tester du terminal client MetaTrader 5.

Le code de l'Expert Advisor, créé par l'Assistant MQL5 est joint dans expert_aml_stoch.mq5.