Скачать MetaTrader 5

Смотри, как бесплатно скачать роботов

Интересный скрипт?
Поставь на него ссылку - пусть другие тоже оценят

Понравился скрипт?
Оцени его работу в терминале MetaTrader 5

2011.02.15 17:50
Советники

Мастер MQL5 - Торговые сигналы свечных паттернов 3 Black Crows/3 White Soldiers + RSI - эксперт для MetaTrader 5

| Russian English 中文 Español Deutsch 日本語 Português

Просмотров:
1972
Рейтинг:
голосов: 17
\MQL5\Include\Expert\Signal\MySignals\

С появлением Мастера MQL5 появилась возможность автоматической генерации кода советника на базе классов торговых сигналов, сопровождения позиций и управления капиталом. Помимо классов торговых сигналов из Стандартной библиотеки, вы можете создавать и тестировать свои собственные торговые системы, для этого достаточно написать модуль торговых сигналов.

В книге "Стратегии лучших трейдеров мира" описаны индикаторы и торговые стратегии для технического анализа с использованием программного пакета MetaStock. Наряду с традиционными, в ней рассмотрены торговые сигналы, основанные на совместном использовании разворотных свечных моделей с подтверждением от осцилляторов Stochastic, CCI, MFI и RSI.

Использование "разворотных" свечных моделей совместно с сигналами осцилляторов позволяет сократить количество ложных сигналов и повысить эффективность торговой системы.

В данной работе мы рассмотрим результаты использования моделей 3 Black Crows (три черные вороны) и 3 White Soldiers (3 белых солдата) в комбинации с сигналами индикатора RSI.


1. Паттерны 3 Black Crows (Три черные вороны) и 3 White Soldiers (Три белых солдата) и их распознавание

1.1. Паттерн "Три черные вороны" (3 Black Crows)

Это фигура на диаграмме, когда день открывается немного выше предыдущего закрытия, а закрывается значительно ниже предыдущего. Повторение такой ситуации три дня подряд считается сигналом о развороте (бычьего) тренда.

Рисунок 1. Свечной паттерн "3 Black Crows"

Рисунок 1. Свечной паттерн "3 Black Crows"

Распознавание паттерна "3 Black Crows" реализовано в методе CheckPatternThreeBlackCrows класса CCandlePattern:

//+------------------------------------------------------------------+
//| Метод проверки формирования свечной модели "3 Black Crows"       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeBlackCrows()
  {
//--- 3 Black Crows - распознавание паттерна "3 черные вороны"
   if((Open(3)-Close(3)>AvgBody(1)) && // тело свечи перед предыдущей черное, и его размер больше среднего
      (Open(2)-Close(2)>AvgBody(1)) && // тело предыдущей свечи черное и его размер больше среднего
      (Open(1)-Close(1)>AvgBody(1)) && // тело завершенной свечи черное и его размер больше среднего (long black)
      (MidPoint(2)<MidPoint(3))     && // положение центра свечей последовательно уменьшается (lower midpoints)
      (MidPoint(1)<MidPoint(2)))       // положение центра последней завершенной свечи ниже положения центра предыдущей
      return(true);
//---
   return(false);
  }

В данном случае проверяются условия того, что три завершенные свечи "медвежьи" (Close<Open), размер их тела (разность между Open и Close) больше среднего, при этом положения центра свечей последовательно уменьшается.

Для проверки факта формирования модели "3 Black Crows" используется метод CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) класса CCandlePattern.


1.2. Паттерн "Три белых солдата" (3 White Soldiers)

Это фигура на диаграмме, когда день открывается немного ниже предыдущего закрытия, а закрывается значительно выше предыдущего. Повторение такой ситуации три дня подряд считается сигналом о развороте (медвежьего) тренда.

Рисунок 2. Свечной паттерн "3 White Soldiers"

Рисунок 2. Свечной паттерн "3 White Soldiers"

Метод распознавания модели "3 White Soldiers":

//+------------------------------------------------------------------+
//| Метод проверки формирования свечной модели "3 White Soldiers"    |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeWhiteSoldiers()
  {
   //--- 3 White Soldiers - распознавание паттерна "3 белых солдата"
   if((Close(3)-Open(3)>AvgBody(1)) && // тело свечи перед предыдущей белое и его размер больше среднего
      (Close(2)-Open(2)>AvgBody(1)) && // тело предыдущей свечи белое и его размер больше среднего
      (Close(1)-Open(1)>AvgBody(1)) && // тело завершенной свечи черное и его размер больше среднего (long white)
      (MidPoint(2)>MidPoint(3))     && // положение центра свечей последовательно увеличивается (higher midpoints)
      (MidPoint(1)>MidPoint(2)))       // положение центра последней завершенной свечи выше положения центра предыдущей
      return(true);
//---
   return(false);
  }

Для проверки факта формирования модели "3 White Soldiers" используется метод CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) класса CCandlePattern.


2. Торговые сигналы в комбинации с индикатором RSI

Сигналы входа в рынок подаются при сочетании разворотной фигуры на диаграмме со значением RSI ниже уровня 40 для длинных и выше 60 - для коротких позиций.

Сигналы выхода формируются при достижении RSI противоположного уровня (70 для длинной и 30 для короткой позиций) или же не подтверждает разворота, достигнув уровня 30 или 70 для длинной или короткой позиций соответственно.

Рисунок 3. Торговые сигналы паттерна "Три черные вороны" с подтверждением от индикатора RSI

Рисунок 3. Торговые сигналы паттерна "Три черные вороны" с подтверждением от индикатора RSI

Реализация проверки условий входа и выхода в рынок осуществляется в методах:

  • int CBC_WS_RSI::LongCondition() - проверка условий для открытия длинной позиции (ф-я возвращает 80) и закрытия короткой позиции (ф-я возвращает 40);
  • int CBC_WS_RSI::ShortCondition() - проверка условий для открытия короткой позиции (ф-я возвращает 80) и закрытия длинной позиции (ф-я возвращает 40).

2.1. Открытие длинной позиции и закрытие короткой позиции

  1. Сигналом к открытию длинной позиции является формирование свечной комбинации Three White Soldiers (три белых солдата) и выполнение условия RSI(1)<40 (значение линии индикатора RSI на последнем завершенном баре меньше 40):

  2. Сигналом к закрытию короткой позиции является пересечение индикатора RSI уровня 30 (снизу вверх) или уровня 70 (снизу вверх).

    //+------------------------------------------------------------------+
    //| Метод проверки условий для входа и выхода с рынка                |
    //| Проверка условий для                                             |
    //| 1) входа в рынок (открытие длинной позиции, result=80)           |
    //| 2) выхода из рынка (закрытие короткой позиции, result=40)        |
    //+------------------------------------------------------------------+
    int CBC_WS_RSI::LongCondition()
      {
       int result=0;
    //--- idx можно использовать для того чтобы узнать режим работы эксперта
    //--- idx=0 - эксперт будет вызывать проверки выполнения торговых условий на каждом тике
    //--- idx=1 - эксперт будет вызывать проверки выполнения торговых условий только на новых барах
       int idx   =StartIndex();
    //--- проверка условий для открытия длинной позиции
    //--- формирование бычьей свечной комбинации 3 White Soldiers и выполнения условия RSI<40
       if(CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) && (RSI(1)<40))
         result=80;
    //--- проверка условий для закрытия короткой позиции
       if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
          result=40;
         result=40;
    //--- возвращаем result
       return(result);
      }

2.2. Открытие короткой позиции и закрытие длинной позиции

  1. Сигналом к открытию короткой позиции является формирование паттерна Three Black Crows (три черные вороны) и выполнение условия RSI(1)>60 (значение индикатора RSI на последнем завершенном баре больше 60);

  2. Сигналом к закрытию длинной позиции является пересечение линией индикатора RSI уровня 70 (сверху вниз) или уровня 30 (сверху вниз).

    //+------------------------------------------------------------------+
    //| Метод проверки условий для входа и выхода с рынка                |
    //| Проверка условий для                                             |
    //| 1) входа в рынок (открытие короткой позиции, result=80)          |
    //| 2) выхода из рынка (закрытие длинной позиции, result=40)         |
    //+------------------------------------------------------------------+
    int CBC_WS_RSI::ShortCondition()
      {
       int result=0;
    //--- idx можно использовать для того чтобы узнать режим работы эксперта
    //--- idx=0 - эксперт будет вызывать проверки выполнения торговых условий на каждом тике
    //--- idx=1 - эксперт будет вызывать проверки выполнения торговых условий только на новых барах
       int idx   =StartIndex();
    //--- проверка условий для открытия короткой позиции
    //--- формирование медвежьей свечной комбинации 3 Black Crows и выполнения условия RSI>60
      if(CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) && (RSI(1)>60))
         result=80;
    //--- проверка условий для закрытия длинной позиции
      if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
         result=40;
    //--- возвращаем result
       return(result);
      }
    
    

2.3. Создание эксперта на основе торговых сигналов разворотной модели "3 Black Crows/3 White Soldiers + Stochastic" при помощи Мастера MQL5

Класс CBC_WS_RSI не входит в Стандартную библиотеку классов торговых сигналов, поэтому для его использования нужно скачать файл acbc_ws_rsi.mqh (прилагается) и сохранить его в каталог_данных_терминала\Include\Expert\Signal\MySignals. Файл acandlepatterns.mqh следует скопировать в тот же каталог, что и файл acbc_ws_rsi.mqh. После этого, перезапустив MetaEditor, вы получите возможность его использования в Мастере MQL5.

Чтобы создать торгового робота по данной стратегии запустите Мастер MQL5:

Рис. 4. Создание советника в Мастере MQL5

Рис. 4. Создание советника в Мастере MQL5

Нажав на кнопку "Далее", укажем имя советника:

Рис. 5. Общие параметры советника

Рис. 5. Общие параметры советника

После этого нужно указать параметры сигналов.

Рис. 6. Параметры сигналов советника

Рис. 6. Параметры сигналов советника

В нашем случае мы будем использовать лишь один модуль торговых сигналов.

Добавляем модуль "Signals based on 3 Black Crows/3 White Soldiers confirmed by RSI":

Рис. 7. Параметры сигналов советника

Рис. 7. Параметры сигналов советника

Модуль сигналов добавлен:

Рис. 8. Параметры сигналов советника

Рис. 8. Параметры сигналов советника

После этого можно выбрать модуль трейлинга, мы его использовать не будем. Выбираем "Trailing Stop not used":

Рис. 9. Выбор модуля трейлинга

Рис. 9. Выбор модуля трейлинга

Затем нужно выбрать модуль управления капиталом, мы будем использовать торговлю с фиксированным объемом (Trading with fixed trade volume):

Рис. 10. Выбор модуля управления капиталом

Рис. 10. Выбор модуля управления капиталом

Нажав на кнопку "Готово", мы получим код сгенерированного советника - файл Expert_ABC_WS_RSI.mq5, который будет сохранен в папке: каталог_данных_терминала\MQL5\Experts\.

Входные параметры (по умолчанию) советника:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

заменяем на:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Параметры Signal_ThresholdOpen и Signal_ThresholdClose позволяют задать пороги для открытия и закрытия позиций.

В коде функций LongCondition() и ShortCondition() модуля торговых сигналов мы указали фиксированные значения порогов:

  • Для открытия позиций: 80;
  • Для закрытия позиций: 40.

Советник, сгенерированный при помощи Мастера MQL5, принимает решение об открытии или закрытии позиции на основании результатов "голосования" модулей торговых сигналов, добавленных в процессе создания советника. При этом основной модуль (содержащий все добавленные модули) торговых сигналов также принимает участие в "голосовании", однако его методы LongCondition() и ShortCondition() всегда возвращают 0.

Поскольку при расчете "голосов" производится усреднение по количеству присутствующих модулей (основной + один добавленный модуль), то значения порогов следует указывать с учетом данного обстоятельства. По этой причине значения величин Signal_ThresholdOpen и Signal_ThresholdClose должны быть установлены в 40=(0+80)/2 и 20=(0+40)/2 соответственно.

Значения входных параметров Signal_StopLevel и Signal_TakeLevel устанавливаем в 0, это означает, что закрытие позиций будет осуществляться только при поступлении торговых сигналов на закрытие позиций.


2.4 Результаты тестирования на истории

Результаты тестирования советника на исторических данных (EURUSD H1, 2010.01.01-2011.02.02, PeriodRSI=37, MA_period=51).

В данном советнике использовался модуль торговли фиксированным объемом 0.1 лота (Trading Fixed Lot), трейлинг не использовался (Trailing not used).

Рис. 11. Результаты тестирования советника, построенного на базе генератора торговых сигналов "3 Black Crows/3 White Soldiers + RSI"

Рис. 11. Результаты тестирования советника, построенного на базе генератора торговых сигналов "3 Black Crows/3 White Soldiers + RSI"

Наилучший набор параметров торговой системы можно найти при помощи Тестера Стратегий терминала MetaTrader 5.

Код советника, созданного Мастером MQL5, прилагается в файле expert_abc_ws_rsi.mq5.


YURAZ_RSAXEL Скрипт рисует уровни Рудолфа Акселя YURAZ_RSAXEL Скрипт рисует уровни Рудолфа Акселя

Скрипт рисует уровни Рудолфа Акселя

YURAZ_CLOSEPRC_V1 YURAZ_CLOSEPRC_V1

Закрытие всех открытых позиций одним кликом либо закрытие всех позиций при достижении указанного профита в процентах от депозита

Мультипериодный индикатор MK_LaguerreMultiPeriodV2 Мультипериодный индикатор MK_LaguerreMultiPeriodV2

Обычный Laguerre на нескольких таймфреймах одновременно.

AskBid Line AskBid Line

AskBid Line — простейший индикатор, отображающий цену Ask или Bid в виде пунктирной линии на истории.