Bibliotecas: Report - página 6

[fxsaber]

FILE_COMMON.

[Arthur Albano]

Hi!

Gerei algumas informações a partir de transações. Também estou escrevendo um código para drawdowns, atualmente em versão beta :)

[Arthur Albano]

Arthur Albano:

Hi!

Gerei algumas informações a partir de negócios. Também estou escrevendo um código para drawdowns, atualmente em versão beta :)

Resultados das negociações. Esses resultados são bons em uma conta de demonstração?

[fxsaber]

Adicionada a classificação por horário de fechamento.

[fxsaber]

Gráfico de equilíbrio alternativo entre plataformas

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Scripts: Gráfico de saldo HTML

fxsaber, 2019.04.08 09:16

Para MT4/5.

// Código MQL4&5

#property strict

// Copie "Graph.txt" para "Files\Graph.txt".
// https://www.mql5.com/en/code/25199
// #resource "\Scripts\Graph_HTML\Resource\Graph.txt" as string htm_file

#import "shell32.dll"
  int ShellExecuteW( int hwnd, string lpOperation, string lpFile, string lpParameters, string lpDirectory, int nShowCmd );
#import

#ifdef __MQL5__
  #include <MT4Orders.mqh> // https://www.mql5.com/en/code/16006

  #define  BASEPATH (TerminalInfoString(TERMINAL_PATH) + "\\MQL5\\Files\\")
#else // __MQL5__
  #define  BASEPATH (TerminalInfoString(TERMINAL_PATH) + "\\MQL4\\Files\\")
#endif // __MQL5__

bool CreateBalanceData( const string FileName = "exdat.txt" )
{
  const int handle = FileOpen(FileName, FILE_WRITE | FILE_TXT | FILE_ANSI);
  const bool Res = (handle != INVALID_HANDLE);

  if (Res)
  {
  // https://www.mql5.com/ru/forum/170953/page14#comment_10550116
  #define  CLOSETIME_INDEX 0
  #define  TICKET_INDEX 1
    long Tickets[][2];
    int Total = OrdersHistoryTotal();    

  #ifdef __MQL5__
    static const bool Sort = false;
  #else // __MQL5__
    #ifdef __VIRTUAL__
      static const bool IsTester = ::MQLInfoInteger(MQL_TESTER);

      const bool Sort = !IsTester && !VIRTUAL::GetHandle();
    #else // __VIRTUAL__
      static const bool Sort = !::MQLInfoInteger(MQL_TESTER);
    #endif // __VIRTUAL__

    if (Sort)
    {
      int Amount = 0;

      for (int i = (::ArrayResize(Tickets, Total) >> 1) - 1; i >= 0; i--) // https://www.mql5.com/ru/forum/170953/page16#comment_10604064
        if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY))
        {
          Tickets[Amount][CLOSETIME_INDEX] = OrderCloseTime();
          Tickets[Amount++][TICKET_INDEX] = OrderTicket();
        }

      if ((bool)(Total = ::ArrayResize(Tickets, Amount) >> 1)) // https://www.mql5.com/ru/forum/170953/page16#comment_10604064
        ::ArraySort(Tickets);
    }
  #endif // __MQL5__
    
    double Balance = 0;

    FileWriteString(handle, "var dat1=[\n");

    for (int i = 0; i < Total; i++)
      if ((Sort ? OrderSelect((int)Tickets[i][TICKET_INDEX], SELECT_BY_TICKET) : (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY))) && // int - (Sort == true) somente para MQL4.
          ((OrderType() <= OP_SELL) || (OrderType() > OP_SELLSTOP)))
    #undef  TICKET_INDEX
    #undef  CLOSETIME_INDEX
      {
        Balance += OrderProfit() + OrderCommission() + OrderSwap();

        FileWriteString(handle, "[" + (string)((long)OrderCloseTime() * 1000) + "," + DoubleToString(Balance, 2) + "],\n");
      }

    FileWriteString(handle, "];\n");
    FileWriteString(handle, "var T1=dat1[0][0];\n");
    FileWriteString(handle, "var T2=dat1[dat1.length-1][0];\n");
    FileWriteString(handle, "var nTrades=dat1.length;\n");
    FileWriteString(handle, "var Balance=" + DoubleToString(Balance, 2) + ";\n");
    FileWriteString(handle, "var Currency=\"" + AccountInfoString(ACCOUNT_CURRENCY) + "\";\n");

    FileClose(handle);
  }

  return(Res);
}

string GetHTM( const string FileName = "Graph.txt" )
{
  uchar Data[];

  const int handle = FileOpen(FileName, FILE_READ | FILE_BIN);
  const bool Res = (handle != INVALID_HANDLE);

  if (Res)
  {
    FileReadArray(handle, Data);

    FileClose(handle);
  }

  return(Res ? CharArrayToString(Data) : NULL);
}

//+------------------------------------------------------------------+
//| Cria um relatório de saldo "HighCharts" sobre as negociações no formato .html.
//+------------------------------------------------------------------+
void CreateHighChartsBalanceReport( const string FileName = "Graph.htm" )
{
  const int handle = FileOpen(FileName, FILE_WRITE | FILE_TXT | FILE_ANSI);

  if (handle != INVALID_HANDLE)
  {
// FileWriteString(handle, htm_file);
    FileWriteString(handle, GetHTM());
    FileClose(handle);

    if (CreateBalanceData())
      ShellExecuteW(0, "Open", BASEPATH + FileName, NULL, NULL, 3);
  }
}

void OnStart()
{
  CreateHighChartsBalanceReport();
}

Diferente do Report - gráfico interativo com vários artifícios.

[Fulvio Monaco]

Excelente ferramenta. No entanto, ao executar testes avançados, ela salva apenas o relatório e o saldo do backtest.

Alguma sugestão de como salvar também os testes futuros?

F

[fxsaber]

Um novo recurso foi adicionado. Exemplo de aplicação em um Expert Advisor padrão.

#define  REPORT_TESTER             // O testador registrará automaticamente os relatórios
#define  REPORT_TESTER_INPUTS      // O relatório de passagem única mostrará os parâmetros de entrada do EA - requer resolução de DLL.
#define  REPORT_INTERACTIVE_CHARTS // Adiciona gráficos interativos ao relatório.
#define  REPORT_BROWSER            // Criação de um relatório com inicialização do navegador - requer permissão de DLL.
#include <Report.mqh> // https://www.mql5.com/pt/code/18801

#include <..\Experts\Examples\Moving Average\Moving Average.mq5>

No trailer está o resultado do lançamento de uma única passagem. Agora você pode ver os parâmetros de entrada do Expert Advisor e o gráfico de balanço interativo.

O script ZY CustomReport foi atualizado. Experimente um relatório de negociação não estático em sua conta. Exemplo de trabalho.

[fxsaber]

Finalmente, as passagens únicas se tornaram completas - todos os gráficos apareceram no relatório.

Também no MT4, para todas as corretoras, o relatório adicionou dados sobre derrapagens ao executar TP/SL. Para fazer isso, você precisa atualizar a biblioteca.

[fxsaber]

As configurações do testador foram adicionadas aos relatórios de passagem única.

[fxsaber]

Inesperadamente, descobri que, apesar do uso constante do MT5-Tester, parei completamente de olhar as guias Backtest e Chart.

Quando preciso calcular mais rapidamente ou definir condições para execução de ordens, tamanho da comissão, faço tudo por meio do Virtual.

A conveniência é que você não precisa saber nada sobre o Virtual ou o Report. Basta escrever as mesmas linhas no início e o MT5-Tester é transformado.