MQL5 Wizard - Handelssignale der Kerzenformationen Dark Cloud Cover/Piercing Line + Stochastic - Experte für den MetaTrader 5

Mit dem MQL5 Wizard können Trader nun Expert Advisor Codes automatisch generieren, die auf den Klassen von Handelssignalen, Positions Tracking und Money Management basieren. Neben den Klassen von Handelssignalen aus der Standardbibliothek können Sie Ihre eigenen Handelssysteme erstellen und testen, dafür brauchen Sie lediglich ein Modul für Handelssignale zu schreiben.

Das Buch "The Strategies of the Best Traders in the World" (in Russisch) beschreibt Indikatoren und Handelsstrategien für die technische Analyse unter Verwendung des MetaStock Softwarepaketes. Neben den konventionellen Handelssignalen befasst sich dieses Buch auch mit denen, die auf einer kombinierten Anwendung von Umkehrkerzenformationen mit der Bestätigung durch Stochastic, CCI, MFI und RSI basieren.

Die Verwendung von Umkehrkerzenformationen zusammen mit Signalen von Oszillatoren, reduziert die Anzahl der falschen Signale und erhöht die Effizienz des Handelssystems.

Hier werden die Ergebnisse einer kombinierten Anwendung der Kerzenformationen Dark Cloud Cover und Piercing Line zusammen mit den Signalen des Stochastic Indikators betrachtet.

1. Die Kerzenformationen "Dark Cloud Cover" und "Piercing Line" und deren Erkennung

1.1. Kerzenformation Dark Cloud Cover

Das Muster weist auf die Umkehr eines bullischen Trends hin. Am ersten Tag wird eine große weiße Kerze gebildet, am nächsten Tag folgt eine Gap Up Eröffnung (über dem Tageshoch des Vortages), der Schlusskurs liegt unterhalb der Mitte des Vortages. Dies ist einer der wenigen Fälle, wenn Hoch und Tief in Candlesticks berücksichtigt werden.

Abb. 1. Kerzemmuster "Dark Cloud Cover"

Die Erkennung der Kerzenformation "Dark Cloud Cover" ist in der Methode CheckPatternDarkCloudCover der Klasse CCandlePattern umgesetzt:

//+------------------------------------------------------------------+
//| Methode zur Überprüfung der Kerzenformation "Dark Cloud Cover"   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternDarkCloudCover()
  {
//--- Dark cloud cover - Erkennung des Musters "Dark cloud cover"
   if((Close(2)-Open(2)>AvgBody(1))  && // langer Körper der weißen Kerze (long white)
      (Close(1)<Close(2))            && // darauf folgt eine schwarze Kerze
      (Close(1)>Open(2))             && // deren Schlusskurs innerhalb des Körpers der weißen Kerze liegt (close within previous body)
      (MidOpenClose(2)>CloseAvg(1))  && // Aufwärtstrend (uptrend)
      (Open(1)>High(2)))                // der Eröffnungskurs liegt über dem Tageshoch des Vortages (open at new high)
      return(true);
//---
   return(false);
  }

1.2. Kerzenformation "Piercing Line"

Das Muster weist auf die Umkehr eines bärischen Trends hin (ähnlich wie die "Dunkle Wolkendecke"). Am ersten Tag wird eine große schwarze Kerze gebildet, dann folgt eine Gap Down Eröffnung (unterhalb des Tageshochs des Vortages), der Schlusskurs liegt über der Mitte des Vortages. Dies ist einer der wenigen Fälle, wenn Hoch und Tief in Candlesticks berücksichtigt werden.

Abb. 2. Kerzenformation "Piercing Line"

Methode zur Erkennung des Musters "Piercing Line":

//+------------------------------------------------------------------+
//| Methode zur Überprüfung der Formation Piercing Line              |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternPiercingLine()
  {
//--- Piercing Line - Erkennung der Kerzenformataion "Piercing Line"
   if((Close(1)-Open(1)>AvgBody(1)) && // langer Körper der weißen Kerze (long white)
      (Open(2)-Close(2)>AvgBody(1)) && // langer Körper der vorherigen schwarzen Kerze (long black)
      (Close(1)>Close(2))           && // Close innerhalb des Körpers
      (Close(1)<Open(2))            && // der vorherigen Kerze (close inside previous body) 
      (MidOpenClose(2)<CloseAvg(2)) && // Abwärtstrend (downtrend)
      (Open(1)<Low(2)))                // Open unter dem Tagestief (open lower than previous Low) 
      return(true);
//---
   return(false);
  }

2. Handelssignale in der Kombination mit dem Stochastic Indikator

Die Signale zum Eröffnen einer Long- oder Short-Position werden nur unter der Bedingung gesendet, dass das Umkehrmuster durch die Lage des Stochastic-Oszillator bestätigt wird. Der Wert der Signallinie %D muss oberhalb oder unterhalb eines entsprechenden kritischen Levels liegen (30 und 70).

Die Ausstiegssignale werden je nach dem weiteren Verhalten der %D gebildet: wenn %D einen gegensätzlichen Level erreicht (80 in Long- und 20 in Short-Positionen) oder wenn %D das Umkehrsignal nicht bestätigt und den Level 20 in einer Long- und 80 in einer Short-Position erreicht.

Abb. 3. Handelssignale des Musters "Dark Cloud Cover" mit der Bestätigung durch den Stochastic Indikator

Die Bedingungen für Einstieg und Ausstieg werden in den folgenden Methoden überprüft:

• int CDC_PL_Stoch::LongCondition() überprüft die Bedingungen für das Eröffnen einer Long-Position (die Funktion gibt 80 zurück) und Schließen einer Short-Position (die Funktion gibt 40 zurück);
  
• int CDC_PL_Stoch::ShortCondition() überprüft die Bedingungen für das Eröffnen einer Short-Position (die Funktion gibt 80 zurück) und Schließen einer Long-Position (die Funktion gibt 40 zurück).

2.1. Eröffnen einer Long-Position und Schließen einer Short-Position

1. Das Signal zum Eröffnen einer Long-Position entsteht, wenn das Muster Piercing Line auftritt und die Bedingung StochSignal(1)<30 (der Wert der Signallinie des Stochastic Indikators auf dem letzten vollendeten Balken ist kleiner als 30) erfüllt ist:

2. Das Signal zum Schließen einer Short-Position entsteht, wenn die Signallinie des Stochastic Indikators den Level 20 (von unten nach oben) oder den Level 80 (von unten nach oben) kreuzt.
   

   //+--------------------------------------------------------------------+
   //| Methode zur Überprüfung der Bedingungen für Einstieg und Ausstieg  |
   //| Überprüfung der Bedingungen für                                    |
   //| 1) Einstieg (Eröffnen einer Long-Position, result=80)              |
   //| 2) Ausstieg (Schließen einer Short-Position, result=40)            |
   //+--------------------------------------------------------------------+
   int CDC_PL_Stoch::LongCondition()
     {
      int result=0;
   //--- idx kann verwendet werden, um den Modus des EAs festzustellen
   //--- idx=0 - der EA wird die Erfüllung der Bedingungen auf jedem Tick überprüfen
   //--- idx=1 - der EA wird die Erfüllung der Bedingungen nur auf neuen Balken überprüfen
      int idx   =StartIndex();
   //--- Überprüfung der Bedingungen für das Eröffnen einer Long-Position
   //--- bärische Kerzenkombination Piercing Line und Erfüllung der Bedingung signal line<30
     if (CheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) && (StochSignal(1)<30))
        result=80;
   //--- Überprüfung der Bedingungen für das Schließen einer Short-Position
   //--- die Signallinie kreuzt die Levels (20 von oben nach unten, 80 von unten nach oben)
      if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
          ((StochSignal(1)>80) && (StochSignal(2)<80))))
        result=40;
   //--- result zurückgeben
      return(result);
     }
   
   
   

2.2. Eröffnen einer Short-Position und Schließen einer Long-Position

1. Das Signal zum Eröffnen einer Short-Position entsteht, wenn das Muster Dark Cloud Cover (dunkle Wolkendecke) auftritt und die Bedingung StochSignal(1)>70 erfüllt ist (der Wert der Signallinie des Stochastic Indikators auf dem letzten vollständigen Balken ist größer als 70):

2. Das Signal zum Schließen einer Long-Position entsteht, wenn die Signallinie des Stochastic Indikators den Level 80 (von oben nach unten) oder des Levels 20 von oben nach unten) kreuzt.
   

   //+--------------------------------------------------------------------+
   //| Methode zur Überprüfung der Bedingungen für Einstieg und Ausstieg  |
   //| Überprüfung der Bedingungen für                                    |
   //| 1) Einstieg (Eröffnen einer Short-Position, result=80)             |
   //| 2) Ausstieg (Schließen einer Long-Position, result=40)             |
   //+--------------------------------------------------------------------+
   int CDC_PL_Stoch::ShortCondition()
     {
      int result=0;
   //--- idx kann verwendet werden, um den Modus des EAs festzustellen
   //--- idx=0 - der EA wird die Erfüllung der Bedingungen auf jedem Tick überprüfen
   //--- idx=1 - der EA wird die Erfüllung der Bedingungen nur auf neuen Balken überprüfen
      int idx   =StartIndex();
   //--- Überprüfung der Bedingungen für das Eröffnen einer Short-Position
   //--- Auftreten des Musters Dark Cloud Cover und Erfüllung der Bedingung signal line>70
     if (CheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) && (StochSignal(1)>70))
        result=80;
   //--- Überprüfung der Bedingungen für das Schließen einer Long-Position
   //--- die Signallinie kreuzt die Levels (80 - von oben nach unten, 20 von oben nach unten)
      if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
          ((StochSignal(1)<20) && (StochSignal(2)>20))))
        result=40;
   //--- result zurückgeben
      return(result);
     }
   
   

Starten Sie den MQL5 Wizard, um einen Handelsroboter nach dieser Strategie zu erstellen:

Abb. 4. Erstellung eines EAs im MQL5 Wizard

Klicken Sie auf "Next" und geben Sie den Namen des EAs ein:

Abb. 5. Allgemeine Parameter des EAs

Danach sind die Parameter der Signale einzugeben:

In unserem Fall verwenden wir nur ein Modul von Handelssignalen.

Fügen wir das Modul "Signals based on Dark Cloud Cover/Piercing Line confirmed by Stochastic" hinzu:

Abb. 7. Parameter der Signale

Das Modul ist hinzugefügt:

Abb. 8. Parameter der Signale

Danach kann man das Modul des Trailings auswählen, wir werden es allerdings nicht verwenden. "Trailing Stop not used" auswählen:

Abb. 9. Trailing Modul

Des Weiteren ist das Money Management Modul auszuwählen, wir werden den Handel mit einem festen Volumen (Trading with fixed trade volume) verwenden:

Abb. 10. Money Management Modul

Klicken Sie auf "Finish", und Sie bekommen den Code des generierten Expert Advisors - die Datei Expert_ADC_PL_Stoch.mq5 wird im Verzeichnis terminal_data_folder\MQL5\Experts\ gespeichert wird.

Die Eingabeparameter des Expert Advisors (default):

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in Punkten)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in Punkten)

ersetzen durch:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in Punkten)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in Punkten)

Die Parameter Signal_ThresholdOpen und Signal_ThresholdClose lassen Schwellenwerte für das Eröffnen und Schließen von Position setzen.

Im Code der Funktionen LongCondition() und ShortCondition() des Moduls von Handelssignalen haben wir die festen Schwellenwerte angegeben:

• Für das Eröffnen von Positionen: 80;
• Für das Schließen von Positionen: 40.
  

Die Werte von Signal_StopLevel und Signal_TakeLevel setzen wir auf 0, dies bedeutet, dass die Positionen nur beim Eingehen von Handelssignalen zum Schließen geschlossen werden.

2.4 Testergebnisse anhand historischer Daten

Die Ergebnisse des Testens anhand historischer Daten (EURUSD H1, Testperiode: 1.1.2010-02.23.2011,  PeriodK=9, PeriodD=5, PeriodSlow=20, MA_period=27).

Dieser Expert Advisor benutzt das Modul für den Handel mit einer festgelegten Lotgröße von 0.1 Lot (Trading Fixed Lot), ein Trailing Stop wurde nicht verwendet (Trailing not used).

Abb. 11. Testergebnisse für den EA, der auf der Basis des Generators der Handelssignale "Dark Cloud Cover/Piercing Line + Stochastic" erstellt wurde

Das beste Parameterset für das Tradingsystem ist mithilfe von Strategietester des MetaTrader 5 Kundenterminals zu finden.

Der von dem MQL5 Wizard generierte Code für den Expert Advisor ist angehängt als Datei: expert_adc_pl_stoch.mq5.