Скачать MetaTrader 5

Смотри, как бесплатно скачать роботов

Интересный скрипт?
Поставь на него ссылку - пусть другие тоже оценят

Понравился скрипт?
Оцени его работу в терминале MetaTrader 5

2011.02.23 17:56
Советники

Мастер MQL5 - Торговые сигналы свечных паттернов Dark Cloud Cover/Piercing Line + Stochastic - эксперт для MetaTrader 5

| Russian English 中文 Español Deutsch 日本語 Português

Просмотров:
2484
Рейтинг:
голосов: 21
\MQL5\Include\Expert\Signal\MySignals\

С появлением Мастера MQL5 появилась возможность автоматической генерации кода советника на базе классов торговых сигналов, сопровождения позиций и управления капиталом. Помимо классов торговых сигналов из Стандартной библиотеки, вы можете создавать и тестировать свои собственные торговые системы, для этого достаточно написать модуль торговых сигналов.

В книге "Стратегии лучших трейдеров мира" описаны индикаторы и торговые стратегии для технического анализа с использованием программного пакета MetaStock. Наряду с традиционными, в ней рассмотрены торговые сигналы, основанные на совместном использовании разворотных свечных моделей с подтверждением от осцилляторов Stochastic, CCI, MFI и RSI.

Использование "разворотных" свечных моделей совместно с сигналами осцилляторов позволяет сократить количество ложных сигналов и повысить эффективность торговой системы.

В данной работе мы рассмотрим результаты использования моделей Dark Cloud Cover (завеса из темных облаков) и Piercing Line (просвет в облаках) в комбинации с сигналами индикатора Stochastic.


1. Паттерны "Dark Cloud Cover" и "Piercing Line" и их распознавание

1.1. Паттерн "Завеса из темных облаков" (Dark Cloud Cover)

Фигура, сигнализирующая о развороте бычьего тренда. Первый день - большая белая свеча, в следующий день высокое открытие (выше максимума предыдущего дня) и закрытие ниже середины первого дня. Это один из немногих случаев, когда в подсвечниках учитываются максимум и минимум.

Рис. 1. Свечной паттерн "Dark Cloud Cover"

Рис. 1. Свечной паттерн "Dark Cloud Cover"

Распознавание паттерна "Dark Cloud Cover" реализовано в методе CheckPatternDarkCloudCover класса CCandlePattern:

//+------------------------------------------------------------------+
//| Метод проверки формирования свечной модели "Dark Cloud Cover"    |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternDarkCloudCover()
  {
//--- Dark cloud cover - распознавание паттерна "Завеса из темных облаков"
   if((Close(2)-Open(2)>AvgBody(1))  && // длинное тело белой свечи (long white)
      (Close(1)<Close(2))            && // далее следует черная свеча
      (Close(1)>Open(2))             && // с закрытием внутри тела белой свечи (close within previous body)
      (MidOpenClose(2)>CloseAvg(1))  && // тренд восходнящий (uptrend)
      (Open(1)>High(2)))                // открытие выше максимальной цены предыдущего дня (open at new high)
      return(true);
//---
   return(false);
  }

Для проверки факта формирования модели "Dark Cloud Cover" используется метод CheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) класса CCandlePattern.


1.2. Паттерн "Просвет в облаках" (Piercing Line)

Фигура, сигнализирующая о развороте медвежьего тренда (аналог "завесы из темных облаков"). Первый день - большая черная свеча, следующее низкое открытие (ниже минимума предыдущего дня) и закрытие выше середины первого дня. Это один из немногих случаев, когда в подсвечниках учитываются максимум и минимум.

Рис. 2. Свечной паттерн "Piercing Line"

Рис. 2. Свечной паттерн "Piercing Line"

Метод распознавания модели "Piercing Line":

//+------------------------------------------------------------------+
//| Метод проверки формирования свечной модели "Piercing Line"       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternPiercingLine()
  {
//--- Piercing Line - распознавание паттерна "просвет в облаках"
   if((Close(1)-Open(1)>AvgBody(1)) && // длинное тело белой свечи (long white)
      (Open(2)-Close(2)>AvgBody(1)) && // длинное тело предыдущей черной свечи (long black)
      (Close(1)>Close(2))           && // закрытие внутри тела 
      (Close(1)<Open(2))            && // предыдущей свечи (close inside previous body) 
      (MidOpenClose(2)<CloseAvg(2)) && // нисходящий тренд (downtrend)
      (Open(1)<Low(2)))                // открытие ниже цены закрытия (open lower than previous Low) 
      return(true);
//---
   return(false);
  }

Для проверки факта формирования модели "Piercing Line" используется метод CheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) класса CCandlePattern.


2. Торговые сигналы в комбинации с индикатором Stochastic

Сигналы входа в длинную или короткую позицию подаются только при условии, что разворотная фигура на диаграмме свечей подтверждается положением стохастического осциллятора. Значение сигнальной линии %D должно быть выше, или ниже соответствующего критического уровня (30 и 70).

Сигналы выхода из позиций формируются в зависимости от дальнейшего поведения %D. Если %D достигает противоположной рынку отметки (80 в длинной и 20 в короткой позициях) или если %D не подтверждает сигнала разворота и достигает уровня 20 в длинной и 80 в короткой позициях.

Рис. 3. Торговые сигналы паттернов "Завеса из темных облаков" с подтверждением от индикатора Stochastic

Рис. 3. Торговые сигналы паттерна "Завеса из темных облаков" с подтверждением от индикатора Stochastic


Реализация проверки условий входа и выхода в рынок осуществляется в методах:

  • int CDC_PL_Stoch::LongCondition() - проверка условий для открытия длинной позиции (ф-я возвращает 80) и закрытия короткой позиции (ф-я возвращает 40);
  • int CDC_PL_Stoch::ShortCondition() - проверка условий для открытия короткой позиции (ф-я возвращает 80) и закрытия длинной позиции (ф-я возвращает 40).

2.1. Открытие длинной позиции и закрытие короткой позиции

  1. Сигналом к открытию длинной позиции является формирование свечной комбинации Piercing Line (просвет в облаках) и выполнение условия StochSignal(1)<30 (значение сигнальной линии индикатора Stochastic на последнем завершенном баре меньше 30):

  2. Сигналом к закрытию короткой позиции является пересечение сигнальной линией индикатора Stochastic уровня 20 (снизу вверх) или уровня 80 (снизу вверх).

    //+------------------------------------------------------------------+
    //| Метод проверки условий для входа и выхода с рынка                |
    //| Проверка условий для                                             |
    //| 1) входа в рынок (открытие длинной позиции, result=80)           |
    //| 2) выхода из рынка (закрытие короткой позиции, result=40)        |
    //+------------------------------------------------------------------+
    int CDC_PL_Stoch::LongCondition()
      {
       int result=0;
    //--- idx можно использовать для того чтобы узнать режим работы эксперта
    //--- idx=0 - эксперт будет вызывать проверки выполнения торговых условий на каждом тике
    //--- idx=1 - эксперт будет вызывать проверки выполнения торговых условий только на новых барах
       int idx   =StartIndex();
    //--- проверка условий для открытия длинной позиции
    //--- формирование бычьей свечной комбинации Piercing Line и выполнения условия signal line<30
      if (CheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) && (StochSignal(1)<30))
         result=80;
    //--- проверка условий для закрытия короткой позиции
    //--- пересечение сигнальной линией уровней (сверху вниз 20, снизу вверх 80)
       if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
           ((StochSignal(1)>80) && (StochSignal(2)<80))))
         result=40;
    //--- возвращаем result
       return(result);
      }
    
    

2.2. Открытие короткой позиции и закрытие длинной позиции

  1. Сигналом к открытию короткой позиции является формирование паттерна Dark Cloud Cover (завеса из темных облаков) и выполнение условия StochSignal(1)>70 (значение сигнальной линии индикатора Stochastic на последнем завершенном баре больше 70):

  2. Сигналом к закрытию длинной позиции является пересечение сигнальной линией индикатора Stochastic уровня 80 (сверху вниз) или уровня 20 (сверху вниз).

    //+------------------------------------------------------------------+
    //| Метод проверки условий для входа и выхода с рынка                |
    //| Проверка условий для                                             |
    //| 1) входа в рынок (открытие короткой позиции, result=80)          |
    //| 2) выхода из рынка (закрытие длинной позиции, result=40)         |
    //+------------------------------------------------------------------+
    int CDC_PL_Stoch::ShortCondition()
      {
       int result=0;
    //--- idx можно использовать для того чтобы узнать режим работы эксперта
    //--- idx=0 - эксперт будет вызывать проверки выполнения торговых условий на каждом тике
    //--- idx=1 - эксперт будет вызывать проверки выполнения торговых условий только на новых барах
       int idx   =StartIndex();
    //--- проверка условий для открытия короткой позиции
    //--- формирование медвежьей свечной комбинации Dark Cloud Cover и выполнения условия signal line>70
      if (CheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) && (StochSignal(1)>70))
         result=80;
    //--- проверка условий для закрытия длинной позиции
    //--- пересечение сигнальной линией уровней (сверху вниз 80, сверху вниз 20)
       if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
           ((StochSignal(1)<20) && (StochSignal(2)>20))))
         result=40;
    //--- возвращаем result
       return(result);
      }
    



2.3. Создание эксперта на основе торговых сигналов разворотной модели "Dark Cloud Cover/Piercing Line + Stochastic" при помощи Мастера MQL5

Класс CBE_BE_Stoch не входит в Стандартную библиотеку классов торговых сигналов, поэтому для его использования нужно скачать файл acdc_pl_stoch.mqh (прилагается) и сохранить его в каталог_данных_терминала\Include\Expert\Signal\MySignals. Файл acandlepatterns.mqh следует скопировать в тот же каталог, что и файл acdc_pl_stoch.mqh. После этого, перезапустив MetaEditor, вы получите возможность его использования в Мастере MQL5.

Чтобы создать торгового робота по данной стратегии запустите Мастер MQL5:

Рис. 4. Создание советника в Мастере MQL5

Рис. 4. Создание советника в Мастере MQL5

Нажав на кнопку "Далее", укажем имя советника:

Рис. 5. Общие параметры советника

Рис. 5. Общие параметры советника

После этого нужно указать параметры сигналов.

Рис. 6. Параметры сигналов советника

В нашем случае мы будем использовать лишь один модуль торговых сигналов.

Добавляем модуль "Signals based on Dark Cloud Cover/Piercing Line confirmed by Stochastic":

Рис. 7. Параметры сигналов советника

Рис. 7. Параметры сигналов советника

Модуль сигналов добавлен:

Рис. 8. Параметры сигналов советника

Рис. 8. Параметры сигналов советника

После этого можно выбрать модуль трейлинга, мы его использовать не будем. Выбираем "Trailing Stop not used":

Рис. 9. Выбор модуля трейлинга

Рис. 9. Выбор модуля трейлинга

Затем нужно выбрать модуль управления капиталом, мы будем использовать торговлю с фиксированным объемом (Trading with fixed trade volume):

Рис. 10. Выбор модуля управления капиталом

Рис. 10. Выбор модуля управления капиталом

Нажав на кнопку "Готово", мы получим код сгенерированного советника - файл Expert_ADC_PL_Stoch.mq5, который будет сохранен в папке: каталог_данных_терминала\MQL5\Experts\.

Входные параметры (по умолчанию) советника:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

заменяем на:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Параметры Signal_ThresholdOpen и Signal_ThresholdClose позволяют задать пороги для открытия и закрытия позиций.

В коде функций LongCondition() и ShortCondition() модуля торговых сигналов мы указали фиксированные значения порогов:

  • Для открытия позиций: 80;
  • Для закрытия позиций: 40.

Советник, сгенерированный при помощи Мастера MQL5, принимает решение об открытии или закрытии позиции на основании результатов "голосования" модулей торговых сигналов, добавленных в процессе создания советника. При этом основной модуль (содержащий все добавленные модули) торговых сигналов также принимает участие в "голосовании", однако его методы LongCondition() и ShortCondition() всегда возвращают 0.

Поскольку при расчете "голосов" производится усреднение по количеству присутствующих модулей (основной + один добавленный модуль), то значения порогов следует указывать с учетом данного обстоятельства. По этой причине значения величин Signal_ThresholdOpen и Signal_ThresholdClose должны быть установлены в 40=(0+80)/2 и 20=(0+40)/2 соответственно.

Значения входных параметров Signal_StopLevel и Signal_TakeLevel устанавливаем в 0, это означает, что закрытие позиций будет осуществляться только при поступлении торговых сигналов на закрытие позиций.


2.4 Результаты тестирования на истории

Результаты тестирования советника на исторических данных (EURUSD H1, период тестирования: 1.1.2010-02.23.2011,  PeriodK=9, PeriodD=5, PeriodSlow=20, MA_period=27).

В данном советнике использовался модуль торговли фиксированным объемом 0.1 лота (Trading Fixed Lot), трейлинг не использовался (Trailing not used).

Рис. 11. Результаты тестирования советника, построенного на базе генератора торговых сигналов "Dark Cloud Cover/Piercing Line + Stochastic"

Рис. 11. Результаты тестирования советника, построенного на базе генератора торговых сигналов "Dark Cloud Cover/Piercing Line + Stochastic"

Наилучший набор параметров торговой системы можно найти при помощи Тестера Стратегий терминала MetaTrader 5.

Код советника, созданного Мастером MQL5, прилагается в файле expert_adc_pl_stoch.mq5.


Скрипт для ChartNavigate Скрипт для ChartNavigate

Простой демонстрационный скрипт по использованию функции ChartNavigate()

Demo_DRAW_ZIGZAG Demo_DRAW_ZIGZAG

Простейший индикатор с использованием стиля DRAW_ZIGZAG.

Мастер MQL5 - Торговые сигналы свечных паттернов Dark Cloud Cover/Piercing Line + CCI Мастер MQL5 - Торговые сигналы свечных паттернов Dark Cloud Cover/Piercing Line + CCI

Торговые сигналы свечных моделей "Dark Cloud Cover/Piercing Line" (Завеса из темных облаков/Просвет в облаках) с подтверждением от индикатора CCI.

Мастер MQL5 - Торговые сигналы свечных паттернов Dark Cloud Cover/Piercing Line + MFI Мастер MQL5 - Торговые сигналы свечных паттернов Dark Cloud Cover/Piercing Line + MFI

Торговые сигналы свечных моделей "Dark Cloud Cover/Piercing Line" (Завеса из темных облаков/Просвет в облаках) с подтверждением от индикатора MFI.