HistoryPositionInfo 版本 2 - MetaTrader 5程序库

版本 1.0: HistoryPositionInfo.

版本 2 的新功能:

还有 GetProfitInPoints 函数, 但是推荐使用新的 GetProfit 函数:

   bool              GetProfit(double &profit_in_points,
                               double &commission,
                               double &swap,
                               double &profit_in_money);

GetProfit 函数返回以下的仓位信息, 除了利润点数之外: 手续费，隔夜息以及利润钱数。

CHistoryPositionInfo 类是设计用于在交易历史中取得仓位的利润点数，手续费，隔夜息和利润钱数的。

类的描述 

CHistoryPositionInfo 类可以从交易历史中取得仓位的利润点数，手续费，隔夜息和利润钱数。 

声明

头文件

类方法分组

一个使用 CHistoryPositionInfo 类的实例: 请求5天的交易历史，生成所有找到仓位的标示符的数组，然后在循环中打印如下信息: 交易历史中仓位的利润点数, 手续费，隔夜息和利润钱数。

//+------------------------------------------------------------------+
//|                                      TestHistoryPositionInfo.mq5 |
//|                              Copyright © 2017, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2017, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "2.000"
#property script_show_inputs
//---
input datetime from_date   = __DATE__-60*60*24*5;  // 开始的日期 (当前日期 - 5 天)
input datetime to_date     =__DATE__+60*60*24;     // 结束日期 (当前日期 + 1 天)
input bool     log_errors  = true;                 // 记录错误
input bool     print_deals = true;                 // 打印交易
#include <HistorySelect_\HistoryPositionInfo.mqh>
//+------------------------------------------------------------------+
//| 脚本程序起始函数                         |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   long arr_tickets[];
//--- 请求交易历史 
   HistorySelect(from_date,to_date);
//---
   uint     total=HistoryDealsTotal();
   ulong    ticket=0;
   long     position_id=0;
//--- 对于所有交易 
   for(uint i=0;i<total;i++)
     {
      //--- 尝试取得交易单号
      if((ticket=HistoryDealGetTicket(i))>0)
        {
         //--- 取得交易属性 
         position_id=HistoryDealGetInteger(ticket,DEAL_POSITION_ID);

         int arr_size=ArraySize(arr_tickets);
         bool search=false;
         for(int ii=0;ii<arr_size;ii++)
           {
            if(arr_tickets[ii]==position_id)
              {
               search=true;
               continue;
              }
           }
         if(!search)
           {
            ArrayResize(arr_tickets,arr_size+1,100);
            arr_tickets[arr_size]=position_id;
           }
        }
     }
//---
   int arr_size=ArraySize(arr_tickets);
   for(int i=0;i<arr_size;i++)
     {
      Print("");
      Print("根据 POSITION_IDENTIFIER 搜索交易",IntegerToString(arr_tickets[i]));

      CHistoryPositionInfo HistoryPositionInfo;
      //--- 初始化仓位标识符
      HistoryPositionInfo.Init(arr_tickets[i]);
      //--- 记录错误
      HistoryPositionInfo.LogErrors(log_errors);
      //--- 打印交易
      HistoryPositionInfo.PrintDeals(print_deals);
      //---
      double profit_in_points=0.0;
      double commission=0.0;
      double swap=0.0;
      double profit=0.0;

      if(HistoryPositionInfo.GetProfit(profit_in_points,commission,swap,profit))
         Print("利润点数 ",DoubleToString(profit_in_points,1),
               ", 手续费 ",DoubleToString(commission,2),
               ", 隔夜息 ",DoubleToString(swap,2),
               ", 利润 ",DoubleToString(profit,2));
     }
  }
//+------------------------------------------------------------------+