演示_FileCopy - MetaTrader 5脚本

这段脚本简单示例如何使用 FileCopy() 函数将一个文件的内容复制到另一个。源文件必须在客户端本地文件夹下，文件名由 "InpSrc" 输入参数指定。客户端的本地文件夹位置包含在 TerminalInfoString() 函数。

PrintFormat("客户端本地文件夹路径: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH)); 

代码:

//--- 当脚本启动时显示输入参数窗口
#property script_show_inputs
//--- 输入参数
input string InpSrc="source.txt";       // source
input string InpDst="destination.txt";  // copy
input int    InpEncodingType=FILE_ANSI; // ANSI=32 or UNICODE=64
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 显示源内容 (它必须存在)
   if(!FileDisplay(InpSrc))
      return;
//--- 检查目的是否文件已经存在 (也许没有)
   if(!FileDisplay(InpDst))
     {
      //--- 目的文件不存在, 复制无需使用 FILE_REWRITE 标志 (正确复制)
      if(FileCopy(InpSrc,0,InpDst,0))
         Print("文件已复制!");
      else
         Print("文件未复制!");
     }
   else
     {
      //--- 目的文件已存在, 尝试复制且不用 FILE_REWRITE 标志 (不正确复制)
      if(FileCopy(InpSrc,0,InpDst,0))
         Print("文件已复制!");
      else
         Print("文件未复制!");
      //---InpDst 文件的内容一致
      FileDisplay(InpDst);
      //--- 再次复制，使用 FILE_REWRITE 标志 (正确复制即使文件存在)
      if(FileCopy(InpSrc,0,InpDst,FILE_REWRITE))
         Print("文件已复制!");
      else
         Print("文件未复制!");
     }
//--- 接收 InpSrc 文件复制
   FileDisplay(InpDst);
  }
//+------------------------------------------------------------------+
//| Read the file contents                                           |
//+------------------------------------------------------------------+
bool FileDisplay(const string file_name)
  {
//---重置错误值
   ResetLastError();
//--- 打开文件
   int file_handle=FileOpen(file_name,FILE_READ|FILE_TXT|InpEncodingType);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- 循环显示文件内容
      Print("+---------------------+");
      PrintFormat("文件名 = %s",file_name);
      while(!FileIsEnding(file_handle))
         Print(FileReadString(file_handle));
      Print("+---------------------+");
      //--- 关闭文件
      FileClose(file_handle);
      return(true);
     }
//--- 打开文件失败
   PrintFormat("%s 没有打开, 错误代码 = %d",file_name,GetLastError());
   return(false);
  }