"MQL5 Cookbook: Hızlı Veri Erişimi için İlişkisel Dizi veya Sözlük Uygulama" makalesi için tartışma - sayfa 3

[Little---Prince]

Forex altın teknik analiz borsaları, grup numarası 375124107, grup doğrulaması 77'ye, işbirliği için teşekkür ederiz!

[Sergei Lebedev]

Bu sınıfı EA'mda (StrategyGUID, Strategy) formundaki stratejilerin bir konteyneri olarak kullanmaya karar verdim, burada StrategyGUID ulong tipinde bir tanımlayıcıdır; Strateji, CObject'ten miras alınan bir sınıf temelinde oluşturulan bir stratejidir.

Buna göre, aktif stratejiler kitabı olan CDictionary StrategyBook dahil olmak üzere gerekli değişkenleri beyan ediyorum; EA'nın OnInit () işlevinde kendilerine benzersiz GUID'ler atamak da dahil olmak üzere çeşitli parametreleri başlatan gerekli Strategy01, Strategy02 stratejilerini oluşturuyorum. OnInit () işlevinin en sonunda, kodu çağırarak stratejileri StrategyBook'a kaydetmeye karar veriyorum

StrategyBook.AddObject(Strategy01.strGUID,Strategy01);

StrategyBook.AddObject(Strategy02.strGUID,Strategy02); 

Ve sonra her iki satırda da "StrategyXX - parametre dönüşümüne izin verilmiyor" hatasını alıyorum.

C# ile olan deneyimime dayanarak, her şey doğru şekilde yapıldı. Ancak MQL5'te bu hatayı alıyorum.

Ne ile ilgili olabilir?

[Vasiliy Sokolov]

Сергей Лебедев:

Bu sınıfı EA'mda (StrategyGUID, Strategy) formundaki stratejilerin bir konteyneri olarak kullanmaya karar verdim, burada StrategyGUID ulong tipinde bir tanımlayıcıdır; Strateji, CObject'ten miras alınan bir sınıf temelinde oluşturulan bir stratejidir.

Buna göre, aktif stratejiler kitabı olan CDictionary StrategyBook dahil olmak üzere gerekli değişkenleri beyan ediyorum; EA'nın OnInit () işlevinde kendilerine benzersiz GUID'ler atamak da dahil olmak üzere çeşitli parametreleri başlatan gerekli Strategy01, Strategy02 stratejilerini oluşturuyorum. OnInit () işlevinin en sonunda, kodu çağırarak stratejileri StrategyBook'a kaydetmeye karar veriyorum

StrategyBook.AddObject(Strategy01.strGUID,Strategy01);

StrategyBook.AddObject(Strategy02.strGUID,Strategy02); 

Ve sonra her iki satırda da "StrategyXX - parametre dönüşümüne izin verilmiyor" hatasını alıyorum.

C# ile olan deneyimime dayanarak, her şey doğru şekilde yapıldı. Ancak MQL5'te bu hatayı alıyorum.

Bu ne ile ilgili olabilir?

Birkaç nedeni olabilir. Büyük olasılıkla, ya tür uyumsuzluğu ya da işaretçilerle yanlış çalışma. Ayrıca, şablon yöntemlerle çalışmanın özelliklerini de göz ardı edemeyiz (bunların da kendi nüansları vardır).

Genel olarak, hazır bir ticaret motoru kullanmak daha iyidir, çok fazla zaman ve sinir tasarrufu sağlarsınız: https://www.mql5.com/tr/articles/2166.

[Sergei Lebedev]

Evet, sonunda yapmaya karar verdiğim şey buydu.

[Hennie Reyneke]

MetaQuotes Software Corp.:

Yeni makale MQL5 Yemek Kitabı: Implementing an Associative Array or a Dictionary for Quick Data Access makalesi yayınlandı:

Yazar Vasiliy Sokolov

Tüm çabalarınız için teşekkürler, ancak kod örneklerinden hiçbirini çalıştıramıyorum.

Görünüşe göre Dictionary dict; CDictionary dict olmalı;

Basit bir çalışma örneğine ne dersiniz?

[[Silindi]]

Yeni MT4 (Build 1080, 12 Mayıs 2017) ile ilgili olarak bu hatalar derleme sırasında ortaya çıkar ve yürütmeyi engeller:

'm_array' - nesne içeren yapılara izin verilmez Dictionary.mqh 303 25

cannot cast 'DoubleValue' to 'ULongValue' Dictionary.mqh 252 14

[Pierre Rougier]

Merhaba,

Daha önce başka bir kişi tarafından söylendiği gibi, derlenebilir bir örnek yoktur.

Sadece Rusça yorumlar içeren bir dosya.

[Gerik]

Merhaba Vasily,

yararlı makaleniz için teşekkür ederim. dictionary.mqh dosyanızı MQL5 build 2063 ile indirip derlerken aşağıdaki hataları alıyorum:

'GetKey' - işlev zaten tanımlanmış ve farklı bir türe sahip

'Compress' - işlev zaten tanımlanmış ve farklı bir türe sahip

Neden böyle oldu?

Saygılarımla

Gerik

[Marcel Fitzner]

Vasiliy'nin kütüphanesini minnetle ve başarıyla kullanıyorum. Gerçekten çok yardımcı oldu!

Ben de bazı derleyici hataları aldığımı ve bunları düzeltebildiğimi hatırlıyorum. Ancak, hangileri olduğunu ve ne yaptığımı gerçekten söyleyemem.

Ve MQL5 kodunun biçimlendirmesinden son derece rahatsız olduğum ve her şeyi her zaman modern bir C++ formatına göre yeniden biçimlendirdiğim için (uygun girintileme, gereksiz parantezlerden kaçınma, yorum karmaşası yok, vb), koddaki gerçek değişikliğin ne olduğunu söylemem imkansız. Tek hatırladığım, değişikliklerin küçük olduğu.

Düzgün biçimlendirilmiş kütüphaneyi kullanmak isterseniz, işte burada:

(Not, sekme kullanıyorum, bu yüzden biçimlendirme burada bozuk görünüyor, ancak MetaEditor'de değil!)

//+------------------------------------------------------------------+
//|CD Sözlük.mqh |
//|Telif Hakkı 2015, Vasiliy Sokolov. |
//| http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2015, Vasiliy Sokolov."
#property link          "http://www.mql5.com"

#include  <Object.mqh>
#include  <Arrays\List.mqh>

#define  FOREACH_DICT(dict) for (CObject* node = (dict).GetFirstNode(); node != NULL; node = (dict).GetNextNode())

class KeyValuePair : public CObject
{
        private:
                string                          m_string_key;
                double                          m_double_key;
                ulong                           m_ulong_key;
                ulong                           m_hash;
                bool                            m_free_mode;
        public:
                CObject*                        object;
                KeyValuePair*           next_kvp;
                KeyValuePair*           prev_kvp;
                template <typename T>
                void                            KeyValuePair(T key, ulong hash, CObject *obj);
                                                        ~KeyValuePair();
                template <typename T>
                bool                            EqualKey(T key);
                template <typename T>
                void                            GetKey(T& gkey);
                ulong                           GetHash()                                       { return m_hash; }
                void                            FreeMode(bool free_mode)        { m_free_mode = free_mode; }
                bool                            FreeMode(void)                          { return m_free_mode; }
};

template <typename T>
void KeyValuePair::KeyValuePair(T key, ulong hash, CObject *obj)
{
        m_hash = hash;
        string name = typename(key);
        if (name == "string")
                m_string_key = (string)key;
        else if
                (name == "double" || name == "float")
        
        m_double_key = (double)key;
        else
                m_ulong_key=(ulong)key;
        
        object = obj;
        m_free_mode = true;
}

template <typename T>
void KeyValuePair::GetKey(T& gkey)
{
        string name = typename(gkey);
        if (name  ==  "string")
                gkey = (T)m_string_key;
        else if (name == "double" || name == "float")
                gkey = (T)m_double_key;
        else
                gkey = (T)m_ulong_key;
}

KeyValuePair::~KeyValuePair()
{
        if (m_free_mode)
                delete object;
}

template <typename T>
bool KeyValuePair::EqualKey(T key)
{
        string name=typename(key);
        if (name == "string")
                return m_string_key  ==  (string)key;
        if (name == "double" || name == "float")
                return m_double_key  ==  (double)key;
        else
                return m_ulong_key  ==  (ulong)key;
}

class CDictionary : public CObject
{
        private:
                int                                     m_array_size;
                int                                     m_total;
                bool                            m_free_mode;
                bool                            m_auto_free;
                int                                     m_index;
                ulong                           m_hash;
                CList*                          m_array[];
                union casting_struct
                {
                        double d_value;
                        ulong  l_value;
                } casting;
                
                KeyValuePair*           m_first_kvp;
                KeyValuePair*           m_current_kvp;
                KeyValuePair*           m_last_kvp;
        
                ulong                           Adler32(string line);
                int                                     GetIndexByHash(ulong hash);
                template <typename T>
                ulong                           GetHashByKey(T key);
                void                            Resize();
                int                                     FindNextSimpleNumber(int number);
                int                                     FindNextLevel();
                void                            Init(int capacity);
        
        public:
                                                        CDictionary();
                                                        CDictionary(int capacity);
                                                        ~CDictionary();
                void                            Compress(void);

                int Total(void)         { return m_total; }

                template <typename T>
                CObject*                        GetObjectByKey(T key);
                template <typename T>
                bool                            AddObject(T key, CObject *value);
                template <typename T>
                bool                            DeleteObjectByKey(T key);
                template <typename T>
                bool                            ContainsKey(T key);
                template <typename T>
                void                            GetCurrentKey(T &key);
                bool                            DeleteCurrentNode(void);
                bool                            FreeMode(void)                                          { return(m_free_mode); }
                void                            FreeMode(bool free_mode);
                void                            AutoFreeMemory(bool autoFree)           { m_auto_free = autoFree; }
                void                            Clear();
        
                CObject*                        GetNextNode(void);
                CObject*                        GetPrevNode(void);
                CObject*                        GetCurrentNode(void);
                CObject*                        GetFirstNode(void);
                CObject*                        GetLastNode(void);
};

CDictionary::CDictionary()
{
        Init(3);
        m_free_mode = true;
        m_auto_free = true;
}

CDictionary::CDictionary(int capacity)
{
        if (capacity < 3)
                Init(3);
        else
                Init(capacity);

        m_free_mode = true;
        m_auto_free = true;
}

CDictionary::~CDictionary()
{
        Clear();
}

void CDictionary::FreeMode(bool free_mode)
{
        if (free_mode == m_free_mode)
                return;

        m_free_mode = free_mode;

        for (int i=0; i < ArraySize(m_array); i++)
        {
                CList *list = m_array[i];
                if (CheckPointer(list) == POINTER_INVALID)
                        continue;

                for (KeyValuePair* kvp = list.GetFirstNode(); kvp != NULL; kvp = list.GetNextNode())
                        kvp.FreeMode(m_free_mode);
        }
}

void CDictionary::Init(int capacity)
{
        m_array_size = ArrayResize(m_array,capacity);
        m_index = 0;
        m_hash  = 0;
        m_total = 0;
}

int CDictionary::FindNextLevel()
{
        double value=4;
        for (int i=2; i <= 31; i++)
        {
                value = MathPow(2.0,(double)i);
                if (value > m_total)
                        return (int)value;
        }
        
        return (int)value;
}

ulong CDictionary::Adler32(string line)
  {
        ulong s1 = 1;
        ulong s2 = 0;
        uint buflength = StringLen(line);
        uchar char_array[];
        ArrayResize(char_array, buflength, 0);
        StringToCharArray(line, char_array, 0, -1, CP_ACP);
        for (uint n=0; n < buflength; n++)
        {
                s1 = (s1 + char_array[n]) % 65521;
                s2 = (s2 + s1) % 65521;
        }
        return ((s2  <<  16) + s1);
}

template <typename T>
ulong CDictionary::GetHashByKey(T key)
{
        ulong ukey = 0;
        string name = typename(key);
        if (name == "string")
                return Adler32((string)key);
        if (name == "double" || name == "float")
        {
                casting.d_value = (double)key;
                ukey = casting.l_value;
        }
        else
                ukey = (ulong)key;
        return ukey;
}

template <typename T>
void CDictionary::GetCurrentKey(T &key)
{
        m_current_kvp.GetKey(key);
}

int CDictionary::GetIndexByHash(ulong key)
{
        return (int)(key % m_array_size);
}

void CDictionary::Clear(void)
{
        int size = ArraySize(m_array);
        for (int i=0; i < size; i++)
        {
                if (CheckPointer(m_array[i]) != POINTER_INVALID)
                {
                        m_array[i].FreeMode(true);
                        delete m_array[i];
                }
        }
        ArrayFree(m_array);
        if (m_auto_free)
                Init(3);
        else
                Init(size);
                
        m_first_kvp = m_last_kvp = m_current_kvp = NULL;
  }

void CDictionary::Resize(void)
  {
        int level = FindNextLevel();
        int n = level;
        CList* temp_array[];
        ArrayCopy(temp_array, m_array);
        ArrayFree(m_array);
        m_array_size = ArrayResize(m_array,n);
        int total = ArraySize(temp_array);
        KeyValuePair* kv = NULL;
        
        for (int i=0; i < total; i++)
        {
                if (temp_array[i] == NULL)
                        continue;

                CList* list = temp_array[i];
                int count = list.Total();
                list.FreeMode(false);
                kv = list.GetFirstNode();

                while (kv != NULL)
                {
                        int index = GetIndexByHash(kv.GetHash());
                        if (CheckPointer(m_array[index]) == POINTER_INVALID)
                        {
                                m_array[index] = new CList();
                                m_array[index].FreeMode(true);  // Элементы KeyValuePair удаляются всегда
                        }
                        list.DetachCurrent();
                        m_array[index].Add(kv);
                        kv = list.GetCurrentNode();
                }
                delete list;
        }
        int size = ArraySize(temp_array);
        ArrayFree(temp_array);
}

void CDictionary::Compress(void)
{
        if (!m_auto_free)
                return;
        
        double koeff = m_array_size / (double)(m_total+1);
        if (koeff < 2.0 || m_total <= 4)
                return;

        Resize();
}

template <typename T>
CObject* CDictionary::GetObjectByKey(T key)
{
        if (!ContainsKey(key))
                return NULL;
        CObject *obj = m_current_kvp.object;
        return obj;
}

template <typename T>
bool CDictionary::ContainsKey(T key)
{
        m_hash = GetHashByKey(key);
        m_index = GetIndexByHash(m_hash);
        
        if (CheckPointer(m_array[m_index]) == POINTER_INVALID)
                return false;
        
        CList* list = m_array[m_index];
        
        KeyValuePair* current_kvp = list.GetCurrentNode();
        
        if (current_kvp  ==  NULL)
                return false;
        
        if (current_kvp.EqualKey(key))
        {
                m_current_kvp = current_kvp;
                return true;
        }
        
        current_kvp = list.GetFirstNode();
        while (true)
        {
                if (current_kvp.EqualKey(key))
                {
                        m_current_kvp = current_kvp;
                        return true;
                }
                current_kvp = list.GetNextNode();
                if (current_kvp == NULL)
                        return false;
        }
        return false;
  }

template <typename T>
bool CDictionary::AddObject(T key, CObject *value)
{
        if (ContainsKey(key))
                return false;
        
        if (m_total == m_array_size)
        {
                Resize();
                ContainsKey(key);
        }
        
        if (CheckPointer(m_array[m_index]) == POINTER_INVALID)
        {
                m_array[m_index] = new CList();
                m_array[m_index].FreeMode(true);
        }
        
        KeyValuePair *kv = new KeyValuePair(key,m_hash,value);
        kv.FreeMode(m_free_mode);
        
        if (m_array[m_index].Add(kv) != -1)
                m_total++;
        
        if (CheckPointer(m_current_kvp) == POINTER_INVALID)
        {
                m_first_kvp = kv;
                m_current_kvp = kv;
                m_last_kvp = kv;
        }
        else
        {
                while (m_current_kvp.next_kvp != NULL)
                        m_current_kvp = m_current_kvp.next_kvp;
                        
                m_current_kvp.next_kvp = kv;
                kv.prev_kvp = m_current_kvp;
                m_current_kvp = kv;
                m_last_kvp = kv;
        }
        return true;
}


CObject* CDictionary::GetCurrentNode(void)
{
        if (m_current_kvp == NULL)
                return NULL;

        return m_current_kvp.object;
}

CObject* CDictionary:: GetPrevNode(void)
{
        if (m_current_kvp == NULL)
                return NULL;

        if (m_current_kvp.prev_kvp == NULL)
                return NULL;

        KeyValuePair *kvp = m_current_kvp.prev_kvp;
        m_current_kvp = kvp;

        return kvp.object;
}

CObject* CDictionary::GetNextNode(void)
{
        if (m_current_kvp == NULL)
                return NULL;
        
        if (m_current_kvp.next_kvp == NULL)
                return NULL;
        
        m_current_kvp = m_current_kvp.next_kvp;

        return m_current_kvp.object;
}

CObject* CDictionary::GetFirstNode(void)
{
        if (m_first_kvp == NULL)
                return NULL;

        m_current_kvp = m_first_kvp;
        return m_first_kvp.object;
}

CObject *CDictionary::GetLastNode(void)
{
        if (m_last_kvp == NULL)
                return NULL;

        m_current_kvp = m_last_kvp;
        return m_last_kvp.object;
}

bool CDictionary::DeleteCurrentNode(void)
{
        if (m_current_kvp == NULL)
                return false;

        KeyValuePair* p_kvp = m_current_kvp.prev_kvp;
        KeyValuePair* n_kvp = m_current_kvp.next_kvp;

        if (CheckPointer(p_kvp) != POINTER_INVALID)
                p_kvp.next_kvp = n_kvp;

        if (CheckPointer(n_kvp) != POINTER_INVALID)
                n_kvp.prev_kvp = p_kvp;

        m_array[m_index].FreeMode(m_free_mode);
        bool res = m_array[m_index].DeleteCurrent();

        if (res)
        {
                m_total--;
                Compress();
        }
        return res;
}

template <typename T>
bool CDictionary::DeleteObjectByKey(T key)
{
        if (!ContainsKey(key))
                return false;
        return DeleteCurrentNode();
}

[Marcel Fitzner]

Sanırım bir öğeyi silerken ve son öğeye ulaşmaya çalışırken bir hata buldum:

class CWord : CObject
{
        string m_Word;

        public:
                CWord(string word) : m_Word(word) {}
                ~CWord() {}
                
                string GetWord() { return m_Word; }
};

CDictionary* testDict = new CDictionary(10);

testDict.AddObject(0, (CObject*)new CWord("A"));
testDict.AddObject(100, (CObject*)new CWord("A"));
testDict.AddObject(200, (CObject*)new CWord("B"));
testDict.AddObject(300, (CObject*)new CWord("C"));

CWord* lastWord = (CWord*)testDict.GetLastNode();
Print(lastWord.GetWord());

CWord* firstWord = (CWord*)testDict.GetFirstNode();
Print(firstWord.GetWord());

testDict.DeleteCurrentNode();

lastWord = testDict.GetLastNode(); // CDictionary::GetLastNode(void) içinde geçersiz işaretçi ile sonuçlanacaktır -> return m_last_kvp.object; -> m_last_kvp geçersiz işaretçidir!
Print(lastWord.GetWord());

CDictionary.mqh dosyasında hata oluşacaktır:

'Dictionary.mqh' içindegeçersiz işaretçi erişimi (463,9)

Bunu doğrulayabilecek biri var mı? Nasıl düzeltileceği hakkında fikri olan var mı?