Вопросы от начинающих MQL5 MT5 MetaTrader 5 - страница 1262

[Andrei Sokolov]

Здравствуйте. Подскажите, пожалста.

Как проверить является ли время торговым или нет?

(чтоб сделать чтоб советник начинал работать сразу, не дожидаясь первого тика)

[Mikhail Mishanin]

Andrey Sokolov:

Здравствуйте. Подскажите, пожалста.

Как проверить является ли время торговым или нет?

(чтоб сделать чтоб советник начинал работать сразу, не дожидаясь первого тика)

OnTimer()

только какие бидаски в ордера будете ставить?)

https://www.mql5.com/ru/docs/event_handlers/ontimer

т.е. функция в эксперте сработает без прихода тиков

[Andrei Sokolov]

dr.mr.mom:

OnTimer()

только какие бидаски в ордера будете ставить?)

https://www.mql5.com/ru/docs/event_handlers/ontimer

т.е. функция в эксперте сработает без прихода тиков

Вопрос не об этом. Вопрос в том, как сделать чтоб при включении эксперт начинал работать, в тч торговать, если время торговое, не  дожидаясь нового тика.

[Mikhail Mishanin]

Andrey Sokolov:

Вопрос не об этом. Вопрос в том, как сделать чтоб при включении эксперт начинал работать, в тч торговать, если время торговое, не  дожидаясь нового тика.

Эксперт обрабатывает события. Если Вы не хотите дожидаться события NewTick#, которое обрабатывается функцией OnTick, есть возможность используя функцию 

bool  EventSetTimer(
   int  seconds      // количество секунд
   );

генерировать события от таймера с указанной периодичностью, событие Timer# обрабатывается функцией OnTimer(). Эксперт у вас будет работать постоянно(с некой периодичностью) не дожидаясь тиков, а что уж он будет при этом делать, решать вам.

[Sergey Voytsekhovsky]

Добрый день. По мотивам урока " Использование структур для повышения эффективности разработки программ" воодушевился применением функции внутри структуры и создал вот такую простейшую конструкцию в МТ5.

#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
#include <Trade\PositionInfo.mqh>
#include <Trade\OrderInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
#include <Trade\AccountInfo.mqh>
#include <Trade\DealInfo.mqh>
#include <Expert\Money\MoneyFixedMargin.mqh>

CPositionInfo      m_position;// object of CPositionInfo class
COrderInfo         m_order;   // object of COrderInfo class
CTrade             m_trade;   // object of CTrade class
CSymbolInfo        m_symbol;  // object of CSymbolInfo class
CAccountInfo       m_account; // object of CAccountInfo class
CDealInfo          m_deal;    // object of CDealInfo class
CMoneyFixedMargin *m_money;   // object of CMoneyFixedMargin class
//+------------------------------------------------------------------+
//| Structure Positions                                              |
//+------------------------------------------------------------------+
struct STRUCT_POSITION
  {
   ENUM_POSITION_TYPE type;       // тип позиции
   ulong              ticket;     // тикет позиции
   long               identifier; // идентификатор
   long               magic;      // магический номер
   double             volume;     // объем позиции
   double             open_price; // цена открытия
   datetime           open_time;  // время открытия
   double             profit;     // профит позиции
   double             comission;  // комиссия
   double             swap;       // своп
   string             comment;    // комментарий
   
   void               GetCurrentPositionProperty();
  };
  STRUCT_POSITION StrPositionArray[];
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   STRUCT_POSITION.GetCurrentPositionProperty();
  }
//+------------------------------------------------------------------+
//---Заполнение массива свойств позиций                              +
//+------------------------------------------------------------------+
void STRUCT_POSITION::GetCurrentPositionProperty(void)
{   
   ZeroMemory(this);
   int pos_total = PositionsTotal();
   ArrayResize(StrPositionArray,pos_total,1000);
   for(int i=0; i<pos_total; i++)
      {
         if(m_position.SelectByIndex(i))
            {
               StrPositionArray[i].ticket     = m_position.Ticket();                  // тикет позиции
               StrPositionArray[i].identifier = m_position.Identifier();              // идентификатор
               StrPositionArray[i].magic      = m_position.Magic();                   // магический номер
               StrPositionArray[i].comment    = m_position.Comment();                 // комментарий
               StrPositionArray[i].type       =(ENUM_POSITION_TYPE)m_position.PositionType();// тип позиции
               StrPositionArray[i].volume     = m_position.Volume();                  // объем позиции
               StrPositionArray[i].open_price = m_position.PriceOpen();               // цена открытия
               StrPositionArray[i].open_time  = m_position.Time();                    // время открытия
               StrPositionArray[i].profit     = m_position.Profit();                  // профит позиции
               StrPositionArray[i].comission  = m_position.Commission();              // комиссия
               StrPositionArray[i].swap       = m_position.Swap();                    // своп
            }
      } 
} 
//+------------------------------------------------------------------+

В структуре

STRUCT_POSITION

присутствует метод 

GetCurrentPositionProperty(void)

который рассчитывает и присваивает значения элементам структуры. Определяем тело метода вне структуры. Для этого используем операцию разрешения контекста (::).

В OnTick() вызываем фунцию:

 

void OnTick() { //--- STRUCT_POSITION.GetCurrentPositionProperty(); }

И получаем ошибку:

'.' - name expected    eSower_and_Gather_5.mq5    69    19
Где накосячено не понимаю, помогите плиз.

[Vladimir Karputov]

Sergey Voytsekhovsky:

'.' - name expected    eSower_and_Gather_5.mq5    69    19

Что за строка 69 19? Опубликуйте строку кода 69 и укажите где 19 позиция. Сразу станет ясно где ошибка.

[Sergey Voytsekhovsky]

Vladimir Karputov:

Что за строка 69 19? Опубликуйте строку кода 69 и укажите где 19 позиция. Сразу станет ясно где ошибка.

STRUCT_POSITION.GetCurrentPositionProperty();

в посте выше она выделена красным. Спасибо за оперативный ответ.

[Sergey Voytsekhovsky]

Vladimir Karputov:

Что за строка 69 19? Опубликуйте строку кода 69 и укажите где 19 позиция. Сразу станет ясно где ошибка.

Это точка, которая должна давать доступ к функции, которая в свою очередь использует контекст структурыю Это то что я понял из учебников. Но почему это не работает понять не могу.

[Vladimir Karputov]

Sergey Voytsekhovsky:

в посте выше она выделена красным. Спасибо за оперативный ответ.

'STRUCT_POSITION' - это ТИП ДАННЫХ. Вам нужно создать переменную с этим типом и потом вызывать ПЕРЕМЕННАЯ.GetCurrentPositionProperty();

[Vladimir Karputov]

Sergey Voytsekhovsky:

Это точка, которая должна давать доступ к функции, которая в свою очередь использует контекст структурыю Это то что я понял из учебников. Но почему это не работает понять не могу.

Код: (просто вызывается функция - функция советника, а не метод структуры - так понятнее)

//+------------------------------------------------------------------+
//|                                                      ProjectName |
//|                                      Copyright 2020, CompanyName |
//|                                       http://www.companyname.net |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
#include <Trade\PositionInfo.mqh>
#include <Trade\OrderInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
#include <Trade\AccountInfo.mqh>
#include <Trade\DealInfo.mqh>
#include <Expert\Money\MoneyFixedMargin.mqh>
//---
CPositionInfo      m_position;// object of CPositionInfo class
COrderInfo         m_order;   // object of COrderInfo class
CTrade             m_trade;   // object of CTrade class
CSymbolInfo        m_symbol;  // object of CSymbolInfo class
CAccountInfo       m_account; // object of CAccountInfo class
CDealInfo          m_deal;    // object of CDealInfo class
CMoneyFixedMargin *m_money;   // object of CMoneyFixedMargin class
//+------------------------------------------------------------------+
//| Structure Positions                                              |
//+------------------------------------------------------------------+
struct STRUCT_POSITION
  {
   ENUM_POSITION_TYPE type;       // тип позиции
   ulong              ticket;     // тикет позиции
   long               identifier; // идентификатор
   long               magic;      // магический номер
   double             volume;     // объем позиции
   double             open_price; // цена открытия
   datetime           open_time;  // время открытия
   double             profit;     // профит позиции
   double             comission;  // комиссия
   double             swap;       // своп
   string             comment;    // комментарий

   void               GetCurrentPositionProperty();
  };
STRUCT_POSITION StrPositionArray[];
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   GetCurrentPositionProperty();
  }
//+------------------------------------------------------------------+
//| Заполнение массива свойств позиций                               |
//+------------------------------------------------------------------+
void GetCurrentPositionProperty(void)
  {
   int pos_total = PositionsTotal();
   ArrayResize(StrPositionArray,pos_total,1000);
   for(int i=0; i<pos_total; i++)
     {
      if(m_position.SelectByIndex(i))
        {
         StrPositionArray[i].ticket     = m_position.Ticket();                  // тикет позиции
         StrPositionArray[i].identifier = m_position.Identifier();              // идентификатор
         StrPositionArray[i].magic      = m_position.Magic();                   // магический номер
         StrPositionArray[i].comment    = m_position.Comment();                 // комментарий
         StrPositionArray[i].type       =(ENUM_POSITION_TYPE)m_position.PositionType();// тип позиции
         StrPositionArray[i].volume     = m_position.Volume();                  // объем позиции
         StrPositionArray[i].open_price = m_position.PriceOpen();               // цена открытия
         StrPositionArray[i].open_time  = m_position.Time();                    // время открытия
         StrPositionArray[i].profit     = m_position.Profit();                  // профит позиции
         StrPositionArray[i].comission  = m_position.Commission();              // комиссия
         StrPositionArray[i].swap       = m_position.Swap();                    // своп
        }
     }
  }
//+------------------------------------------------------------------+