Попробуйте добавить флаги в MqlTick, соотвественно с обновлением времени - Биржевой трейдинг

prostotrader 2017.09.21 23:43 #41

Уважаемые разработчики!

ПРОШУ ВНИМАТЕЛЬНО прочитать это сообщение.

Кажется, я понял причину, почему появляется расхождение во времени!!!

Сегодня:

Терминал

23:49:58.148    Trades  'xxxxx': buy limit 2.00 UCHF-3.18 at 0.9310
23:49:58.154    Trades  'xxxxx': accepted buy limit 2.00 UCHF-3.18 at 0.9310
23:49:58.156    Trades  'xxxxx': buy limit 2.00 UCHF-3.18 at 0.9310 placed for execution in 8.040 ms

Эксперт

2017.09.21 23:49:58.182 trader (UCHF-3.18,H1)     StopTrading: Время сервера = 23:50:00; Статус ордера = BUY_ORDER; Билет = 77833993  Buy ордер отклонён.
2017.09.21 23:49:58.182 trader (UCHF-3.18,H1)     Alert: Эксперт остановлен. Инструмент UCHF-3.18
2017.09.21 23:49:58.182 trader (UCHF-3.18,H1)     OnTradeTransaction: Buy ордер отклонён брокером(биржей). Билет = 77833993 Причина: 0 0

Механизм проверки времени

При изменении стакана цен по инструменту (работаю только со стаканом цен)

//+------------------------------------------------------------------+
// Expert Book event function                                        |
//+------------------------------------------------------------------+  
void OnBookEvent(const string &symbol)
{
  if(symbol == Symbol()))
  {
    if(CheckMarketTime(symbol)
    {
      //Выставление ордеров и т.д.
    }
  }     
}

Вызывается функция CheckMarketTime

//+------------------------------------------------------------------+
//| Expert Check Market Time function                                |
//+------------------------------------------------------------------+
bool CheckMarketTime(const string a_symbol)
{
  if(SymbolInfoTick(a_symbol, cur_tick))
  {
    sv_time.year = 0;
    TimeToStruct(cur_tick.time, sv_time);
    if(sv_time.year > 0)
    {
      if((sv_time.day_of_week == int(FirstDay)) ||
         (sv_time.day_of_week == int(SecondDay))) return(false);
      tts_time.year = 0;
      TimeTradeServer(tts_time);
      if(tts_time.year > 0)
      {   
        if((tts_time.day_of_week == sv_time.day_of_week) &&
           (tts_time.hour == sv_time.hour) &&
           (tts_time.min == sv_time.min))
        {
          ulong cur_time = sv_time.hour * 3600 + sv_time.min * 60 + sv_time.sec;
          if(((cur_time >= time_st_mon) && (cur_time < 50370)) ||
             ((cur_time >= time_st_day) && (cur_time < 67470)) ||
             ((cur_time >= time_st_evn) && (cur_time < 85770)))
          {
            return(true);
          }
        }
      }
    }
  }
  return(false);
}

Получив данные по последнему тику по инструменту

if(SymbolInfoTick(a_symbol, cur_tick))

произвожу проверку на временные рамки, НО (ОЧЕНЬ ВАЖНО)!!!!

В MqlTick (СКОРЕЕ ВСЕГО) не заносится последнее время, если

в стакане цен изменился ТОЛЬКО объём одной и той же цены.

Это предположкение я делаю потому, что во флагах нет

флага TICK_FLAG_ASK_VOLUME и TICK_FLAG_BID_VOLUME

Функция OnBookEvent сработала (изменился объём такой-то цены), а

в MqlTick не занеслось время этого изменения.

Прошу добавить эти флаги в MqlTick, соотвественно с обновлением времени.

Добавлено

Почему-то в СД не могу сделать запись

Особенности языка mql5, тонкости Новая версия платформы MetaTrader Тестируем 'CopyTicks'

fxsaber 2017.09.22 07:17 #42

prostotrader:

В MqlTick (СКОРЕЕ ВСЕГО) не заносится последнее время, если

в стакане цен изменился ТОЛЬКО объём одной и той же цены.

Абсолютно верно. И это правильное поведение. MqlTick берет данные из того же источника, откуда наполняется тиковая история. Соседей-дубликатов в истории тиков быть не должно, т.к. тиковая история в MT5 не хранит объем даже на бестбандах.

Давно поднимался вопрос, что нет прямой возможности узнать время, которому соответствует стакан. Узнавайте другим способом.

Бэктестинг/оптимизация Библиотеки: Virtual Korey Вернись :)

prostotrader 2017.09.22 07:40 #43

fxsaber:

Абсолютно верно. И это правильное поведение. MqlTick берет данные из того же источника, откуда наполняется тиковая история. Соседей-дубликатов в истории тиков быть не должно, т.к. тиковая история в MT5 не хранит объем даже на бестбандах.

Давно поднимался вопрос, что нет прямой возможности узнать время, которому соответствует стакан. Узнавайте другим способом.

Будьте любезны, подскажите каким?

Добавлено

Если я получил уведомление, что в такане что-то изменилось, то

почему для удобства ("малой кровью") не добавить поле

datetime book_change; ?

Или ещё проще, в труктуру MqlBookInfo добавить поле

datetime book_change;

Тем более, что это время транслирует биржа.

Как поменять время в В справочнике MQL5 ошибка Улучшения в чатах: теперь

fxsaber 2017.09.22 07:45 #44

prostotrader:

Будьте любезны, подскажите каким?

// Время последнего тика символа
long GetSymbolTime( const string Symb )
{
  MqlTick Tick;
  
  return(SymbolInfoTick(Symb, Tick) ? Tick.time_msc : 0);
}

// Время последнего тика Обзора рынка
long GetMarketWatchTime( void )
{
  long Res = 0;
  
  for (int i = SymbolsTotal(true) - 1; i >= 0; i--)
  {
    const long TmpTime = GetSymbolTime(SymbolName(i, true));
    
    if (TmpTime > Res)
      Res = TmpTime;
  }
  
  return(Res);
}

// Текущее время на торговом сервере без учета пинга
long GetCurrenTime( void )
{
  static ulong StartTime = GetMicrosecondCount();
  static long PrevTime = 0;
  
  const long TmpTime = GetMarketWatchTime();
  
  if (TmpTime > PrevTime)
  {
    PrevTime = TmpTime;
    
    StartTime = GetMicrosecondCount();
  }
  
  return(PrevTime + (long)((GetMicrosecondCount() - StartTime) / 1000));
}

void OnInit()
{
  MarketBookAdd(_Symbol);
}

void OnDeinit( const int )
{
  MarketBookRelease(_Symbol);
}

string TimeToString( const long Value )
{
  return((string)(datetime)(Value / 1000) + "." + (string)IntegerToString(Value % 1000, 3, '0'));
}

void OnBookEvent( const string& )
{
  Comment(TimeToString(GetCurrenTime()));
}

prostotrader 2017.09.22 07:50 #45

fxsaber:

Не смешите... :)

fxsaber 2017.09.22 07:50 #46

prostotrader:

Если я получил уведомление, что в такане что-то изменилось, то

почему для удобства ("малой кровью") не добавить поле

datetime book_change; ?

Или ещё проще, в труктуру MqlBookInfo добавить поле

datetime book_change;

Тем более, что это время транслирует биржа.

Только не datetime, а long - миллисекунды. Ну и

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

Market closed

fxsaber, 2017.09.22 09:17

Давно поднимался вопрос, что нет прямой возможности узнать время, которому соответствует стакан.

с подобными предложениями.

Особенности языка mql5, тонкости Как в таймере MQL4 Обсуждение статьи "Основы программирования

prostotrader 2017.09.22 08:07 #47

Может быть, после срабатывания OnBookEvent

запросить CopyTicks по данному символу?

Ща попробую...

fxsaber 2017.09.22 08:10 #48

prostotrader:

Может быть, после срабатывания OnBookEvent

запросить CopyTicks по данному символу?

Не поможет, конечно. Единственный вариант сейчас узнать время стакана привел.

prostotrader 2017.09.22 08:20 #49

fxsaber:

Не поможет, конечно. Единственный вариант сейчас узнать время стакана привел.

Интересно получается :)

#property copyright "Copyright 2017 prostotrader"
#property link      "https://www.mql5.com"
#property version   "1.00"
//
MqlTick a_ticks[], b_ticks;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   if(!MarketBookAdd(Symbol()))
   {
     Print("Book not added!");
     return(INIT_FAILED);
   }
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
    MarketBookRelease(Symbol());   
  }
//+------------------------------------------------------------------+
//| BookEvent function                                               |
//+------------------------------------------------------------------+
void OnBookEvent(const string &symbol)
  {
    if(symbol == Symbol())
    {
      int res = CopyTicks(symbol, a_ticks, COPY_TICKS_ALL, 0, 1);
      if(res > 0)
      {
        if(SymbolInfoTick(symbol, b_ticks))
        {
          Print("CopyTicks time = ", TimeToString(a_ticks[0].time, TIME_SECONDS), "; SymbolInfoTick = ", TimeToString(b_ticks.time, TIME_SECONDS));
        }
      }
    }
  }

Результат

2017.09.22 11:18:36.029 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:27; SymbolInfoTick = 11:18:35
2017.09.22 11:18:36.933 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:27; SymbolInfoTick = 11:18:35
2017.09.22 11:18:37.577 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:27; SymbolInfoTick = 11:18:37
2017.09.22 11:18:38.257 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:27; SymbolInfoTick = 11:18:37
2017.09.22 11:18:38.317 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:38; SymbolInfoTick = 11:18:38
2017.09.22 11:18:38.511 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:38; SymbolInfoTick = 11:18:38
2017.09.22 11:18:38.871 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:38; SymbolInfoTick = 11:18:38
2017.09.22 11:18:39.071 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:38; SymbolInfoTick = 11:18:38
2017.09.22 11:18:39.545 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:38; SymbolInfoTick = 11:18:38
2017.09.22 11:18:39.655 Test_time (RTS-12.17,M1)        CopyTicks time = 11:18:38; SymbolInfoTick = 11:18:39

???????

Я даже не знаю что сказать....

fxsaber 2017.09.22 08:42 #50

prostotrader:

Я даже не знаю что сказать....

void OnInit()
{
  MarketBookAdd(_Symbol);
}

void OnDeinit( const int )
{
  MarketBookRelease(_Symbol);
}

string GetTickFlag( uint tickflag )
{
  string flag = "";

#define TICKFLAG_MACRO(A) flag += ((bool)(tickflag & TICK_FLAG_##A)) ? " TICK_FLAG_" + #A : "";
  TICKFLAG_MACRO(BID)
  TICKFLAG_MACRO(ASK)
  TICKFLAG_MACRO(LAST)
  TICKFLAG_MACRO(VOLUME)
  TICKFLAG_MACRO(BUY)
  TICKFLAG_MACRO(SELL)
#undef TICKFLAG_MACRO

  if (flag == "")
    flag = " FLAG_UNKNOWN (" + (string)tickflag + ")";
     
  return(flag);
}

#define TOSTRING(A) " " + #A + " = " + (string)Tick.A

string TickToString( const MqlTick &Tick )
{
  return(TOSTRING(time) + "." + (string)IntegerToString(Tick.time_msc % 1000, 3, '0') +
         TOSTRING(bid) + TOSTRING(ask) + TOSTRING(last)+ TOSTRING(volume) + GetTickFlag(Tick.flags));
}

void OnBookEvent( const string &Symb )
{
  if (Symb == _Symbol)
  {
    MqlTick Tick1, Tick2[];
    
    if (SymbolInfoTick(_Symbol, Tick1) && (CopyTicks(_Symbol, Tick2, COPY_TICKS_ALL, 0, 1) > 0))
      Print("\nMqlTick: " + TickToString(Tick1) + "\nCopyTick: " + TickToString(Tick2[0]));
  }
}

увидите, что время будет различаться только в таких ситуациях

Test3 (RTS-12.17,M1)    MqlTick:  time = 2017.09.22 11:21:50.668 bid = 112000.0 ask = 112010.0 last = 112000.0 volume = 5 FLAG_UNKNOWN (0)
Test3 (RTS-12.17,M1)    CopyTick:  time = 2017.09.22 11:21:50.572 bid = 112000.0 ask = 112010.0 last = 112000.0 volume = 5 TICK_FLAG_LAST TICK_FLAG_VOLUME TICK_FLAG_SELL

Несколько раз обсуждалось, что MqlTick не возвращает тик, как есть. Что есть два тиковых потока - котировочный и сделки. И что в CopyTicks они объединяются иногда задним числом, т.к. потоки несинхронизированы. И что время MqlTick и CopyTicks могут не совпадать.

Market closed - страница 5