MQL5 Wizard - ストキャスティクスをフィルターとした"Bullish Harami/Bearish Harami"ロウソク足パターン - MetaTrader 5のためのエキスパート

MQL5 Wizardを使えば、クライアントターミナルにあるStandard libraryのエキスパートアドバイザーを自動生成することができます。(詳細は、Creating Ready-Made Expert Advisors in MQL5 Wizardを参照)トレードシグナルのクラスを生成しさせすれば、トレードアイディアをすぐに確認することができますクラスの例と構造については MQL5 Wizard: How to Create a Module of Trading Signalsを参照してください。

全般的な考え方は下記のとおりです。: CExpertSignalでトレードシグナルのクラスを作ります。次に、LongCondition() と ShortCondition()の仮想メソッドを無効にする必要があります。

"Strategies of best traders" (ロシア)という著書があります。 そこには数多くの手法と方法が記述されており、転換足パターンを Stochastic、 CCI、 MFI、 RSIの条件のもと、焦点を当てていきます。

最も良い方法は、ロウソク足のパターンの確認に、CExpertSignalから導かれるクラスを切り分けて生成することです。ロウソク足のパターンによるトレードシグナルの確認には、CCandlePatternのクラスを書いて、必要な条件例えば、オシレーターの確認など)を追加すれば十分です。

Stochasticのフィルター付きの"Bullish Harami/Bearish Harami"の転換足パターンのシグナルを考えてみましょう。トレードシグナルのモジュールは、CCandlePattern classに基づいています。ロウソク足のパターンによるシグナルの生成のシンプルな一例です。

1. "Bullish Harami and "Bearish Harami"

1.1. Bullish Harami

Bullish Haramiでは、大きなロウソク足が下降トレンドで形成され、その後、大きなロウソク足の実体の範囲内に実体がある小さなロウソク足が発生します。このパターンは、下降トレンドが転換することを表し、買いエントリーするタイミングであることを示します。2本目のロウソク足は上窓と同時に始まります。

2本目が小さければ小さいほど、転換する確率が上がります。

図1. "Bullish Harami"

"Bullish Harami"は、 CCandlePatternのCCheckPatternBullishHarami() method に実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "Bullish Harami" candlestick pattern         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishHarami()
  {
//--- Bullish Harami
   if((Close(1)>Open(1))              && // the last completed bar is bullish (white day)
     ((Open(2)-Close(2))>AvgBody(1))  && // the previous candle is bearish, its body is greater than average (long black)
     ((Close(1)<Open(2))              && // close price of the bullish candle is lower than open price of the bearish candle 
      (Open(1)>Close(2)))             && // open price of the bullish candle is higher than close price of the bearish candle
      (MidPoint(2)<CloseAvg(2)))         // down trend
      return(true);
//---
   return(false);
  }

1.2. Bearish Harami

Bearish Harami では、大きなロウソク足が上昇トレンドで形成され、その後、大きなロウソク足の実体の範囲内に実体がある小さなロウソク足が発生します。. このパターンは、上昇トレンドが転換することを表し、売りエントリーするタイミングであることを示します。2本目のロウソク足は下窓と同時に始まります。

2本目が小さければ小さいほど、転換する確率が上がります。

図2. "Bearish Harami"

"Bearish Harami"は、 CCandlePatternのCheckPatternBearishHarami() method に実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "Bearish Harami" candlestick pattern         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishHarami()
  {
//--- Bearish Harami
   if((Close(1)<Open(1))              && // last completed bar is bearish (black day)
     ((Close(2)-Open(2))>AvgBody(1))  && // the previous candle is bullish, its body is greater than average (long white)
     ((Close(1)>Open(2))              && // close price of the bearish candle is higher than open price of the bullish candle 
      (Open(1)<Close(2)))             && // open price of the bearish candle is lower than close price of the bullish candle
      (MidPoint(2)>CloseAvg(2)))         // up trend
      return(true);
//---
   return(false);
  }

2. ストキャスティクスによるフィルター付きのシグナル

買いや売りのシグナルは、Stochasticで確認する必要があります。シグナル%Dラインは、それぞれの基準レベルよりも高いか、低くなければなりません。(30 か 70).

ポジションの決済は、%Dの値で決めます。2通りのケースがあります。:

1. %Dが反対側の基準レベルに到達した (買いポジションなら80、売りポジションなら20)
2. 逆のシグナルが発生しなかった(%Dが基準点に達した: 買いポジションなら20、売りポジションなら80)

図3. ストキャスティクスをフィルターとした"Bearish Harami"

エントリー・決済条件の確認は２つのメソッドに実装されています。:

• int CBH_BH_Stoch::LongCondition() - 買いポジションのエントリー条件(80) と 売りポジションの決済条件 (40);
  
• int CBH_BH_Stoch::ShortCondition() - 売りポジションのエントリー条件(80) と 買いポジションの決済条件 (40).

2.1. 買いポジション/売りポジションの決済

1. "Bullish Harami" の条件は、Stochasticで確認する必要があります。: StochSignal(1)<30 (直近の確定足のストキャスティクスのシグナルラインは30よりも低くなければなりません。)

2. Stochasticのシグナルラインが20か80ラインを上抜けしたら、売りポジションは決済するべきです。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBH_BH_Stoch::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Bullish Harami pattern and signal line<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_HARAMI) && (StochSignal(1)<30))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (downward 20, upward 80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- return result
   return(result);
  }

2.2. 売りポジション/買いポジションの決済

1. "Bearish Harami"の条件は、Stochasticで確認する必要があります。: StochSignal(1)>70 (直近の確定足のストキャスティクスのシグナルラインは70よりも高くなければなりません。)

2. Stochasticのシグナルラインが20か80ラインを下抜けしたら、買いポジションは決済するべきです。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBH_BH_Stoch::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Bearish Harami pattern and signal line>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_HARAMI) && (StochSignal(1)>70))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward 80, upward 20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- return result
   return(result);
  }

2.3. MQL5 WizardでEAを生成する

エキスパートアドバイザーを生成するには、MQL5 Wizardを立ち上げてください。:

図4. MQL5 WizardでEAを生成する

エキスパートアドバイザーの名前を決めましょう。:

図5. エキスパートアドバイザーの一般設定

トレードシグナルのモジュールを選択します。

図6. エキスパートアドバイザーのシグナルプロパティ

今回の場合、モジュールは１つだけ使います。

"Signals based on Bullish Harami/Bearish Harami confirmed by Stochastic" のモジュールを追加:

図7. エキスパートアドバイザーのシグナルプロパティ

シグナルの追加モジュール:

図8. エキスパートアドバイザーのシグナルプロパティ

トレーリングプロパティにも様々なものがありますが、今回は"Trailing Stop not used"にします。:

図9. エキスパートアドバイザーのトレーリングプロパティTrailing properties of the Expert Advisor

資金管理プロパティとして、"Trading with fixed trade volume"(単利)を使います。:

図10エキスパートアドバイザーの資金管理プロパティMoney management properties of the Expert Advisor

"Finish"ボタンを押すと、エキスパートアドバイザーがExpert_ABH_BH_Stoch.mq5に生成されます。保存場所は、terminal_data_folder\MQL5\Experts\です。

生成後のエキスパートアドバイザーのデフォルトのパラメーター:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in points)

上記は下記にしなければなりません。:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Signal_ThresholdOpen/Signal_ThresholdClose パラメーターは、ポジションのオープン、決済の最初のレベルを決めます。

LongCondition() と ShortCondition() のメソッドのコードの中に、デフォルトの固定値が入っています。:

• エントリー: 80;
• 決済: 40.
  

Signal_StopLevel と Signal_TakeLevel パラメーターの値は、0にします。これは、ポジションの決済は、決済条件がtrueのときにのみ行われるということを表します。

2.4. バックテスト結果

過去データでエキスパートアドバイザーをテストしてみましょう。(EURUSD H1, テスト期間: 2010.01.01-2011.03.04, PeriodK=47, PeriodD=9, PeriodSlow=13, MA_period=5).

エキスパートアドバイザーの生成において、今回は固定ロット(Trading Fixed Lot, 0.1), トレーリングストップ(Trailing not used)はなしを選択しました。

図11. Bullish/Bearish Harami + Stochastic"のテスト結果

パラメーターの最適な設定値は、MetaTrader 5 client terminalのStrategy Testerで探すことができます。

MQL5 Wizard で生成したコードは、expert_abh_bh_stoch.mq5です。