Manual de referencia de MQL5Biblioteca estándarMatemáticasEstadísticaDistribución binomial

Distribución binomial

En este apartado se muestran las funciones para trabajar con la distribución binomial. Estas permiten calcular la densidad, la probabilidad, los cuantiles y generar números pseudoaleatorios, distribuidos conforme a la ley binomial. La distribución binomial se describe con la siguiente fórmula:

donde:

x – valor de la magnitud aleatoria

n – número de pruebas

p – probabilidad de éxito para cada prueba

DemoBinomialDistribution

Aparte del cálculo de diferentes magnitudes aleatorias, se ha implementado la posibilidad de trabajar con sus matrices.

Función	Descripción
MathProbabilityDensityBinomial	Calcula la densidad de probabilidad de la distribución binomial
MathCumulativeDistributionBinomial	Calcula el valor de la función de la distribución binomial de la probabilidad
MathQuantileBinomial	Calcula el valor de la función inversa de la distribución binomial para la probabilidad indicada
MathRandomBinomial	Genera una magnitud/matriz pseudoaleatoria de magnitudes pseudoaleatorias, distribuidas según la ley de la distribución binomial
MathMomentsBinomial	Calcula los valores numéricos teóricos de los 4 primeros momentos de la distribución binomial.

Ejemplo:

#include <Graphics\Graphic.mqh>
#include <Math\Stat\Binomial.mqh>
#include <Math\Stat\Math.mqh>
#property script_show_inputs
//--- input parameters
input double n_par=40;        // número de pruebas
input double p_par=0.75;      // probabilidad de éxito para cada prueba
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- desactivamos la exhibición del gráfico de precio
   ChartSetInteger(0,CHART_SHOW,false);
//--- inicializamos el generador de números aleatorios
   MathSrand(GetTickCount());
//--- generamos una muestra de la magnitud aleatoria
   long chart=0;
   string name="GraphicNormal";
   int n=1000000;       // número de valores en la muestra
   int ncells=20;       // número de intervalos en el histograma
   double x[];          // centros de los intervalos del histograma
   double y[];          // número de valores de la muestra que han entrado en el intervalo
   double data[];       // muestra de valores aleatorios
   double max,min;      // valor máximo y mínimo en la muestra
//--- obtenemos la muestra de la distribución binomial
   MathRandomBinomial(n_par,p_par,n,data);
//--- calculamos los datos para construir el histograma
   CalculateHistogramArray(data,x,y,max,min,ncells);
//--- obtenemos los datos calculados teóricamente en el intervalo [min,max]
   double x2[];
   double y2[];
   MathSequence(0,n_par,1,x2);
   MathProbabilityDensityBinomial(x2,n_par,p_par,false,y2);
//--- escalamos
   double theor_max=y2[ArrayMaximum(y2)];
   double sample_max=y[ArrayMaximum(y)];
   double k=sample_max/theor_max;
   for(int i=0; i<ncells; i++)
      y[i]/=k;
//--- mostramos el gráfico
   CGraphic graphic;
   if(ObjectFind(chart,name)<0)
      graphic.Create(chart,name,0,0,0,780,380);
   else
      graphic.Attach(chart,name);
   graphic.BackgroundMain(StringFormat("Binomial distributionn n=%G p=%G",n_par,p_par));
   graphic.BackgroundMainSize(16);
//--- plot all curves
   graphic.CurveAdd(x,y,CURVE_HISTOGRAM,"Sample").HistogramWidth(6);
//--- y ahora construimos la curva teórica de la densidad de la distribución
   graphic.CurveAdd(x2,y2,CURVE_LINES,"Theory").LinesSmooth(true);
   graphic.CurvePlotAll();
//--- plot all curves
   graphic.Update();
  }
//+------------------------------------------------------------------+
//|  Calculate frequencies for data set                              |
//+------------------------------------------------------------------+
bool CalculateHistogramArray(const double &data[],double &intervals[],double &frequency[],
                             double &maxv,double &minv,const int cells=10)
  {
   if(cells<=1) return (false);
   int size=ArraySize(data);
   if(size<cells*10) return (false);
   minv=data[ArrayMinimum(data)];
   maxv=data[ArrayMaximum(data)];
   double range=maxv-minv;
   double width=range/cells;
   if(width==0) return false;
   ArrayResize(intervals,cells);
   ArrayResize(frequency,cells);
//--- establecemos los centros de los intervalos
   for(int i=0; i<cells; i++)
     {
      intervals[i]=minv+(i+0.5)*width;
      frequency[i]=0;
     }
//--- rellenamos las frecuencias de entrada en el intervalo
   for(int i=0; i<size; i++)
     {
      int ind=int((data[i]-minv)/width);
      if(ind>=cells) ind=cells-1;
      frequency[ind]++;
     }
   return (true);
  }

MathMomentsWeibull

MathProbabilityDensityBinomial