Referência MQL5Biblioteca PadrãoMatemáticaEstatísticaDistribuição binomial

Distribuição binomial

Esta seção apresenta as funções para trabalhar com a distribuição binomial. Elas permitem que você calcule a densidade, probabilidade, quantis e gere números pseudo-aleatórios de acordo com a distribuição binomial. A distribuição binomial é descrita pela seguinte fórmula:

Onde:

x – valor da variável aleatória

n – número de testes

p – probabilidade de sucesso para cada teste

DemoBinomialDistribution

Além do cálculo das variáveis aleatórias individuais, é possível trabalhar com suas matrizes.

Função	Descrição
MathProbabilityDensityBinomial	Calcula a densidade de probabilidade da distribuição binomial
MathCumulativeDistributionBinomial	Calcula o valor da função distribuição binomial de probabilidades
MathQuantileBinomial	Calcula o inverso da função de distribuição binomial para a probabilidade especificada
MathRandomBinomial	Gera um valor/matriz pseudo-aleatório de valores pseudo-aleatórios de acordo com a distribuição binomial
MathMomentsBinomial	Calcula os valores numéricos teóricos dos primeiros 4 momentos da distribuição binomial

Exemplo:

#include <Graphics\Graphic.mqh>
#include <Math\Stat\Binomial.mqh>
#include <Math\Stat\Math.mqh>
#property script_show_inputs
//--- input parameters
input double n_par=40;        // número de tentativas
input double p_par=0.75;      // probabilidade de sucesso em cada tentativa
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- desativamos a exibição do gráfico de preço
   ChartSetInteger(0,CHART_SHOW,false);
//--- inicializamos o gerador de números aleatórios
   MathSrand(GetTickCount());
//--- geramos a amostragem da variável aleatória
   long chart=0;
   string name="GraphicNormal";
   int n=1000000;       // número de valores na amostragem
   int ncells=20;       // número de intervalos no gráfico de colunas
   double x[];          // centros de intervalos no gráfico de colunas
   double y[];          // número de valores a partir da amostragem dentro do intervalo
   double data[];       // amostragem de valores aleatórios
   double max,min;      // valores máximo e mínimo na amostragem
//--- obtemos a amostragem a partir da distribuição binomial
   MathRandomBinomial(n_par,p_par,n,data);
//--- calculamos os dados para plotagem do gráfico de colunas
   CalculateHistogramArray(data,x,y,max,min,ncells);
//--- obtemos teoricamente os cálculos no intervalo [min,max]
   double x2[];
   double y2[];
   MathSequence(0,n_par,1,x2);
   MathProbabilityDensityBinomial(x2,n_par,p_par,false,y2);
//--- dimensionamos
   double theor_max=y2[ArrayMaximum(y2)];
   double sample_max=y[ArrayMaximum(y)];
   double k=sample_max/theor_max;
   for(int i=0; i<ncells; i++)
      y[i]/=k;
//--- imprimimos o gráfico
   CGraphic graphic;
   if(ObjectFind(chart,name)<0)
      graphic.Create(chart,name,0,0,0,780,380);
   else
      graphic.Attach(chart,name);
   graphic.BackgroundMain(StringFormat("Binomial distributionn n=%G p=%G",n_par,p_par));
   graphic.BackgroundMainSize(16);
//--- plot all curves
   graphic.CurveAdd(x,y,CURVE_HISTOGRAM,"Sample").HistogramWidth(6);
//--- e agora traçamos a curva teórica de densidade da distribuição
   graphic.CurveAdd(x2,y2,CURVE_LINES,"Theory").LinesSmooth(true);
   graphic.CurvePlotAll();
//--- plot all curves
   graphic.Update();
  }
//+------------------------------------------------------------------+
//|  Calculate frequencies for data set                              |
//+------------------------------------------------------------------+
bool CalculateHistogramArray(const double &data[],double &intervals[],double &frequency[],
                             double &maxv,double &minv,const int cells=10)
  {
   if(cells<=1) return (false);
   int size=ArraySize(data);
   if(size<cells*10) return (false);
   minv=data[ArrayMinimum(data)];
   maxv=data[ArrayMaximum(data)];
   double range=maxv-minv;
   double width=range/cells;
   if(width==0) return false;
   ArrayResize(intervals,cells);
   ArrayResize(frequency,cells);
//--- definimos os centros dos intervalos
   for(int i=0; i<cells; i++)
     {
      intervals[i]=minv+(i+0.5)*width;
      frequency[i]=0;
     }
//--- preenchemos a frequência de aparecimento no intervalo
   for(int i=0; i<size; i++)
     {
      int ind=int((data[i]-minv)/width);
      if(ind>=cells) ind=cells-1;
      frequency[ind]++;
     }
   return (true);
  }

MathMomentsWeibull

MathProbabilityDensityBinomial