Azerbaijan's CCanvas and the PlotFucntion Program: A series of improvements in the Graphics Library, - General

--- 2017.01.31 14:19 #51

Roman Konopelko:
In class CGraphic, I replaced the color type by uint in all places, as you asked.

Also, I added new methods to CCanvas class, which allow to draw primitives with specified thickness:
In line with the innovation of CCanvas, I extended the properties of CCurve:
When drawing a curve with lines, you can now specify the thickness of the lines and the style of its ends.

That's just awesome.

Roman Konopelko 2017.02.08 15:56 #52

The handling of splines (interpolation with Bézier curves) has been revised. Its implementation has been moved from the CGraphics class directly into CCanvas, which allows splines to be constructed outside of the Graphics library.

In addition, an algorithm for rendering closed spline was added.

As a result, the CCanvas class now has two new public methods.

void              PolylineSmooth(const int &x[],const int &y[],const uint clr,const int size,
                                    ENUM_LINE_STYLE style=STYLE_SOLID,ENUM_LINE_END end_style=LINE_END_ROUND,
                                    double tension=0.5,double step=10);
void              PolygoneSmooth(int &x[],int &y[],const uint clr,const int size,
                                    ENUM_LINE_STYLE style=STYLE_SOLID,ENUM_LINE_END end_style=LINE_END_ROUND,
                                    double tension=0.5,double step=10);

These methods allow splines to be drawn in a given style and with a given thickness.

Since Bezier curves describe circles and ellipses rather precisely, there is no obvious need to augment the CCanvas class with new methods to render these primitives with a given thickness.

The example of ellipse approximation by Bézier curves based on PolygoneSmooth method:

#include <Canvas\Canvas.mqh>
//+------------------------------------------------------------------+
//| Get arrays with ellipse coordinates                              |
//+------------------------------------------------------------------+
void Ellipse(int &x[],int &y[])
  {
   int xc = 750;
   int yc = 300;
   int rx = 300;
   int ry = 150;
   ArrayResize(x,16);
   ArrayResize(y,16);
   int i=0;
   for(double fi=0; fi<2*M_PI; fi+=M_PI_4/2,i++)
     {
      x[i]=(int)MathRound(xc+cos(fi)*rx);
      y[i]=(int)MathRound(yc+sin(fi)*ry);
     }
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   CCanvas canvas;
   canvas.CreateBitmapLabel(0,0,"Canvas",0,0,1500,600);
   canvas.Erase(ColorToARGB(clrWhite));
   int x[];
   int y[]; 
   Ellipse(x,y);
   canvas.PolygoneSmooth(x,y,ColorToARGB(clrBlack),20,STYLE_SOLID,LINE_END_BUTT,0.5,1);
   canvas.Arc(750,300,300,150,0,M_PI*2,ColorToARGB(clrRed));   
   canvas.Update();
  }

Result:

Interpolation, approximation and the Elite indicators :) How to set the

Roman Konopelko 2017.02.08 15:59 #53

Another possible step towards the versatility of the Graphics library: a custom curve drawing mode CURVE_CUSTOM.

This mode will eliminate the need to inherit the CGraphic class and overload the ...Plot methods in order to draw a curve differently than the library's standard tools allow.

To implement this mode CURVE_CUSTOM new properties will be added to the CCurve class.

   //--- gets or sets the custom properties
   PlotFucntion      CustomPlotFunction(void)              const { return(m_custom_plot_func);   }
   void             *CustomPlotCBData(void)                const { return(m_custom_plot_cbdata); }
   void              CustomPlotFunction(PlotFucntion func) { m_custom_plot_func=func;     }
   void              CustomPlotCBData(void *cbdata)        { m_custom_plot_cbdata=cbdata; }

It is based on a new pointer to the PlotFucntion function.

typedef void(*PlotFucntion)(double &x[],double &y[], int size, CGraphic *graphic,CCanvas *canvas,void *cbdata);

This approach opens up new possibilities for drawing plots.

Let's implement drawing of candlesticks in the CGraphics library as an example:

1. Let's create a container class in which all data of a single candle will be stored.

//+------------------------------------------------------------------+
//| Class CCandle                                                    |
//| Usage: class to represent the candle                             |
//+------------------------------------------------------------------+
class CCandle: public CObject
  {
private:
   double            m_open;
   double            m_close;
   double            m_high;
   double            m_low;
   uint              m_clr_inc;
   uint              m_clr_dec;
   int               m_width;

public:
                     CCandle(const double open,const double close,const double high,const double low,
                                                       const int width,const uint clr_inc=0x000000,const uint clr_dec=0xF5F5F5);
                    ~CCandle(void);
   double            OpenValue(void)            const { return(m_open);     }
   double            CloseValue(void)           const { return(m_close);    }
   double            HigthValue(void)           const { return(m_high);     }
   double            LowValue(void)             const { return(m_low);      }
   uint              CandleColorIncrement(void) const { return(m_clr_inc);  }
   uint              CandleColorDecrement(void) const { return(m_clr_dec);  }
   int               CandleWidth(void)          const { return(m_width);    }
  };
//+------------------------------------------------------------------+
//| Constructor                                                      |
//+------------------------------------------------------------------+
CCandle::CCandle(const double open,const double close,const double high,const double low,
                                 const int width,const uint clr_inc=0x000000,const uint clr_dec=0xF5F5F5):
                                 m_open(open),m_close(close),m_high(high),m_low(low),
                                 m_clr_inc(clr_inc),m_clr_dec(clr_dec),m_width(width)
  {
  }
//+------------------------------------------------------------------+
//| Destructor                                                       |
//+------------------------------------------------------------------+
CCandle::~CCandle(void)
  {
  }

Since the CCandle class is a descendant of the CObject class, all the candlesticks we want to draw, we can sequentially write them into the object of the CArrayObj class. This array will get into our custom drawing method as the cbdata parameter. As a result, the candlestick drawing method will look as follows.

//+------------------------------------------------------------------+
//| Custom method for plot candles                                   |
//+------------------------------------------------------------------+
void PlotCandles(double &x[],double &y[],int size,CGraphic *graphic,CCanvas *canvas,void *cbdata)
  {
//--- check obj
   CArrayObj *candles=dynamic_cast<CArrayObj*>(cbdata);
   if(candles==NULL || candles.Total()!=size)
      return;
//--- plot candles  
   for(int i=0; i<size; i++)
     {
      CCandle *candle=dynamic_cast<CCandle*>(candles.At(i));
      if(candle==NULL)
         return;
      //--- primary calculate
      int xc=graphic.ScaleX(x[i]);
      int width_2=candle.CandleWidth()/2;
      int open=graphic.ScaleY(candle.OpenValue());
      int close=graphic.ScaleY(candle.CloseValue());
      int high=graphic.ScaleY(candle.HigthValue());
      int low=graphic.ScaleY(candle.LowValue());
      uint clr=(open<=close) ? candle.CandleColorIncrement() :  candle.CandleColorDecrement();
      //--- plot candle
      canvas.LineVertical(xc,high,low,0x000000);
      //--- plot candle real body
      canvas.FillRectangle(xc+width_2,open,xc-width_2,close,clr);
      canvas.Rectangle(xc+width_2,open,xc-width_2,close,0x000000);
     }
  }

3. For simplicity, all candlesticks will be generated randomly. And so we sequentially generate 10 candlesticks and fill the CArrayObj class object with them. Then we create CGraphics object and add one curve into it, while specifying that it will be drawn using our PlotCandles function. We also need to change the maximum and minimum values of the y-axis, so that our candles would be fully visible.

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   int count=10;
   int width=10;
   double x[];
   double y[];
   ArrayResize(x,count);
   ArrayResize(y,count);
   CArrayObj candles();
   double max=0;
   double min=0;
//--- create values 
   for(int i=0; i<count; i++)
     {
      x[i] = i;
      y[i] = i;
      //--- calculate values
      double open=MathRound(50.0+(MathRand()/32767.0)*50.0);
      double close=MathRound(50.0+(MathRand()/32767.0)*50.0);
      double high=MathRound(MathMax(open,close)+(MathRand()/32767.0)*10.0);
      double low=MathRound(MathMin(open,close) -(MathRand()/32767.0)*10.0);
      //--- find max and min
      if(i==0 || max<high)
         max=high;
      if(i==0 || min>low)
         min=low;
      //--- create candle
      CCandle *candle=new CCandle(open,close,high,low,width);
      candles.Add(candle);
     }
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"CandleGraphic",0,30,30,780,380))
     {
      graphic.Attach(0,"CandleGraphic");
     }
//--- create curve
   CCurve *curve=graphic.CurveAdd(x,y,CURVE_CUSTOM,"Candles");
//--- sets the curve properties
   curve.CustomPlotFunction(PlotCandles);
   curve.CustomPlotCBData(GetPointer(candles));
//--- sets the graphic properties
   graphic.YAxis().Max((int)max);
   graphic.YAxis().Min((int)min);
//--- plot 
   graphic.CurvePlotAll();
   graphic.Update();
  }

As a result, we get the following graph:

Files:

Canvas.mqh 304 kb

Axis.mqh 12 kb

ColorGenerator.mqh 4 kb

Curve.mqh 23 kb

Graphic.mqh 73 kb

Candle.mq5 6 kb

About the OOP Programm Questions on MQL5 Wizard How to change CAppDialog

--- 2017.03.12 17:51 #54

@Roman Konopelko

there is a small error in the CGraphic::SetDefaultParameters function

The colours should be initialized with opacity taken into account.

void CGraphic::SetDefaultParameters(void)
  {
...
...
//--- sets the default values for grid
   m_grid.clr_line=ColorToARGB(clrWhiteSmoke,255);
   m_grid.clr_axis_line=ColorToARGB(clrSilver,255);

Roman Konopelko 2017.03.13 15:29 #55

o_o:

@Roman Konopelko

there is a small error in the CGraphic::SetDefaultParameters function

Colours should be initialized with opacity taken into account.

Good afternoon, I have already fixed this point, but unfortunately these edits have not hit the build yet

Vladimir Karputov 2017.06.13 11:40 #56

This example caused the computer to freeze. What I did: after putting the indicator on the chart in the editor, I played with different combinations of commenting/uncommenting lines 87 and 88 (when one at a time, when together)

//+------------------------------------------------------------------+
//|                                        tst.mq5 |
//|                              Copyright © 2017, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2017, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
#property description "Panel indicator: \"Evening Star\" pattern " 
#property description "search results for different periods" 
#property indicator_chart_window 
#property indicator_buffers 0
#property indicator_plots   0
#include <Graphics\Graphic.mqh>
//--- object for creating graphs
CGraphic my_graphic;
//+------------------------------------------------------------------+
//| Global Variables                                                 |
//+------------------------------------------------------------------+
bool           m_first_start=false;
//+------------------------------------------------------------------+ 
//| Custom indicator initialization function                         | 
//+------------------------------------------------------------------+ 
int OnInit()
  {
   if(!EventSetTimer(3))
      if(!EventSetTimer(3))
         if(!EventSetTimer(3))
           {
            Print("Error create timer! THREE attempts!");
            return(INIT_FAILED);
           }
//--- canvas creation
   my_graphic.Create(0,"Evening Star Statistics",0,10,10,800,550);

   my_graphic.CurvePlotAll();
   my_graphic.Update();
//---
   m_first_start=false;
//--- 
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   my_graphic.Destroy();
  }
//+------------------------------------------------------------------+ 
//| Custom indicator iteration function                              | 
//+------------------------------------------------------------------+ 
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   if(!m_first_start)
     {
      //--- revert access to arrays - do it like in timeseries 
      ArraySetAsSeries(time,true);
      ArraySetAsSeries(open,true);
      ArraySetAsSeries(high,true);
      ArraySetAsSeries(low,true);
      ArraySetAsSeries(close,true);

      int size=ArraySize(time);
      double arrY[],arrX[];
      ArrayResize(arrX,size);
      ArrayResize(arrY,size);
      for(int i=0; i<size;++i)
        {
         arrX[i]=(double)time[i];
         arrY[i]=close[i];
        }
      CCurve *curve_b=my_graphic.CurveAdd(arrX,arrY,CURVE_LINES,"Close");
      CAxis *xAxis=my_graphic.XAxis();           // получаем ось X
      //---попеременно комбинирую (комментировать, раскомментировать) строки 87
      //--- и 88 можно словить момент поглощения памяти и зависания компьютера
      //xAxis.AutoScale(false); 
      //xAxis.Type(AXIS_TYPE_DATETIME); 
      my_graphic.CurvePlotAll();
      my_graphic.Update();
      m_first_start=true;
     }
//--- return value of prev_calculated for next call 
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer()
  {

  }
//+------------------------------------------------------------------+

Repeated the achievement twice. I have not recorded the sequence of actions. Third time is trivial I'm afraid to check.

Added: build 1607 x64

Files:

tst.mq5 8 kb

How I assemble my Technical glitches How to build a

Vladimir Karputov 2017.06.14 07:06 #57

Vladimir Karputov:

This example caused the computer to freeze. What I did: after putting the indicator on the chart in the editor, I played with different combinations of commenting/uncommenting lines 87 and 88 (when one at a time, when together)

Repeated the achievement twice. I have not recorded the sequence of actions. Third time is trivial I'm afraid to check.

Added: build 1607 x64

Repeated the record today - dead computer hangs, managed to see RAM consumption rise from 2GB to 5.5GB. Seems to have managed to close the schedule, but the computer has been hanging for five minutes.

This time I put a limit on the size of the array - not more than 300 elements. As you can see it didn't help 🤔

Questions from Beginners MQL5 Re-activation...... Any rookie question, so

--- 2017.06.14 08:11 #58

what does debug say?

Vladimir Karputov 2017.06.14 08:14 #59

o_o:

what does debug say?

Jbug didn't get it, I did this: hovered an indicator and uncommented/commented one or two lines and compiled. Ended up writing from a tablet, laptop went out...

Vladimir Karputov 2017.06.14 08:28 #60

Vladimir Karputov:

The gbug didn't make it, I did this: I hovered over the indicator and commented out/commented one or two lines and compiled. Ended up writing from a tablet, laptop went out...

So, laptop after hard reboot came back to life, but I don't want to conduct further destructive experiment - there are several Expert Advisors running on the laptop, so there is no desire to catch a freeze for a whole hour.

Laptop overheats and reboots EURUSD - Trends, Forecasts cannot set millisecond timer

Testing CGraphic - questions and suggestions - page 6