Download MetaTrader 5

Watch how to download trading robots for free

Interesting script?
So post a link to it -
let others appraise it

You liked the script? Try it in the MetaTrader 5 terminal

2011.02.18 12:19
Experts

MQL5 Wizard - Trade Signals Based on 3 Black Crows/3 White Soldiers + CCI - expert for MetaTrader 5

| English Русский 中文 Español Deutsch 日本語 Português

Views:
2628
Rating:
votes: 15
\MQL5\Include\Expert\Signal\MySignals\

The MQL5 Wizard allows creating ready-made Expert Advisors based on the Standard library classes delivered together with the client terminal (see Creating Ready-Made Expert Advisors in MQL5 Wizard for the details). It allows to check your trade ideas quickly, all you need is to create your own trading signals class. The structure of this class and example can be found in the article MQL5 Wizard: How to Create a Module of Trading Signals.

The generic idea is the following: the class of trading signals is derived from CExpertSignal, the next, it's necessary to override the LongCondition() and ShortCondition() virtual methods with your own methods.

There is a book "Strategies of best traders" (in Russian), there are many trading strategies are considered there, we will focus on reversal candlestick patterns, confirmed by Stochastic, CCI, MFI and RSI oscillators.

The best way is to create the separate class, derived from CExpertSignal for checking of formation of candlestick patterns. For confirmation of trade signals, generated by candlestick patterns, it's sufficient to write the class, derived from CCandlePattern and add the necessary features (for example, confirmation by oscillators) there.

Here we will consider the signals, based "3 Black Crows/3 White Soldiers" reversal candlestick pattern, confirmed by Commodity Channel Index indicator. The module of trade signals is based on the CCandlePattern class, it's simple example of its use for creation of trade signals with candlestick patterns.


1. "3 Black Crows" and 3 "White Soldiers" reversal candlestick patterns

1.1. 3 Black Crows

A bearish candlestick pattern that is used to predict the reversal of the current uptrend. This pattern consists of three consecutive long-bodied candlesticks that have closed lower than the previous day with each session's open occurring within the body of the previous candle.

Fig. 1. "3 Black Crows" candlestick pattern

Fig. 1. "3 Black Crows" candlestick pattern

The recognition of "3 Black Crows" pattern is implemented in CheckPatternThreeBlackCrows method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "3 Black Crows" candlestick pattern          |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeBlackCrows()
  {
//--- 3 Black Crows 
   if((Open(3)-Close(3)>AvgBody(1)) && // (long black)
      (Open(2)-Close(2)>AvgBody(1)) &&
      (Open(1)-Close(1)>AvgBody(1)) && 
      (MidPoint(2)<MidPoint(3))     && // (lower midpoints)
      (MidPoint(1)<MidPoint(2)))       
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) method of CCandlePattern class is used to check formation of "3 Black Crows" candlestick pattern.


1.2. 3 White Soldiers candlestick pattern

A bullish candlestick pattern that is used to predict the reversal of the current downtrend. This pattern consists of three consecutive long-bodied candlesticks that have closed higher than the previous day, with each session's open occurring within the body of the previous candle.

The pattern is valid as long as the candle of day two opens in the upper half of day one's range. By the end of day two, it should close near its high, leaving a very small or non-existent upper shadow. The same pattern is then repeated on day three.

Fig. 2. "3 White Soldiers" candlestick pattern

Fig. 2. "3 White Soldiers" candlestick pattern

Here is the method for recognition of "3 White Soldiers" pattern:

//+------------------------------------------------------------------+
//| Checks formation of "3 White Soldiers" candlestick pattern       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeWhiteSoldiers()
  {
   //--- 3 White Soldiers
   if((Close(3)-Open(3)>AvgBody(1)) && // long white
      (Close(2)-Open(2)>AvgBody(1)) &&
      (Close(1)-Open(1)>AvgBody(1)) &&
      (MidPoint(2)>MidPoint(3))     && // higher midpoints
      (MidPoint(1)>MidPoint(2)))
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) method of CCandlePattern class is used to check formation of "3 White Soldiers" candlestick pattern.


2. Trade signals, confirmed by CCI indicator

The trading signals to open long or short position must be confirmed by CCI indicator. The value of CCI must be greater/lower than critical levels (-50 for long position and 50 for short position)

The closing of opened position depends on the values of CCI. It can be done in 2 cases:

  1. if CCI line has reached the opposite critical level (80 for long position and -80 for short position)
  2. if the reverse signal isn't confirmed (when CCI reaches the following levels: -80 for long position and 80 for short position)

Fig. 3. "3 Black Crows" pattern, confirmed by CCI indicator

Fig. 3. "3 Black Crows" pattern, confirmed by CCI indicator


  • int CBC_WS_CCI::LongCondition() - checks conditions to open long position (returns 80) and close of the short position (returns 40);
  • int CBC_WS_CCI::ShortCondition() - checks conditions to open short position (returns 80) and close of the long position (returns 40).

2.1. Open long position/Close short position

  1. The formation of "3 Black Crows" pattern must be confirmed by CCI indicator: CCI(1)<-50 (the value of the CCI of the last completed bar must be less than -50).

  2. The short position must be closed if the CCI indicator has crossed upward the critical level -80 or crossed downward the critical level 80.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBC_WS_CCI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of 3 White Soldiers pattern and CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) && (CCI(1)<-50))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (downward -80, downward -80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- return result
   return(result);
  }

2.2. Open short position/Close long position

  1. The formation of "3 White Soldiers" pattern must be confirmed by CCI indicator: CCI(1)>50 (the value of the CCI indicator of the last completed bar must be greater than 50).

  2. The long position must be closed if CCI indicator has crossed downward the -80 or 80 levels.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBC_WS_CCI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of 3 Black Crows pattern and CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) && (CCI(1)>50))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward -80, downward 80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- return result
   return(result);
  }


2.3. Creating Expert Advisor using MQL5 Wizard

The CBC_WS_CCI class isn't included in the Standard Library classes, to use it, it's necessary to download the acbc_ws_cci.mqh file (see attachments) and save it to the client_terminal_data\folder\MQL5\Include\Expert\Signal\MySignals. The same should be done with the candlepatterns.mqh file. You can use it in MQL5 Wizard after restart of the MetaEditor.

To create an Expert Advisor launch MQL5 Wizard:

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Let's specify the name of the Expert Advisor:

Fig. 5. General properties of the Expert Advisor

Fig. 5. General properties of the Expert Advisor

After that we need to select the modules of trade signals used.

Fig. 6. Signal properties of the Expert Advisor

Fig. 6. Signal properties of the Expert Advisor

In our case we use only one module of trade signals.

Adding the "Signals based on 3 Black Crows/3 White Soldiers confirmed by CCI" module of trading signals:

Fig. 7. Signal properties of the Expert Advisor

Fig. 7. Signal properties of the Expert Advisor

Module of trade signals added:

Fig. 8. Signal properties of the Expert Advisor

Fig. 8. Signal properties of the Expert Advisor

You can select any trailing properties, but we will use "Trailing Stop not used":

Fig. 9. Trailing properties of the Expert Advisor

Fig. 9. Trailing properties of the Expert Advisor

Concerning the money management properties, we will use "Trading with fixed trade volume":

Fig. 10. Money management properties of the Expert Advisor

Fig. 10. Money management properties of the Expert Advisor

By pressing the "Finish" button, we will get the code of the generated Expert Advisor, located in Expert_ABC_WS_CCI.mq5, it will be saved in terminal_data_folder\MQL5\Experts\.

The default input parameters of the generated Expert Advisor:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

must be replaced to:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

The Signal_ThresholdOpen/Signal_ThresholdClose input parameters allow to specify threshold levels for open and close of positions.

In code of the LongCondition() and ShortCondition() methods of the trade signals class we have specified the fixed values of the threshold:

  • Open position: 80;
  • Close position: 40.

The Expert Advisor, generated by MQL5 Wizard open and close position using the "votes" from the modules of trade signals. The vote of the main module (as container, it consist of all the modules added) is also used, but its LongCondition() and ShortCondition() methods always return 0.

The vote results of the main module is also used in "votes" averaging. In our case we have:  main module + 1 module of trade signals, so we need to take this fact into account when setting of the threshold values. Because of this fact the ThresholdOpen and ThresholdClose must be set as 40=(0+80)/2 and 20=(0+40)/2.

The values of Signal_StopLevel and Signal_TakeLevel input parameters is set to 0, it means that closing of the positions will be done only when closing conditions will be true.


2.4. History backtesting results

Let's consider backtesting of the Expert Advisor on historical data (EURUSD H1, testing period: 2010.01.01-2011.03.16, PeriodCCI=37, MA_period=13).

In creation of Expert Advisor we used the fixed volume (Trading Fixed Lot, 0.1), Trailing Stop algorithm is not used (Trailing not used).

Fig. 11. Testing results of the Expert Advisor, based on 3 Black Crows/3 White Soldiers + CCI

Fig. 11. Testing results of the Expert Advisor, based on 3 Black Crows/3 White Soldiers + CCI


The best set of input parameters can be found using the Strategy Tester of MetaTrader 5 client terminal.

The code of the Expert Advisor, created by MQL5 Wizard is attached in expert_abc_ws_cci.mq5.


Translated from Russian by MetaQuotes Software Corp.
Original code: https://www.mql5.com/ru/code/286

cIntSpeech cIntSpeech

It speaks the specified text using the speech engine.

MQL5 Wizard - Candlestick Patterns Class MQL5 Wizard - Candlestick Patterns Class

The class can be used for creation of trade signal classes with reversal candlestick patterns.

MQL5 Wizard - Trade Signals Based on 3 Black Crows/3 White Soldiers + MFI MQL5 Wizard - Trade Signals Based on 3 Black Crows/3 White Soldiers + MFI

Trade signals based on "3 Black Crows/3 White Soldiers" candlestick pattern, confirmed by Market Facilitation Index (MFI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on 3 Black Crows/3 White Soldiers + RSI MQL5 Wizard - Trade Signals Based on 3 Black Crows/3 White Soldiers + RSI

Trade signals based on "3 Black Crows/3 White Soldiers" candlestick pattern, confirmed by Relative Strength Index (RSI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.