//+--------------------------------------------------------------------------------+
//| Demo_iWPR.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "L'indicatore dimostra come ottenere i dati"
#property description "dei buffers indicatore per l'indicatore tecnico iWPR."
#property description "Il simbolo e timeframe usati per i calcoli dell'indicatore,"
#property description "vengono impostati dai parametri simbolo e periodo."
#property description "Il metodo per la creazione dell'handle è impostato attraverso il parametro 'type' (funzione type)."
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots 1
//--- il tracciamento di iWPR
#property indicator_label1 "iWPR"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrCyan
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- imposta il limite dei valori degli indicatori
#property indicator_minimum -100
#property indicator_maximum 0
//--- livelli orizzontali nella finestra dell'indicatore
#property indicator_level1 -20.0
#property indicator_level2 -80.0
//+--------------------------------------------------------------------------------+
//| Enumerazione dei metodi della creazione dell'handle |
//+--------------------------------------------------------------------------------+
enum Creation
{
Call_iWPR, // usa iWPR
Call_IndicatorCreate // usa IndicatorCreate
};
//--- parametri di input
input Creation type=Call_iWPR; // tipo della funzione
input int calc_period=14; // periodo
input string symbol=" "; // simbolo
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // timeframe
//--- buffer indicatore
double iWPRBuffer[];
//--- variabile per memorizzare l'handle dell'indicatore iWPR
int handle;
//--- variabile per memorizzare
string name=symbol;
//--- nome dell'indicatore sul grafico
string short_name;
//--- manterremo il numero di valori dell'indicatore Larry Williams' Percent Range
int bars_calculated=0;
//+--------------------------------------------------------------------------------+
//| Funzione di inizializzazione Indicatore Personalizzato |
//+--------------------------------------------------------------------------------+
int OnInit()
{
//--- assegnazione di array al buffer indicatore
SetIndexBuffer(0,iWPRBuffer,INDICATOR_DATA);
//--- determinare il simbolo per cui viene disegnato l'indicatore
name=symbol;
//--- eliminare gli spazi a destra e a sinistra
StringTrimRight(name);
StringTrimLeft(name);
//--- se il risultato è zero nella lunghezza della stringa 'name'
if(StringLen(name)==0)
{
//--- prende il simbolo del grafico indicatore a cui è attaccato
name=_Symbol;
}
//--- crea l'handle dell'indicatore
if(type==Call_iWPR)
handle=iWPR(name,period,calc_period);
else
{
//--- riempie la struttura con i parametri dell'indicatore
MqlParam pars[1];
//--- periodo
pars[0].type=TYPE_INT;
pars[0].integer_value=calc_period;
handle=IndicatorCreate(name,period,IND_WPR,1,pars);
}
//--- se l'handle non viene creato
if(handle==INVALID_HANDLE)
{
//--- dice riguardo il fallimento e l'output del codice di errore
PrintFormat("Fallimento nel creare l'handle dell'indicatore iWPR per il simbolo %s/%s, codice errore %d",
name,
EnumToString(period),
GetLastError());
//--- l'indicatore si ferma precocemente
return(INIT_FAILED);
}
//--- mostra il simbolo/timeframe per cui è calcolato l'indicatore tecnico Williams' Percent Range
short_name=StringFormat("iWPR(%s/%s, %d)",name,EnumToString(period),calc_period);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inizializzazione normale dell'indicatore
return(INIT_SUCCEEDED);
}
//+--------------------------------------------------------------------------------+
//| Funzione di iterazione indicatore personalizato |
//+--------------------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- numero di valori copiati dall' indicatore iWPR
int values_to_copy;
//--- determina il numero di valori calcolati in dell'indicatore
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
return(0);
}
//--- se è il primo inizio del calcolo dell'indicatore o se il numero di valori dell'indicatore iWPR è cambiato
//--- o se è necessario calcolare l'indicatore per due o più barre (significa che qualcosa è cambiato nello storico prezzi)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- se l' array iWPRBuffer è maggiore del numero di valori dell'indicatore iWPR per il simbolo/periodo, allora non copiamo tutto
//--- altrimenti, copiamo meno della grandezza del buffer indicatore
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- vuol dire che non è la prima volta del calcolo dell'indicatore, e dopo l'ultima chiamata di OnCalculate() )
//--- per il calcolo non viene aggiunta più di una barra
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- riempie l'array con i valori dell'indicatore Williams' Percent Range
//--- se FillArrayFromBuffer restituisce false, significa che l'informazione non è ancora pronta, chiude l'operazione
if(!FillArrayFromBuffer(iWPRBuffer,handle,values_to_copy)) return(0);
//--- forma il messaggio
string comm=StringFormat("%s ==> Valore aggiornato nell'indicatore %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- visualizza il messaggio di servizio sul grafico
Comment(comm);
//--- manterremo il numero di valori dell'indicatore Larry Williams' Percent Range
bars_calculated=calculated;
//--- restituisce il valore prev_calculated per la chiamata successiva
return(rates_total);
}
//+--------------------------------------------------------------------------------+
//| Riempie il buffer indicatore dall'indicatore iWPR |
//+--------------------------------------------------------------------------------+
bool FillArrayFromBuffer(double &wpr_buffer[], // buffer indicatore dei valori di Williams' Percent Range
int ind_handle, // handle dell'indicatore iWPR
int amount // numero di valori copiati
)
{
//--- resetta codice errore
ResetLastError();
//--- riempie una parte dell'array iWPRBuffer con valori dal buffer indicatore che ha indice 0
if(CopyBuffer(ind_handle,0,0,amount,wpr_buffer)<0)
{
//--- se la copia fallisce, dice il codice dell'errore
PrintFormat("Fallimento nel copiare i dati dall'indicatore iBearsPower, codice errore %d",GetLastError());
//--- esce con risultato zero - significa che l'indicatore è considerato come non calcolato
return(false);
}
//--- tutto è ok
return(true);
}
//+--------------------------------------------------------------------------------+
//| Funzione deinizializzazione indicatore |
//+--------------------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- cancella il grafico dopo aver eliminato l'indicatore
Comment("");
}
|