Обсуждение статьи "Создание бота для Telegram на языке MQL5"

Marco vd Heijden 2020.06.26 21:34 #301

SendPhoto

В классе реализована возможность отправки фотографий с двумя способами применения.

int SendPhoto(const long chat_id, const string local_path, string &photo_id, const string caption=NULL, const bool common_flag=false, const int timeout=10000)
идентификатор чата	номер чата
локальный_путь	локальный путь к папке в <папке данных>\MQL5\Files
photo_id	идентификатор фотографии, загруженной на сервер
подпись	текст подписи под фотографией
общий_флаг	флаг расположения файлов в общей папке всех клиентских терминалов \Terminal\Common\Files
таймаут	время ожидания операции в миллисекундах

Есть несколько способов отправить фотографию.

CCustomBot bot;

string token = "208375865:AAFnuOjlZ3Wsdan6PAjeqqUtBybe0Di1or8";

bot.Token(token);

string photo_id;
int result=bot.SendPhoto(198289825,"EURUSD1.gif",photo_id,"screenshot");
if(result==0)
   Print("Photo ID: ",photo_id);
else
   Print("Error: ",GetErrorDescription(result));

Я вижу, что у вас стоит знак минус.

Вы можете посмотреть в файле Telegram.mqh.

//+------------------------------------------------------------------+
   int SendPhoto(const long   _chat_id,
                 const string _photo_id,
                 const string _caption=NULL)
     {
      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      string out;
      string url=StringFormat("%s/bot%s/sendPhoto",TELEGRAM_BASE_URL,m_token);
      string params=StringFormat("chat_id=%lld&photo=%s",_chat_id,_photo_id);
      if(_caption!=NULL)
         params+="&caption="+UrlEncode(_caption);

      int res=PostRequest(out,url,params,WEB_TIMEOUT);
      if(res!=0)
        {
         //--- результат разбора
         CJAVal js(NULL,jtUNDEF);
         bool done=js.Deserialize(out);
         if(!done)
            return(ERR_JSON_PARSING);

         //--- получите описание ошибки
         bool ok=js["ok"].ToBool();
         long err_code=js["error_code"].ToInt();
         string err_desc=js["description"].ToStr();
        }
      //--- done
      return(res);
     }

   //+------------------------------------------------------------------+
   int SendPhoto(string &_photo_id,
                 const string _channel_name,
                 const string _local_path,
                 const string _caption=NULL,
                 const bool _common_flag=false,
                 const int _timeout=10000)
     {
      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      string name=StringTrim(_channel_name);
      if(StringGetCharacter(name,0)!='@')
         name="@"+name;

      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      ResetLastError();
      //--- копирование файла в буфер памяти
      if(!FileIsExist(_local_path,_common_flag))
         return(ERR_FILE_NOT_EXIST);

      //---
      int flags=FILE_READ|FILE_BIN|FILE_SHARE_WRITE|FILE_SHARE_READ;
      if(_common_flag)
         flags|=FILE_COMMON;

      //---
      int file=FileOpen(_local_path,flags);
      if(file<0)
         return(_LastError);

      //---
      int file_size=(int)FileSize(file);
      uchar photo[];
      ArrayResize(photo,file_size);
      FileReadArray(file,photo,0,file_size);
      FileClose(file);

      //--- создать границу: (данные -> base64 -> 1024 байта -> md5)
      uchar base64[];
      uchar key[];
      CryptEncode(CRYPT_BASE64,photo,key,base64);
      //---
      uchar temp[1024]={0};
      ArrayCopy(temp,base64,0,0,1024);
      //---
      uchar md5[];
      CryptEncode(CRYPT_HASH_MD5,temp,key,md5);
      //---
      string hash=NULL;
      int total=ArraySize(md5);
      for(int i=0;i<total;i++)
         hash+=StringFormat("%02X",md5[i]);
      hash=StringSubstr(hash,0,16);

      //--- WebRequest
      uchar result[];
      string result_headers;

      string url=StringFormat("%s/bot%s/sendPhoto",TELEGRAM_BASE_URL,m_token);

      //--- 1
      uchar data[];

      //--- добавьте идентификатор графика
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"chat_id\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,name);
      ArrayAdd(data,"\r\n");

      if(StringLen(_caption)>0)
        {
         ArrayAdd(data,"--"+hash+"\r\n");
         ArrayAdd(data,"Content-Disposition: form-data; name=\"caption\"\r\n");
         ArrayAdd(data,"\r\n");
         ArrayAdd(data,_caption);
         ArrayAdd(data,"\r\n");
        }

      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"photo\"; filename=\"lampash.gif\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,photo);
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"--\r\n");

      // SaveToFile("debug.txt",data);

      //---
      string headers="Content-Type: multipart/form-data; boundary="+hash+"\r\n";
      int res=WebRequest("POST",url,headers,_timeout,data,result,result_headers);
      if(res==200)//OK
        {
         //--- удалить BOM
         int start_index=0;
         int size=ArraySize(result);
         for(int i=0; i<fmin(size,8); i++)
           {
            if(result[i]==0xef || result[i]==0xbb || result[i]==0xbf)
               start_index=i+1;
            else
               break;
           }

         //---
         string out=CharArrayToString(result,start_index,WHOLE_ARRAY,CP_UTF8);

         //--- результат разбора
         CJAVal js(NULL,jtUNDEF);
         bool done=js.Deserialize(out);
         if(!done)
            return(ERR_JSON_PARSING);

         //--- получите описание ошибки
         bool ok=js["ok"].ToBool();
         if(!ok)
            return(ERR_JSON_NOT_OK);

         total=ArraySize(js["result"]["photo"].m_e);
         for(int i=0; i<total; i++)
           {
            CJAVal image=js["result"]["photo"].m_e[i];

            long image_size=image["file_size"].ToInt();
            if(image_size<=file_size)
               _photo_id=image["file_id"].ToStr();
           }

         return(0);
        }
      else
        {
         if(res==-1)
           {
            string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
            //Print(out);
            return(_LastError);
           }
         else
           {
            if(res>=100 && res<=511)
              {
               string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
               //Print(out);
               return(ERR_HTTP_ERROR_FIRST+res);
              }
            return(res);
           }
        }
      //--- 
      return(0);
     }

   //+------------------------------------------------------------------+
   int SendPhoto(string &_photo_id,
                 const long _chat_id,
                 const string _local_path,
                 const string _caption=NULL,
                 const bool _common_flag=false,
                 const int _timeout=10000)
     {
      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      ResetLastError();
      //--- копирование файла в буфер памяти
      if(!FileIsExist(_local_path,_common_flag))
         return(ERR_FILE_NOT_EXIST);

      //---
      int flags=FILE_READ|FILE_BIN|FILE_SHARE_WRITE|FILE_SHARE_READ;
      if(_common_flag)
         flags|=FILE_COMMON;

      //---
      int file=FileOpen(_local_path,flags);
      if(file<0)
         return(_LastError);

      //---
      int file_size=(int)FileSize(file);
      uchar photo[];
      ArrayResize(photo,file_size);
      FileReadArray(file,photo,0,file_size);
      FileClose(file);

      //--- создать границу: (данные -> base64 -> 1024 байта -> md5)
      uchar base64[];
      uchar key[];
      CryptEncode(CRYPT_BASE64,photo,key,base64);
      //---
      uchar temp[1024]={0};
      ArrayCopy(temp,base64,0,0,1024);
      //---
      uchar md5[];
      CryptEncode(CRYPT_HASH_MD5,temp,key,md5);
      //---
      string hash=NULL;
      int total=ArraySize(md5);
      for(int i=0;i<total;i++)
         hash+=StringFormat("%02X",md5[i]);
      hash=StringSubstr(hash,0,16);

      //--- WebRequest
      uchar result[];
      string result_headers;

      string url=StringFormat("%s/bot%s/sendPhoto",TELEGRAM_BASE_URL,m_token);

      //--- 1
      uchar data[];

      //--- добавьте идентификатор графика
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"chat_id\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,IntegerToString(_chat_id));
      ArrayAdd(data,"\r\n");

      if(StringLen(_caption)>0)
        {
         ArrayAdd(data,"--"+hash+"\r\n");
         ArrayAdd(data,"Content-Disposition: form-data; name=\"caption\"\r\n");
         ArrayAdd(data,"\r\n");
         ArrayAdd(data,_caption);
         ArrayAdd(data,"\r\n");
        }

      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"photo\"; filename=\"lampash.gif\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,photo);
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"--\r\n");

      // SaveToFile("debug.txt",data);

      //---
      string headers="Content-Type: multipart/form-data; boundary="+hash+"\r\n";
      int res=WebRequest("POST",url,headers,_timeout,data,result,result_headers);
      if(res==200)//OK
        {
         //--- удалить BOM
         int start_index=0;
         int size=ArraySize(result);
         for(int i=0; i<fmin(size,8); i++)
           {
            if(result[i]==0xef || result[i]==0xbb || result[i]==0xbf)
               start_index=i+1;
            else
               break;
           }

         //---
         string out=CharArrayToString(result,start_index,WHOLE_ARRAY,CP_UTF8);

         //--- результат разбора
         CJAVal js(NULL,jtUNDEF);
         bool done=js.Deserialize(out);
         if(!done)
            return(ERR_JSON_PARSING);

         //--- получите описание ошибки
         bool ok=js["ok"].ToBool();
         if(!ok)
            return(ERR_JSON_NOT_OK);

         total=ArraySize(js["result"]["photo"].m_e);
         for(int i=0; i<total; i++)
           {
            CJAVal image=js["result"]["photo"].m_e[i];

            long image_size=image["file_size"].ToInt();
            if(image_size<=file_size)
               _photo_id=image["file_id"].ToStr();
           }

         return(0);
        }
      else
        {
         if(res==-1)
           {
            string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
            //Print(out);
            return(_LastError);
           }
         else
           {
            if(res>=100 && res<=511)
              {
               string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
               //Print(out);
               return(ERR_HTTP_ERROR_FIRST+res);
              }
            return(res);
           }
        }
      //--- 
      return(0);
     }
   //+------------------------------------------------------------------+

Если вы посмотрите в файл mqh, вы увидите

      string name=StringTrim(_channel_name);
      if(StringGetCharacter(name,0)!='@')
         name="@"+name;

В вашем случае вы можете попробовать модификацию следующим образом

      string name = _channel_name;
      //if(StringGetCharacter(name,0)!='@')
      // name="@"+name;

Keith Watford 2020.06.26 23:35 #302

tdbguy:

Не публикуйте двойные сообщения!

Я удалю вашу тему и перенесу ответы сюда.

RedProviders 2020.06.29 13:18 #303

John Progton:

Andrey Voytenko в основном я добавил файлы, которые вы используете, а затем изменил скрипт, который у меня есть, чтобы отправить в telegram вместо электронной почты при выполнении торгового действия. Это работает, за исключением того, что при открытии сделки сообщение будет отправлено несколько раз

Те же проблемы

huwa 2020.07.07 21:03 #304

Подтверждаю, что с небольшими изменениями из поста #46, код отлично работает на MT5 для отправки алертов на каналы.

Подтверждаю также, что отправка запросов боту для управления советником работает.

Но кому-нибудь удалось заблокировать запросы от бота к советнику только по некоторому "from_id"? Таким образом, бот слушает только запросы от определенного ID.

WebRequest в MT4 возвращает Стратегия выхода: Ступенчатые стопы Проблема ввода нескольких ордеров

huwa 2020.07.11 19:14 #305

huwa:

Я подтверждаю, что с небольшими изменениями из поста #46, код отлично работает на MT5 для отправки алертов на каналы.

Подтверждаю также, что отправка запросов боту для управления советником работает.

Но кому-нибудь удалось заблокировать запросы от бота к советнику только по некоторому "from_id"? Таким образом, бот слушает только запросы от определенного ID.

Для тех, кто хочет заблокировать запрос бота на ID аккаунта Telegram, найдите эту строку в Telegram.mqh :

//--- фильтр
   //if(m_users_filter.Total()==0 || (m_users_filter.Total()>0 && m_users_filter.SearchLinear(msg.from_username)>=0)) //Удаляем эту строку из кода
   if(msg.from_id==??????????)   //Добавьте эту строку в код, где ?????????? - это ID вашего аккаунта Telegram.

ade kurniawan 2020.07.21 15:32 #306

Спасибо Андрею Войтенко за то, что поделился своими знаниями, это очень полезно для новичков вроде меня.

Telegram_Bot_EA и Telegram_Search_EA работают очень хорошо, но не с последним (Telegram_signal_EA).

Я не получал сигнал в моем канале.

Вот что я сделал:

- Создайте бота, добавьте в мой канал и установите права администратора.

- Замена вашего кода на мой индикатор

- Изменил Telegram.mqh, чтобы сделать приватный канал.

После запуска Telegram_singal_EA я вижу имя своего бота, но по-прежнему не получаю никакого сигнала.

Каждый тик я получаю ошибку:

Telegram_Signal_EA GBPUSD,M1: Error:Bad Request

Telegram_Signal_EA GBPUSD,M1: { "ok":false, "error_code":400, "description": "Bad Request: chat not found"}

Есть ли у вас какие-либо предложения?

Закрывайте только прибыльные сделки, Советники: Ask Bid Ticks Индикаторы: i-Regr

Andriy Voitenko 2020.07.21 16:10 #307

@ade kurniawan Вы должны работать с приватными каналами, используя ID чата (а не название канала).

Ade Kurniawan 2020.07.21 16:12 #308

Andrey Voytenko:

@ade kurniawan Вы должны работать с частными каналами, используя ID графика (а не название канала).

Да, я уже изменил это. Но все равно та же ошибка. Даже я изменил все на публичный канал

Herman Makmur 2020.08.01 06:25 #309

Кто-нибудь пробовал использовать шрифты BOLD или ITALIC в этой библиотеке?
Я пробовал **bold** __italic__ с разметкой в сообщении следующим образом, но ничего не вышло...

"n**boldtext** __italictext__ Balance: $%s parse_mode=MARKDOWN"

Результат:

**boldtext** __italictext__ Баланс: $10056.21 parse_mode=MARKDOWN

Может ли кто-нибудь помочь Backtest/optimize/MT4 Исторические данные Машинное обучение в трейдинге:

Herman Makmur 2020.08.01 06:44 #310

Неважно....

Я нашел ответ, установив флаг AsHTML в true...

bot.SendMessage(InpTelegramId,"<b>Balance: $10056.21</b>",true);

Извините...

spottypegasus: