Вопросы от начинающих MQL5 MT5 MetaTrader 5 - страница 827

[Igor Makanu]

помогите подправить индикатор - не могу разобраться с последним баром!

индикатор считает серию непрерывных выигрышей для бинарных опционов с учетом того, что ставка будет сделана каждые 2 бара (т.е. через один - выиграл/проиграл, ждешь текущий бар), внешняя переменная это анализ цены предыдущего  бара на возрастание цены или на убывание

все вроде работает, но вот онлайн последний бар неправильно считается, ну и как следствие если поставить индикатор на М1, то данные из истории будут правильно рассчитаны, а все что онлайн рассчитывается уже не правильно, код:

//+------------------------------------------------------------------+
//|                                                         test.mq5 |
//|                        Copyright 2017, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "IgorM"
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Label1
#property indicator_label1  "Label1"
#property indicator_type1   DRAW_HISTOGRAM
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  4
#property indicator_level1  2
#property indicator_level2  4
#property indicator_level3  6
//--- input parameters
input bool     on_a_higher=true;
//--- indicator buffers
double         Label1Buffer[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int count;
bool win;
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,Label1Buffer,INDICATOR_DATA);
   count = 0;
   win = false;
   
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const int begin,
                const double &price[])
  {
//---
      int start;
      if(prev_calculated==rates_total) return(rates_total);
      if(prev_calculated==0) start=1; else start=prev_calculated-1;
      for(int i=start;i<rates_total;i++){
            if (win){  // признак выигрыша на предыдущей ставке
                  win = false;
                  Label1Buffer[i]=count;
            }
            else{
                  if(on_a_higher){    // on_a_higher = true - расчитываем на рост цены относительно предидущего бара
                     if (price[i]>price[i-1]){
                           count++;
                           win = true;
                     } else{
                                 count = 0;
                                 win = false;
                     }
                  Label1Buffer[i]=count;
                  }else{              // on_a_higher = false - расчитываем на падение цены относительно предидущего бара
                        if (price[i]<price[i-1]){
                           count++;
                           win = true;
                     } else{
                                 count = 0;
                                 win = false;
                     }
                  Label1Buffer[i]=count;
                  }
            }
      }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+

заранее благодарен!

[yur4ik]

Здравствуйте! Помогите пожалуйста с модулем сигналов на закрытие позиций. Что я не так делаю?

[Vladimir Karputov]

yur4ik:
Здравствуйте! Помогите пожалуйста с модулем сигналов на закрытие позиций. Что я не так делаю?

Ваш файл - это модуль СИГНАЛОВ. В системе эксперта он встраивается так же как и модуль СИГНАЛОВ ПОЛЬЗОВАТЕЛЬСКОГО индикатора. Другими словами сигналы генерируемые Вашим модулем имеют ВЕС и может случится так, что этого веса не хватит для срабатывания сигнала.

Нужно подумать, как лучше делать закрытие применительно в Вашем случае. Возможно это нужно делать не в модуле сигналов

[yur4ik]

Vladimir Karputov:

Ваш файл - это модуль СИГНАЛОВ. В системе эксперта он встраивается так же как и модуль СИГНАЛОВ ПОЛЬЗОВАТЕЛЬСКОГО индикатора. Другими словами сигналы генерируемые Вашим модулем имеют ВЕС и может случится так, что этого веса не хватит для срабатывания сигнала.

Нужно подумать, как лучше делать закрытие применительно в Вашем случае. Возможно это нужно делать не в модуле сигналов

Хотелось бы в виде модуля сигналов, что бы через генератор советников собирать можно было. В момент, когда должен срабатывать данный модуль, LongCondition() и ShortCondition() во втором модуле советника возвращают нулевые значения - то есть вес=0, я правильно понимаю? Соответственно вес сигнала данного модуля должен перевесить, но он не срабатывает. В CheckCloseLong() и CheckCloseShort() я вставил строки Print("-------------"); и Print(time_GMT_DST()); которые, при нормальной работе модуля, должны делать соответствующие записи в журнал при поступлении каждого тика, я правильно понимаю? Записи не делаются, CheckCloseLong() и CheckCloseShort() не вызываются. В чем подвох?

Я конечно топорно объясняю, но я только учусь

[Vladimir Karputov]

yur4ik:

Хотелось бы в виде модуля сигналов, что бы через генератор советников собирать можно было. В момент, когда должен срабатывать данный модуль, LongCondition() и ShortCondition() во втором модуле советника возвращают нулевые значения - то есть вес=0, я правильно понимаю? Соответственно вес сигнала данного модуля должен перевесить, но он не срабатывает. В CheckCloseLong() и CheckCloseShort() я вставил строки Print("-------------"); и Print(time_GMT_DST()); которые, при нормальной работе модуля, должны делать соответствующие записи в журнал при поступлении каждого тика, я правильно понимаю? Записи не делаются, CheckCloseLong() и CheckCloseShort() не вызываются. В чем подвох?

Я конечно топорно объясняю, но я только учусь

Используйте методы

   //--- methods of checking if the market models are formed
   virtual int       LongCondition(void);
   virtual int       ShortCondition(void);

вместо своих CheckCloseLong и  CheckCloseShort.

[lil_lil]

fxsaber:

Спасибо.

[Nikita Chernyshov]

Здравствуйте, подскажите, как сделать счетчик убыточных сделок?
Советник анализирует последнюю сделку на истории - если она убыточна, то добавляет +1 к переменной, которая и будет являться количеством подряд убыточных сделок.

Как только прибыльная сделка наступает - переменную нужно обнулить.

[Vladimir Karputov]

Nikita Chernyshov:

Здравствуйте, подскажите, как сделать счетчик убыточных сделок?
Советник анализирует последнюю сделку на истории - если она убыточна, то добавляет +1 к переменной, которая и будет являться количеством подряд убыточных сделок.

Как только прибыльная сделка наступает - переменную нужно обнулить.

Можно отказаться от работы с торговой историей и работать только в OnTradeTransaction() - там ловить сделку с типом "OUT" - то есть это и будет закрытие позиции. Как только такая сделка нашлась - определяем была она прибыльной или убыточной. Соответственно счётчик "losses" сбрасываем или увеличиваем.

//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value 
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      long     deal_ticket       =0;
      long     deal_order        =0;
      long     deal_time         =0;
      long     deal_time_msc     =0;
      long     deal_type         =-1;
      long     deal_entry        =-1;
      long     deal_magic        =0;
      long     deal_reason       =-1;
      long     deal_position_id  =0;
      double   deal_volume       =0.0;
      double   deal_price        =0.0;
      double   deal_commission   =0.0;
      double   deal_swap         =0.0;
      double   deal_profit       =0.0;
      string   deal_symbol       ="";
      string   deal_comment      ="";
      string   deal_external_id  ="";
      if(HistoryDealSelect(trans.deal))
        {
         deal_ticket       =HistoryDealGetInteger(trans.deal,DEAL_TICKET);
         deal_order        =HistoryDealGetInteger(trans.deal,DEAL_ORDER);
         deal_time         =HistoryDealGetInteger(trans.deal,DEAL_TIME);
         deal_time_msc     =HistoryDealGetInteger(trans.deal,DEAL_TIME_MSC);
         deal_type         =HistoryDealGetInteger(trans.deal,DEAL_TYPE);
         deal_entry        =HistoryDealGetInteger(trans.deal,DEAL_ENTRY);
         deal_magic        =HistoryDealGetInteger(trans.deal,DEAL_MAGIC);
         deal_reason       =HistoryDealGetInteger(trans.deal,DEAL_REASON);
         deal_position_id  =HistoryDealGetInteger(trans.deal,DEAL_POSITION_ID);

         deal_volume       =HistoryDealGetDouble(trans.deal,DEAL_VOLUME);
         deal_price        =HistoryDealGetDouble(trans.deal,DEAL_PRICE);
         deal_commission   =HistoryDealGetDouble(trans.deal,DEAL_COMMISSION);
         deal_swap         =HistoryDealGetDouble(trans.deal,DEAL_SWAP);
         deal_profit       =HistoryDealGetDouble(trans.deal,DEAL_PROFIT);

         deal_symbol       =HistoryDealGetString(trans.deal,DEAL_SYMBOL);
         deal_comment      =HistoryDealGetString(trans.deal,DEAL_COMMENT);
         deal_external_id  =HistoryDealGetString(trans.deal,DEAL_EXTERNAL_ID);
        }
      else
         return;
      if(deal_symbol==Symbol() && deal_magic==m_magic)
         if(deal_entry==DEAL_ENTRY_OUT)
           {
            if(deal_commission+deal_swap+deal_profit>0)
              {
               losses=0;
              }
            else
              {
               losses++;
              }
           }
     }
  }

А проверку в торговой истории делать в OnInit() - один раз при старте советника.

[Vitaliy Sendyaev]

Всем привет,

Не подскажите как можно программно очистить журнал экспертов перед выводом в него информацию :?

Только через Win API?

Спасибо!

[Vladimir Karputov]

Vitaliy Sendyaev:

Всем привет,

Не подскажите как можно программно очистить журнал экспертов перед выводом в него информацию :?

Только через Win API?

Спасибо!

Журнал только через Win API.