Любой вопрос новичка, чтоб не захламлять форум. Профи, не проходите мимо. Без вас никуда - 6. - страница 759

Новый комментарий
 
Ты два раза пытаешься закрыть один и тот же ордер. Убери верхний.
 
Roger:
Ты два раза пытаешься закрыть один и тот же ордер. Убери верхний.
Лучше нижний. Ордер предварительно надо выбрать.
  
            
//ResetLastError();
//if(!OrderClose(OrderTicket(),OrderLots(),_Bid,15)) Print("Чё-та не закрылася позиция. Фигня вот такая происходит: "+GetLastError());

Доброе утро.

Исключил две строки. Все работает. И на графике все правильно отображается, и в результатах и в журналах.

Вопрос: при компиляции выдает


'Ozero.mq4'                                                        Ozero.mq4     1    1
return value of 'OrderClose' should be checked    Ozero.mq4    46    13
0 error(s), 1 warning(s)                                                           1    2



О чем предупреждает компилятор? 46 строка это OrderClose(OrderTicket(),OrderLots(),_Bid,15);


Ozero.

 
tuner:

Ребяты подскажите из-за чего может быть глюк, возникший сегодня.

В советнике есть возможность остановки торговли за 15 минут до закрытия рынка в пятницу.

При появлении нового дня советник проверяет, если это пятница, то сегодня перестаем торговать в StringToTime("23:59")-15*60

В тестере стратегий эта функция работает правильно, но на реале наблюдаю совсем другую картину - советник перестает торговать с первым тиком при наступлении пятницы. 

Вот принты из журнала экспертов:

Брокер №1, демо:

0 05:59:47.731 Scalper GBPAUDpt,M1: Finish In Friday = 2014.10.23 23:44:00

Брокер №2, реал:

0 03:00:11.999 Scalper EURUSD,M1: Finish In Friday = 2014.10.23 23:44:00

То есть при появлении сегодняшнего дневного бара (24 окт, пятница) на первом же тике советник 

преобразует строку "23:59" во время со вчерашним днем, за место того чтобы присваивать день сегодняшний.

Но если советник перезапустить в пятницу в середине дня, то он корректно определит время завершения работы.

Нашел причину этой проблемы: https://forum.mql4.com/33023

Как и предполагалось, это практически баг функции StringToTime. Все симптомы сходятся. Данная функция преобразует строку "23:59" в datetime с датой локального ПК, а не с датой МТ4. А в тестере, как известно, дата локального ПК эмулируется и приравнивается ко времени терминала. Поэтому в тестере все работает как надо, а на демо/реале получается глюк и убытки. В документации конечно не сказано откуда берется дата и по ссылке выше видно что данная проблема озвучивалась еще 4 года назад, но видимо метаквотам все равно.

  
      RefreshRates();                     // Обновим данные
      _Bid=MarketInfo( "GBPUSD",MODE_BID);

      if (_Bid>=gPoint1)
        {
           for(pos=OrdersTotal();pos>=0;pos--)
             {
                OrderClose(OrderTicket()-1,OrderLots(),_Bid,15);
             }      
       
        }

Еще вопрос. Я правильно понимаю, что:

1. нумерация ордеров начинается от "0".

2. такой код закроет абсолютно все ордера, хоть я их открывал в ручную, хоть программно? Т.е. никогда не найдется такой ордер, который эта часть программы не сможет закрыть?


Ozero.

[Удален]  

Кто нибудь делал скроллинг текста на экране? К примеру - ордер такой то открыт/закрыт/модифицирован и т.п.. Новости там такие то... ?

Если не жалко, покажите пожалуйста кусок кода.

Сенкс!

 
Vinin:
Лучше нижний. Ордер предварительно надо выбрать.

Лучше так:

//+------------------------------------------------------------------+
//|                                                        Ozero.mq4 |
//|                                            Copyright 2014, Vinin |
//|                                         http://bomzh_inc.ucoz.ru |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, Bomzh Inc"
#property link      "http://bomzh_inc.ucoz.ru"
#property version   "1.00"
#property strict
// -------- переменные --- Н -----
input double gLot=0.1;           // Размер лота для покупки 
input double gPoint=0.001;       // Дельта для закрытия 
input string symbol="GBPUSD";    // Рабочая валютная пара
void OnTick() {
   // Открытие позиции
   if(OrdersTotal()==0) {
      int ticket=0;
      double _Ask=SymbolInfoDouble(symbol,SYMBOL_ASK);
      Print(" Открытие первой позиции ");
      ticket=OrderSend(symbol,OP_BUY,gLot,_Ask,15,0,0);
      if(ticket>0) Print("ОТКРЫТ ОРДЕР #"+IntegerToString(ticket));
      }
   //--- Закрытие позиций
   double _Bid=SymbolInfoDouble(symbol,SYMBOL_BID); //для цены
   for(int pos=OrdersTotal()-1;pos>=0;pos--) {
      if(OrderSelect(pos,SELECT_BY_POS)) {
         if(OrderSymbol()!=symbol) continue;
         if(OrderType()!=OP_BUY)   continue;
         if(OrderOpenPrice()+gPoint<_Bid) {
            ResetLastError();
            if(!OrderClose(OrderTicket(),OrderLots(),_Bid,15)) 
               Print("Чё-та не закрылася позиция. Фигня вот такая происходит: "+IntegerToString(GetLastError()));
            }
         }
      }
   //--- End OnTick()
}
//+------------------------------------------------------------------+
 
_new-rena:

Кто нибудь делал скроллинг текста на экране? К примеру - ордер такой то открыт/закрыт/модифицирован и т.п.. Новости там такие то... ?

Если не жалко, покажите пожалуйста кусок кода.

Сенкс!

Делал вертикальный скроллинг в окне пустого индикатора. Вот функция:

//+------------------------------------------------------------------+
// Если bool print = true или нет окна индикатора, то функция будет выводить сообщения в журнал
void iPrint(string mess1, int sz=9, color color1=clrDarkGray, 
            string mess2="", color color2=clrDarkGray, 
            string mess3="", color color3=clrDarkGray, 
            string mess4="", color color4=clrDarkGray, 
            bool draws=true) {
   string   NameGrafText, message, nm;
   int      i, y, k, shift, Win_Num=-1, num=0;
   color    cl;
   Win_Num=WindowFind("Win_Inform");
   if (mess1=="") {
      //Print("Func iPrint: Передана пустая строка, выходим");
      return;
      }
   if (!draws || Win_Num<0) {
      message=mess1+mess2+mess3+mess4;
      Print(message); 
      return;
      }
   k=ArraySize(Mass_Name_Message)-1;
   if (StringLen(mess1)>0) num++;
   if (StringLen(mess2)>0) num++;
   if (StringLen(mess3)>0) num++;
   if (StringLen(mess4)>0) num++;
// Смещение и перекрашивание старых сообщений   
   for (i=k; i>=0; i--) {                             
      NameGrafText=Mass_Name_Message[i];           
      if (StringLen(NameGrafText)>0) {
         if (ObjectFind(NameGrafText)==Win_Num) {
            if (i+num>k) {                   // Удаляем самую верхнюю строчку
               ObjectDelete(NameGrafText);  
               Mass_Name_Message[i]="";
               }
            else if (i+num<=k) {             // Сдвигаем и перекрашиваем старые сообщения
               Mass_Name_Message[i+num]=Mass_Name_Message[i];
               y=(int)ObjectGet(NameGrafText, OBJPROP_YDISTANCE);          // старая координата Y
               ObjectSet  (NameGrafText, OBJPROP_YDISTANCE, y+(sz+1)*num); // новая координата Y
               ObjectSet  (NameGrafText, OBJPROP_COLOR, clrDimGray);       // новый цвет
               }
            }
         }
      }
// Вывод новых сообщений
   shift=num;
   uint v=GetTickCount();
   for (i=0; i<num; i++) {
      shift--;
      NameGrafText=Prefix+"_GT_"+IntegerToString(i)+"_"+IntegerToString(v);   // Уникальное имя объекта
      int app=0;
      while (ObjectFind(NameGrafText)==Win_Num) {  // Если всё-таки такой объект есть
         app++;
         NameGrafText=Prefix+"_GT_"+IntegerToString(i)+"_"+IntegerToString(v)+"_"+IntegerToString(app); // добавим к его имени "хвостик"
         }
      Mass_Name_Message[num-1-i]=NameGrafText;
      switch (i) {
         case 0: message=mess1; cl=color1; break;
         case 1: message=mess2; cl=color2; break;
         case 2: message=mess3; cl=color3; break;
         case 3: message=mess4; cl=color4; break;
         default:message=mess1; cl=color1; break;
         }
      ObjectCreate (NameGrafText, OBJ_LABEL, Win_Num, 0, 0);
      ObjectSetText(NameGrafText, message, sz, "Courier New", cl);
      ObjectSet    (NameGrafText, OBJPROP_COLOR, cl);                   // цвет
      ObjectSet    (NameGrafText, OBJPROP_CORNER,    2);                // угол
      ObjectSet    (NameGrafText, OBJPROP_XDISTANCE, 150);              // координата Х
      ObjectSet    (NameGrafText, OBJPROP_YDISTANCE, 2+(sz+1)*shift);   // координата Y
      WindowRedraw();
      }
}
//+------------------------------------------------------------------+

Как пример использования одноцветного сообщения (можно 4 цвета в одной строке для разных слов):

if(get.BarOpenLastPos(sy,PERIOD_H4,OP_SELL,mn)!=0) {
   string mess1="На D1 вниз, на H4 ниже SAR, M15 сигнал. Продаём";
   iPrint(mess1,9,clrBlue);
   trade.OpenS(sy,lots,mn,0.0,0.0,co);
   }

На графике должен быть пустой индикатор с именем Win_Inform.

[Удален]  
_new-rena:

Кто нибудь делал скроллинг текста на экране? К примеру - ордер такой то открыт/закрыт/модифицирован и т.п.. Новости там такие то... ?

Если не жалко, покажите пожалуйста кусок кода.

Сенкс!

https://book.mql4.com/ru/build/info


[Удален]  
artmedia70:

Делал вертикальный скроллинг в окне пустого индикатора. Вот функция:

Как пример использования одноцветного сообщения (можно 4 цвета в одной строке для разных слов):

На графике должен быть пустой индикатор с именем Win_Inform.

Спасибо!

Ознакомился, принцип понятен.

Чтобы осуществить такую функцию, не хватает одной детали:

- как вытащить те информационные сообщения, которые МТ4 выдает на вкладках "Журнал" и "Эксперты" ?

(Собираюсь запоминать их в строковый массив стекового типа и выводить на основной экран, плюсом добавлю новости и получится приличная вещь))))

1...752753754755756757758759760761762763764765766...1178
Новый комментарий