ДокументацияРазделы
Справочник MQL5Дата и времяTimeToStruct 

TimeToStruct

Производит конвертацию из значения типа datetime (количество секунд с 01.01.1970) в переменную типа структуры MqlDateTime.

bool  TimeToStruct(
   datetime      dt,            // дата и время
   MqlDateTime&  dt_struct      // структура для принятия значений
   );

Параметры

dt

[in]  Значение даты для конвертации.

dt_struct

[out]  Переменная структуры типа MqlDateTime.

Возвращаемое значение

true – в случае успеха, иначе false. Чтобы получить информацию об ошибке, необходимо вызвать функцию GetLastError().

Пример:

void OnStart()
  {
//---получим последнее известное время сервера, объявим структуру даты/времени и  заполним поля структуры
   datetime    time=TimeCurrent();
   MqlDateTime tm  ={};
   if(!TimeToStruct(time,tm))
      Print("TimeToStruct() failed. Error ", GetLastError());
   
//--- выведем в журнал полученное время сервера и результат заполнения структуры MqlDateTime при помощи TimeToStruct()
   PrintFormat("Server time: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)",
               (string)time, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week, EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week));
   /*
   результат:
   Server time: 2024.04.18 15:47:27
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 15
   - Min: 47
   - Sec: 27
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   */
  }