Perguntas de Iniciantes MQL4 MT4 MetaTrader 4

Valeriy Yastremskiy 2020.09.20 13:12 #2131

Aleksandr Martynov:

UPS, acho que a encontrei:

De acordo com a documentação:

Se um indicador personalizado é chamado usando a funçãoiCustom(), este indicador é executado na linha do programa de chamada. As funções da biblioteca (importada) também funcionam na linha do programa de chamadas.

De modo geral, para a MQL4 não importa onde você coloca os cálculos, pois serão alocados recursos para a linha única do programa e indicadores utilizados por ela.

Neste caso, é aconselhável, se possível, transferir o código do indicador para o Expert Advisor e otimizar o número de valores calculados pela profundidade da matriz e o número de "buffers", embora não diga respeito aos algoritmos recursivos - ainda é mais fácil lê-los no indicador, pois o programa indexou automaticamente os buffers apenas para os dados de preços ...

A questão está na conveniência de ler e editar o código e, portanto, o mt4 é de rosca única em uma janela. É mais fácil para mim levar a parte de cálculo de um indicador para um Expert Advisor. Mas nem sempre é bom. O código se torna longo, enquanto o inludes ou iQuest é o mesmo. Se você quiser acelerar, então o mt5. mt4 não é suficientemente rápido, a julgar pelos participantes do fórum.

Menos código, mais ação... como identificar os pontos Faz sentido mudar do

Aleksandr Martynov 2020.09.20 18:27 #2132

Valeriy Yastremskiy:

A questão é como é fácil ler e editar o código, e como ele é, o mt4 é de rosca simples em uma janela. Acho mais fácil obter a parte de cálculo de um indicador em uma EA. Mas nem sempre é bom. O código se torna longo, enquanto o inludes ou iQuest é o mesmo. Se você quiser acelerar, vá para mt5. mt4 é mais lento, a julgar pelos comentários do fórum.

Se você quiser acelerar, então é mt5, mas o mt4 perde, a julgar pelos comentários do fórum. Fórmulas tão simples como média, ziguezague, e não qualquer tipo. 5 é certamente bom, mas nem todos ainda o estão fornecendo e você tem que aprendê-lo

[FOREX - Tendências, previsões Perguntas de Iniciantes MQL5 Comércio rentável

Valeriy Yastremskiy 2020.09.20 21:51 #2133

Aleksandr Martynov:

A gestão dos buffers de cálculo no EA será mais cara do que o indicador. Fórmulas tão simples como média, ziguezague e não todas elas. 5 é bom, é claro, mas nem todos têm acesso a ele.

Mas para fazer isso é preciso tirar o código de lógica indicadora, o que nem sempre é fácil.

Alexander Kovalev 2020.09.21 09:42 #2134

É seguro dar os logs do EA e do terminal a um desenvolvedor a seu pedido? Ele pode fazer alguma coisa à minha conta ou computador?

Vitaly Muzichenko 2020.09.21 10:11 #2135

Alexander Kovalev:

É seguro dar os logs do EA e do terminal ao desenvolvedor a seu pedido? Ele pode fazer alguma coisa à minha conta ou computador?

Sim, e também tirar todas as jóias de ouro da casa do caixão

Alexander Korovkin 2020.09.21 10:15 #2136

Meus amigos, por favor, me avisem onde estou indo errado (por favor não me matem, estou trabalhando na MQL4 há 3 dias).

Estou tentando abrir uma ordem de venda do mercado a um preço de pontos Delta indentados (60) do valor previamente colocado (que eu tomo ao abrir uma ordem anterior).

Entretanto, o roteiro abre uma nova ordem ao mesmo tempo que a ordem anterior, ao preço atual, sem esperar pela condição apropriada (uma queda de preço de 60 pontos). Sei que cheguei a algum lugar, mas ainda não entendo onde está.

Eu ficaria muito grato!

[ARQUIVO]Qualquer pergunta de novato, [AVISO FECHADO!] Qualquer pergunta [Arquivo!] Escrever um assessor

Dmitrii Solovei 2020.09.21 17:30 #2137

Ajude-me!!!

Eu não consigo descobrir onde está meu problema. A EA requer volumes de EMA. Eu usei o iMAonArray.

Mas o cálculo não é semelhante ao real.

Aqui está o código:

***

Arquivos anexados:

FastStoneEditor1.jpg 199 kb

Наджибулло Хабибов 2020.09.23 09:22 #2138

Aleksandr Martynov:
Boa pergunta, eu tenho um carro e algo chocalha dentro dele, que parafuso para apertar? Você tem idéia do quanto os conselhos são possíveis e no final são todos inúteis porque é preciso apertar a porca...

Há apenas um código no estúdio e nenhuma outra forma.

Olhe a razão pela qual não abre para o ouro ?

***

Документация по MQL5: Дата и время / TimeCurrent

www.mql5.com

Возвращает последнее известное время сервера, время прихода последней котировки по одному из выбранных в "Обзоре рынка" символов. В обработчике OnTick() данная функция вернет время пришедшего обрабатываемого тика. В других случаях (например, вызов в обработчиках OnInit(), OnDeinit(), OnTimer() и так далее) это –...

Vladimir Karputov 2020.09.23 09:46 #2139

Наджибулло Хабибов:

Veja a razão pela qual não abre sobre o ouro ?

***

Insira o códigocorretamente: use o botão

ou, alternativamente: anexe o arquivo usando o

MQL5.community - Памятка пользователя

www.mql5.com

Теперь вы можете не только читать статьи и скачивать программы на языке MQL5, но и участвовать в обсуждении интересующих вас тем на Форуме, оставлять комментарии к статьям и опубликованным кодам. Кроме того, вы можете не только выкладывать собственные разработки в Code Base, но и публиковать Статьи, за которые мы предлагаем вознаграждение...

Наджибулло Хабибов 2020.09.23 11:54 #2140

Наджибулло Хабибов:

Veja a razão pela qual não abre sobre o ouro ?

***

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern double Profit     = 0;        // Профит в валюте
extern int StopLoss      = 0;        // Стоп Лось
extern int TakeProfit    = 0;        // ТейкПрофит
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ
extern int TrailingStop  = 0;        // трал
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Reverse       = 0;        // 1-реверс
extern int CloseSig      = 0;        // 1-закрытие по сигналу
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

extern string IndName    = "Aroow";
extern int SignalPeriod  = 9;

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool TimeSession(int aStartHour,int aStartMinute,int aStopHour,int aStopMinute,datetime aTimeCur)
  {
//--- время начала сессии
   int StartTime=3600*aStartHour+60*aStartMinute;
//--- время окончания сессии
   int StopTime=3600*aStopHour+60*aStopMinute;
//--- текущее время в секундах от начала дня
   aTimeCur=aTimeCur%86400;
   if(StopTime<StartTime)
     {
      //--- переход через полночь
      if(aTimeCur>=StartTime || aTimeCur<StopTime)
        {
         return(true);
        }
     }
   else
     {
      //--- внутри одного дня
      if(aTimeCur>=StartTime && aTimeCur<StopTime)
        {
         return(true);
        }
     }
   return(false);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,_Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   
   if(CountTrades()>0)
     {
      lot=NormalizeDouble(lot*MathPow(KLot,CountTrades()),2);
     }
   if(lot>MaxLot)
      lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*_Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*_Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*_Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*_Point)) || (OrderStopLoss()==0))
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*_Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*_Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double blu = iCustom(NULL,0,IndName,SignalPeriod,4,Shift);
   double red = iCustom(NULL,0,IndName,SignalPeriod,5,Shift);
   double blu2 = iCustom(NULL,0,IndName,SignalPeriod,4,Shift+1);
   double red2 = iCustom(NULL,0,IndName,SignalPeriod,5,Shift+1);

   bool buy = blu<1000 && red2<1000;
   bool sell = red<1000 && blu2<1000;

   if(Reverse>0)
     {
      buy = red<1000 && blu2<1000;
      sell = blu<1000 && red2<1000;
     }

   if(BULevel>0)
      BU();
   if(TrailingStop>0)
      Trailing();
   if(AllProfit()>Profit && Profit>0)
      CloseAll();

   if(TimeSession(StartHour,StartMin,EndHour,EndMin,TimeCurrent()) && t!=Time[0])
     {
      if(buy)
        {
         PutOrder(0,Ask);
        }
      if(sell)
        {
         PutOrder(1,Bid);
        }
      t=Time[0];
     }

   if(CountTrades()>0 && CloseSig>0)
     {
      if(sell)
        {
         CloseAll(0);
        }
      if(buy)
        {
         CloseAll(1);
        }
     }

   Comment("\n blu: ",blu,
           "\n red: ",red,
           "\n All Profit: ",AllProfit());
  }
//+------------------------------------------------------------------+

Perguntas de Iniciantes MQL4 MT4 MetaTrader 4 - página 214