Distribuição de Cauchy

Esta seção contém funções para trabalhar com a distribuição de Cauchy. Elas permitem que você calcule a densidade, probabilidade, quantis e gere números pseudo-aleatórios de acordo com a distribuição de Cauchy. A distribuição de Cauchy é descrita pela seguinte fórmula:

pdf_cauchy_distribution

Onde:

  • x – valor da variável aleatória
  • a –  parâmetro de distribuição mean
  • b – parâmetro de distribuição scale

DemoCauchyDistribution

Além do cálculo das variáveis ​​aleatórias individuais, é possível trabalhar com suas matrizes.  

Função

Descrição

MathProbabilityDensityCauchy

Calcula a densidade de probabilidade da distribuição de Cauchy

MathCumulativeDistributionCauchy

Calcula o valor da função distribuição de Cauchy de probabilidades

MathQuantileCauchy

Calcula o inverso da função de distribuição de Cauchy para a probabilidade especificada

MathRandomCauchy

Gera um valor/matriz pseudo-aleatório de valores pseudo-aleatórios de acordo com a distribuição de Cauchy

MathMomentsCauchy

Calcula os valores numéricos teóricos dos primeiros 4 momentos da distribuição de Cauchy

Exemplo:

#include <Graphics\Graphic.mqh>
#include <Math\Stat\Cauchy.mqh>
#include <Math\Stat\Math.mqh>
#property script_show_inputs
//--- input parameters
input double a_par=-2;      // parâmetro de distribuição mean
input double b_par=1;       // parâmetro de distribuição scale
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- desativamos a exibição do gráfico de preço
   ChartSetInteger(0,CHART_SHOW,false);
//--- inicializamos o gerador de números aleatórios  
   MathSrand(GetTickCount());
//--- geramos a amostragem da variável aleatória
   long chart=0;
   string name="GraphicNormal";
   int n=1000000;       // número de valores na amostragem
   int ncells=51;       // número de intervalos no gráfico de colunas
   double x[];          // centros de intervalos no gráfico de colunas
   double y[];          // número de valores a partir da amostragem dentro do intervalo
   double data[];       // amostragem de valores aleatórios
   double max,min;      // valores máximo e mínimo na amostragem
//--- obtemos a amostragem a partir da distribuição de Cauchy
   MathRandomCauchy(a_par,b_par,n,data);
//--- calculamos os dados para plotagem do gráfico de colunas
   CalculateHistogramArray(data,x,y,max,min,ncells);
//--- obtemos os limites de sequência e passo para plotagem da curva teórica
   double step;
   GetMaxMinStepValues(max,min,step);
   step=MathMin(step,(max-min)/ncells);
//--- obtemos teoricamente os cálculos no intervalo [min,max]
   double x2[];
   double y2[];
   MathSequence(min,max,step,x2);
   MathProbabilityDensityCauchy(x2,a_par,b_par,false,y2);
//--- dimensionamos
   double theor_max=y2[ArrayMaximum(y2)];
   double sample_max=y[ArrayMaximum(y)];
   double k=sample_max/theor_max;
   for(int i=0; i<ncells; i++)
      y[i]/=k;
//--- imprimimos o gráfico
   CGraphic graphic;
   if(ObjectFind(chart,name)<0)
      graphic.Create(chart,name,0,0,0,780,380);
   else
      graphic.Attach(chart,name);
   graphic.BackgroundMain(StringFormat("Cauchy distribution a=%G b=%G",a_par,b_par));
   graphic.BackgroundMainSize(16);
//--- plot all curves
   graphic.CurveAdd(x,y,CURVE_HISTOGRAM,"Sample").HistogramWidth(6);
//--- e agora traçamos a curva teórica de densidade da distribuição
   graphic.CurveAdd(x2,y2,CURVE_LINES,"Theory");
   graphic.CurvePlotAll();
//--- plot all curves
   graphic.Update();
  }
//+------------------------------------------------------------------+
//|  Calculate frequencies for data set                              |
//+------------------------------------------------------------------+
bool CalculateHistogramArray(const double &data[],double &intervals[],double &frequency[],
                             double &maxv,double &minv,const int cells=10)
  {
   if(cells<=1)
      return(false);
   int size=ArraySize(data);
   if(size<cells*10)
      return(false);
   minv=data[ArrayMinimum(data)];
   maxv=data[ArrayMaximum(data)];
   Print("min=",minv," max=",maxv);
   minv=-20;
   maxv=20;
   double range=maxv-minv;
   double width=range/cells;
   if(width==0)
      return(false);
   ArrayResize(intervals,cells);
   ArrayResize(frequency,cells);
//--- definimos os centros dos intervalos
   for(int i=0; i<cells; i++)
     {
      intervals[i]=minv+i*width;
      frequency[i]=0;
     }
//--- preenchemos a frequência de aparecimento no intervalo
   for(int i=0; i<size; i++)
     {
      int ind=(int)MathRound((data[i]-minv)/width);
      if(ind>=0 && ind<cells)
         frequency[ind]++;
     }
   return(true);
  }
//+------------------------------------------------------------------+
//|  Calculates values for sequence generation                       |
//+------------------------------------------------------------------+
void GetMaxMinStepValues(double &maxv,double &minv,double &stepv)
  {
//--- calculamos a magnitude da sequência para obter a precisão da normalização
   double range=MathAbs(maxv-minv);
   int degree=(int)MathRound(MathLog10(range));
//--- normalizamos os valores máx. e mín. com a precisão
   maxv=NormalizeDouble(maxv,degree);
   minv=NormalizeDouble(minv,degree);
//--- definimos o passo de geração da mesma maneira a partir da precisão definida
   stepv=NormalizeDouble(MathPow(10,-degree),degree);
   if((maxv-minv)/stepv<10)
      stepv/=10.;
  }